SAS編程：通過Picture語句設(shè)置變量Format

輸出一張頻數(shù)匯總表，遇到一個(gè)問題。TFLShell中，頻數(shù)百分比保留一位小數(shù)，我直接用5.1的格式將百分比put出來 (put(percent, 5.1))。這樣做，本來沒什么問題。但這張表的BigN大于1000，分類中有頻數(shù)為0和1的情況，這樣對(duì)于頻數(shù)為0和1的類別，百分比輸出都為“(0.0)”，直觀上看這兩個(gè)百分比相同。

跟統(tǒng)計(jì)師進(jìn)行確認(rèn)，對(duì)于頻數(shù)不為0的記錄，如果頻率小于0.1，顯示為“(<0.1)”。這樣，頻率百分比顯示要求具體如下：

  1. 對(duì)于＞0以及＜0.1的值，顯示“<0.1”;
  2. 對(duì)于0或≥0.1的值，顯示5.1的格式。

對(duì)于每一個(gè)試驗(yàn)分組，我目前的代碼如下：

c1 = strip(put(_0, 5)) || " (" || strip(put(_0/&n_0.*100, 5.1)) ||")";

基于新的邏輯，我需要判斷頻數(shù)是否為0，以及頻率是否小于0.1之后，再進(jìn)行賦值。同時(shí)，5個(gè)不同的試驗(yàn)分組需要單獨(dú)處理。

直接進(jìn)行條件判斷，程序更新比較繁瑣，所以我考慮通過設(shè)置百分比的Format來實(shí)現(xiàn)統(tǒng)計(jì)師的要求。設(shè)置好符合條件的Format之后，直接替換格式5.1，就可以完成程序的更新。

而這個(gè)格式的設(shè)置，就是通過Format過程步中的pircture語句來實(shí)現(xiàn)。

這里為什么不能使用value語句來設(shè)置Format呢？value語句設(shè)置的Format，是固定的值或范圍對(duì)應(yīng)具體的字符串，而條件2顯示具體的格式，是無法用value語句實(shí)現(xiàn)的。

下面開始介紹Format過程步中的Picture語句，讀者也可以直接跳到第4部分，先看一下Picture語句的具體應(yīng)用。

0. Picture語句語法

Picture語句是用于創(chuàng)建輸出數(shù)值的模板 (Creates a template for printing numbers.)，其主要語法為:

proc format;
  picture fmtname
  value-or-range-1 = 'picture-1'
  value-or-range-2 = 'picture-2'
    ... ...
  ;
run;

1. value-or-range

等號(hào)左側(cè)的value-or-range, 有兩類形式，一是具體的值，二是具體的范圍。具體的離散值不做詳細(xì)的介紹，具體的范圍主要有三種形式：

  1. 范圍端點(diǎn)包含無限值（正無窮或負(fù)無窮），舉例：0-high, low-0, low-high；
  2. 范圍端點(diǎn)為有限值，且包含有限值，舉例：0-1，1-100，-1-6
  3. 范圍端點(diǎn)為有限值，但不包含有限值，舉例：0<-1, 1-<100, -1<-<6。

同時(shí)，value-or-range的兩類形式可以互相并列，中間用,間隔：

proc format;
  picture fmtname
  1,3, 4-10 = 'picture1'
  11-20, 21 = 'picture2'
  ;
run;

2. 'Picture'

等號(hào)右側(cè)的'Picture'可以理解成一種具體的數(shù)值模板，主要有3類：

  1. 數(shù)值選擇符 (digit selectors)；
  2. 信息字符 (message characters)
  3. 指令 (directives)
2.1 數(shù)值選擇符 (digit selectors)；

數(shù)值選擇符，用于定義數(shù)值位置的0-9的字符，1個(gè)選擇符代表1位數(shù)字。如果是非0選擇符在最左側(cè)，不足位的數(shù)值將會(huì)用0補(bǔ)位；如果是0選擇符在最左側(cè)，不足位的數(shù)值將不會(huì)用0補(bǔ)位；通常用數(shù)字9來表示非0字符。代碼示例如下：

proc format;
  picture fmt
    1-5 = '009.9'
    5<-10 = '999.9'
  ;
run;

data tmp;
    a = 1; b = put(a, fmt.); output; 
    a = 10; b = put(a, fmt.); output;
run;
tmp

格式fmt的含義為，對(duì)于1到5之間的數(shù)值，保留1位小數(shù)；對(duì)于5到10之間的數(shù)據(jù)值，保留1位小數(shù)，如果小數(shù)點(diǎn)左側(cè)位數(shù)小于3位，則用0補(bǔ)位。

數(shù)值1的格式為0選擇符在最左側(cè)，整數(shù)位不足3位時(shí)，不需要用0補(bǔ)足位數(shù)；數(shù)值10的格式為非0選擇符在最左側(cè)，整數(shù)位不足3位時(shí)，需要用0補(bǔ)足位數(shù)。

2.2 信息字符 (message characters)；

信息字符，是指非數(shù)字字符，直接輸出字符串的內(nèi)容，這類似于Value語句生成的格式。

proc format;
  picture fmt
    1-5 = 'ha'
    5<-10 = 'hei'
  ;
run;

data tmp;
    a = 1; b = put(a, fmt.); output; 
    a = 10; b = put(a, fmt.); output;
run;
tmp

Picture模板中，也可以同時(shí)包括數(shù)值選擇符和信息字符，不過數(shù)值字符必須在模板的開頭，這樣數(shù)值選擇符的格式才能正常顯示。

proc format;
  picture fmt
    1-5 = '000.00 ha'
    5<-10 = '999.9 hei'
  ;
run;

data tmp;
    a = 1; b = put(a, fmt.); output; 
    a = 10; b = put(a, fmt.); output;
run;
tmp
2.3 指令 (directives)；

指令，是一些特殊字符，可以用來格式化日期、時(shí)間或日期時(shí)間值。這一內(nèi)容在日常工作中，比較少用到，這里不做過多介紹，感興趣的讀者可以自行查看SAS官方文檔（SAS Help Center: Syntax: PROC FORMAT PICTURE Statement）。

3. 常用選項(xiàng)

Picture語句中的選項(xiàng)，分為Format選項(xiàng)和Picture選項(xiàng)。在Format過程步使用選項(xiàng)時(shí)，要將選項(xiàng)放置到括號(hào)()中。Format選項(xiàng)放在格式名稱之后，Picture選項(xiàng)放在模板'Picture'之后。介紹3個(gè)常用選項(xiàng)，Round，Noedit以及Prefix=""。

3.1 Format選項(xiàng)——Round

Round選項(xiàng)的作用是，對(duì)數(shù)值進(jìn)行格式化時(shí)，會(huì)將數(shù)值四舍五入到最近的整數(shù)。直接看定義不方便理解，直接看代碼演示：

**Without Round option;
proc format;
  picture fmt
    1-5 = '000.00'
    5<-10 = '999.99 '
  ;
run;

data tmp1;
  a = 1.444; b = put(a, fmt.); output; 
  a = 1.445; b = put(a, fmt.); output;

  a = 9.444; b = put(a, fmt.); output; 
  a = 9.445; b = put(a, fmt.); output;
run;
tmp1

未使用Round選項(xiàng)時(shí)，對(duì)數(shù)值進(jìn)行保留兩位小數(shù)的操作，會(huì)直接取小數(shù)位的后兩位，不管小數(shù)點(diǎn)后第3位數(shù)值的大小。

**With Round option;
proc format;
  picture fmt (round)
    1-5 = '000.00'
    5<-10 = '999.99 '
  ;
run;

data tmp2;
  a = 1.444; b = put(a, fmt.); output; 
  a = 1.445; b = put(a, fmt.); output;

  a = 9.444; b = put(a, fmt.); output; 
  a = 9.445; b = put(a, fmt.); output;
run;
tmp2

使用Round選項(xiàng)后，對(duì)數(shù)值進(jìn)行保留兩位小數(shù)的操作，會(huì)根據(jù)小數(shù)點(diǎn)后第3位數(shù)值的大小進(jìn)行四舍五入。代碼示例中，第3位為5時(shí)，會(huì)向前進(jìn)一位。

3.2 Picture選項(xiàng)——Noedit

Noedit選項(xiàng)作用是，將Picture模板中的數(shù)值當(dāng)做信息字符 (message characters)，而不是數(shù)值選擇符 (digit selectors)。前面介紹到，模板中的數(shù)字都有對(duì)應(yīng)的含義，Noedit選項(xiàng)會(huì)抹去模板中數(shù)字的含義，直接將數(shù)字當(dāng)作純粹的字符，與Value語句生成Format的作用完全相同。

代碼舉例如下：

**Noedit option;
proc format;
  picture fmt
    1-5 = '000.00 ha' (noedit)
    5<-10 = '999.9 hei'
  ;
run;

data tmp;
    a = 1; b = put(a, fmt.); output; 
    a = 10; b = put(a, fmt.); output;
run;
tmp

數(shù)字1的Format，對(duì)應(yīng)字符000.00 ha；數(shù)字10的Format，對(duì)應(yīng)保留1位小數(shù)，并在數(shù)值后面添加字符"hei"。

3.3 Picture選項(xiàng)——Prefix=

Prefix=選項(xiàng)的作用是，指定一個(gè)字符作為格式化值的前綴。這個(gè)比較容易理解，直接看代碼實(shí)例，輸出結(jié)果中直接添加前綴中的內(nèi)容。關(guān)于Prefix=選項(xiàng)的具體應(yīng)用，我們在下一部分介紹。

**Prefix= option;
proc format;
  picture fmt
    1-5 = '000.00' (prefix = "Haha - ")
    5<-10 = '999.99' (prefix = "Heihei - ")
  ;
run;

data tmp;
    a = 1; b = put(a, fmt.); output; 
    a = 10; b = put(a, fmt.); output;
run;
tmp

4. Picture語句應(yīng)用舉例

4.1 頻率格式自帶括號(hào)——Prefix=

通常我們在輸出頻數(shù)匯總時(shí)，頻數(shù)和頻率的輸出都是以n (xx.x)的形式輸出。常規(guī)的做法是將數(shù)值Put出來后，與左右括號(hào)進(jìn)行拼接。

c1 = strip(put(_0, 5)) || " (" || strip(put(_0/&n_0.*100, 5.1)) ||")";

通過Picture語句生成的頻率格式也可以自帶括號(hào)，這需要Prefix選項(xiàng)來實(shí)現(xiàn)。

前面談到，'Picture'模板，可以同時(shí)使用數(shù)值選擇符和信息字符，但是數(shù)值選擇符必須位于模板的開頭。

特定范圍的數(shù)值可以使用數(shù)值選擇符設(shè)置特定的格式，后面添加信息字符右括號(hào))，而開頭的左括號(hào)可以通過prefix="( "選項(xiàng)來實(shí)現(xiàn)。

具體演示代碼如下，F(xiàn)ormat選項(xiàng)中min =選項(xiàng)指定格式的最小長度。如果不指定長度的話，默認(rèn)長度是第一條記錄Format值的長度，這可能造成后續(xù)值的截?cái)唷?/p>

代碼中也展示了手動(dòng)輸出括號(hào)的結(jié)果，兩者的顯示略有區(qū)別。使用Picture格式的輸出，左括號(hào)始終距離數(shù)字1個(gè)空格；而手動(dòng)輸出括號(hào)的方法，左括號(hào)的位置始終固定。

具體如何展示，需要看各個(gè)公司、項(xiàng)目、統(tǒng)計(jì)師的要求，不能一概而論。

proc format;
  picture fmt (round min = 10)
    0-<99.95 = '009.9 )'  (prefix = "( ")
    99.95-100 = '999.9 )'  (prefix = "( ")
  ;
run;

data tmp1;
    a = 0.15; b = put(a, fmt.); output; 
    a = 10.15; b = put(a, fmt.); output; 
    a = 99.92; b = put(a, fmt.); output;
    a = 99.96; b = put(a, fmt.); output;
run;

data tmp2;
    a = 0.15; b = "( " || put(a, 5.1) || " ) "; output; 
    a = 10.15; b = "( " || put(a, 5.1) || " ) "; output; 
    a = 99.92; b = "( " || put(a, 5.1) || " ) "; output;
    a = 99.96; b = "( " || put(a, 5.1) || " ) "; output;
run;
tmp1
tmp2
4.2 頻率輸出演示

最近手頭項(xiàng)目的要求，頻率百分比大于0且小于0.1，輸出為<0.1；其他則輸出保留1位小數(shù)。

具體實(shí)現(xiàn)的代碼如下：

proc format;
  picture fmt (round min = 10)
    0<-<0.1 = '( <0.1 )'  (noedit)
    0, 0.1-high = '009.9 )'  (prefix = "( ")
  ;
run;

data tmp;
    a = 0.05; b = put(a, fmt.); output; 
    a = 0; b = put(a, fmt.); output; 
    a = 90.15; b = put(a, fmt.); output;
    a = 99.96; b = put(a, fmt.); output;
run;
tmp

取值為0與≥0.1的Format值相同，設(shè)置格式時(shí)可以使用,進(jìn)行并列。Format選項(xiàng)round使保留小數(shù)位時(shí)，進(jìn)行四舍五入。

4.3 p值輸出演示

醫(yī)學(xué)期刊一般對(duì)p值的輸出有要求，例如：

  1. p > 0.1, p值保留2位小數(shù)；
  2. 0.1 > p ≥ 0.001，p值保留3位小數(shù)；
  3. p < 0.001，p值顯示為"p < 0.001"。

實(shí)現(xiàn)代碼如下：

proc format;
  picture fmt (round min = 10)
    0-<0.001 = 'p < 0.001'  (noedit)
    0.001-<0.01 = '9.999'  
    0.01-1 = '9.99'
  ;
run;

data tmp;
    a = 0.0005; b = put(a, fmt.); output; 
    a = 0.0015; b = put(a, fmt.); output; 
    a = 0.624; b = put(a, fmt.); output;
    a = 0.625; b = put(a, fmt.); output;
run;
tmp

總結(jié)

這篇文章介紹了Format過程步中Picture語句基本語法，Pircture語句生成的Format與Value語句生成的不同，模板設(shè)置的多樣性可以應(yīng)對(duì)更加復(fù)雜的格式要求。文章還介紹了3個(gè)常用的選項(xiàng)，以及3個(gè)Picture語句的應(yīng)用舉例。

希望給讀者在日常工作中一些思路啟發(fā)，提供不一樣的解決格式問題的視角。

感謝閱讀！若有疑問，歡迎評(píng)論區(qū)交流！

最后編輯于 ：
?著作權(quán)歸作者所有,轉(zhuǎn)載或內(nèi)容合作請聯(lián)系作者
【社區(qū)內(nèi)容提示】社區(qū)部分內(nèi)容疑似由AI輔助生成，瀏覽時(shí)請結(jié)合常識(shí)與多方信息審慎甄別。
平臺(tái)聲明：文章內(nèi)容（如有圖片或視頻亦包括在內(nèi)）由作者上傳并發(fā)布，文章內(nèi)容僅代表作者本人觀點(diǎn)，簡書系信息發(fā)布平臺(tái)，僅提供信息存儲(chǔ)服務(wù)。

相關(guān)閱讀更多精彩內(nèi)容

友情鏈接更多精彩內(nèi)容