1. TCP服務端簡介

TCP服務端是基于TCP協(xié)議構(gòu)建的一種網(wǎng)絡服務模式，它為HTTP（超文本傳輸協(xié)議）、SMTP（簡單郵件傳輸協(xié)議）等高層協(xié)議的應用程序提供了可靠的底層支持。在TCP服務端中，服務器啟動后會監(jiān)聽一個或多個端口，等待客戶端發(fā)起連接請求。當接收到客戶端的連接請求時，服務端會響應并建立一個全雙工的連接，并確保雙方都準備好進行數(shù)據(jù)交換。一旦連接建立成功，服務端就能夠開始接收來自客戶端的數(shù)據(jù)，并根據(jù)需要向客戶端發(fā)送響應信息。對于運行在TCP服務端之上的應用層協(xié)議來說，這種可靠的服務是非常重要的。例如，Web服務器通過HTTP協(xié)議處理網(wǎng)頁請求時，就需要依賴TCP來確保請求和響應數(shù)據(jù)的正確性；郵件服務器使用SMTP協(xié)議發(fā)送和接收郵件時，同樣依靠TCP保證郵件內(nèi)容的完整傳輸。掌握TCP服務端的編程技巧，可以極大地提升開發(fā)者的網(wǎng)絡應用構(gòu)建能力。本系列的第25篇文章《鴻蒙網(wǎng)絡編程系列25-TCP回聲服務器的實現(xiàn)》中基于ArkTS語言實現(xiàn)了TCP回聲服務器，演示了基本的TCP服務端編程方法，本文將使用倉頡語言在API 12的環(huán)境中實現(xiàn)類似的功能。

2. TCP回聲服務器演示

本示例運行后的頁面如圖所示：

image.png

輸入綁定的本地端口，默認是9999，單擊“啟動”按鈕即可啟動TCP監(jiān)聽服務，如圖所示：

image.png

再啟動上一篇文章《鴻蒙網(wǎng)絡編程系列49-倉頡版TCP客戶端》中介紹的TCP客戶端，使用該客戶端連接本TCP服務器，然后發(fā)送“Hi,TCP Server”給服務端，如圖所示：

image.png

可以看到，收到了服務端的回復，此時再查看回聲服務器的日志，如圖所示：

image.png

可以看到，回聲服務器也收到了客戶端發(fā)送的消息。

3. TCP回聲服務器示例編寫

下面詳細介紹創(chuàng)建該示例的步驟（確保DevEco Studio已安裝倉頡插件）。

步驟1：創(chuàng)建[Cangjie]Empty Ability項目。

步驟2：在module.json5配置文件加上對權(quán)限的聲明：

"requestPermissions": [
      {
        "name": "ohos.permission.INTERNET"
      }
    ]

這里添加了訪問互聯(lián)網(wǎng)的權(quán)限。

步驟3：在build-profile.json5配置文件加上倉頡編譯架構(gòu)：

"cangjieOptions": {
      "path": "./src/main/cangjie/cjpm.toml",
      "abiFilters": ["arm64-v8a", "x86_64"]
    }

步驟4：在index.cj文件里添加如下的代碼：

package ohos_app_cangjie_entry

import ohos.base.*
import ohos.component.*
import ohos.state_manage.*
import ohos.state_macro_manage.*
import ohos.net.http.*
import ohos.ability.getStageContext
import ohos.ability.*
import std.convert.*
import std.net.*
import std.socket.*

@Entry
@Component
class EntryView {
    @State
    var title: String = '倉頡版TCP回聲服務器示例';
    //連接、通訊歷史記錄
    @State
    var msgHistory: String = ''
    //本地端口
    @State
    var localPort: UInt16 = 9999

    //綁定狀態(tài)
    @State
    var bindState = false

    let scroller: Scroller = Scroller()

    func build() {
        Row {
            Column {
                Text(title).fontSize(14).fontWeight(FontWeight.Bold).width(100.percent).textAlign(TextAlign.Center).
                    padding(10)

                Flex(FlexParams(justifyContent: FlexAlign.Start, alignItems: ItemAlign.Center)) {
                    Text("綁定的本地端口：").fontSize(14)

                    TextInput(text: localPort.toString()).onChange({
                        value => localPort = UInt16.parse(value)
                    }).setType(InputType.Number).width(100).fontSize(11).flexGrow(1)

                    Button("啟動").onClick {
                        evt => startServer()
                    }.enabled(!bindState).width(70).fontSize(14)
                }.width(100.percent).padding(10)

                Scroll(scroller) {
                    Text(msgHistory).textAlign(TextAlign.Start).padding(10).width(100.percent).backgroundColor(0xeeeeee)
                }.align(Alignment.Top).backgroundColor(0xeeeeee).height(300).flexGrow(1).scrollable(
                    ScrollDirection.Vertical).scrollBar(BarState.On).scrollBarWidth(20)
            }.width(100.percent).height(100.percent)
        }.height(100.percent)
    }

    //啟動回聲服務器
    func startServer() {
        //TCP服務端
        let tcpServer = TcpServerSocket(bindAt: localPort)
        tcpServer.bind()
        msgHistory += "綁定到端口${localPort}\r\n"
        bindState = true

        //啟動一個線程監(jiān)聽客戶端的連接并讀取客戶端發(fā)送過來的消息
        spawn {
            msgHistory += "開始監(jiān)聽客戶端連接\r\n"
            while (true) {
                let echoClient = tcpServer.accept()
                msgHistory += "接受客戶端連接, 客戶端地址:${echoClient.remoteAddress}\r\n"
                //啟動一個線程處理新的socket
                spawn {
                    try {
                        dealWithEchoClient(echoClient)
                    } catch (exp: Exception) {
                        msgHistory += "從套接字讀取數(shù)據(jù)出錯：${exp}\r\n"
                    }
                }
            }
        }
    }

    //從客戶端套接字讀取數(shù)據(jù)并回寫
    func dealWithEchoClient(echoClient: TcpSocket) {
        //存放從socket讀取數(shù)據(jù)的緩沖區(qū)
        let buffer = Array<UInt8>(1024, item: 0)

        while (true) {
            //從socket讀取數(shù)據(jù)
            var readCount = echoClient.read(buffer)
            if (readCount > 0) {
                //把接收到的數(shù)據(jù)轉(zhuǎn)換為字符串
                let content = String.fromUtf8(buffer[0..readCount])

                //輸出接收到的信息到日志
                msgHistory += "${echoClient.remoteAddress}:${content}\r\n"
                //回寫到客戶端
                echoClient.write(content.toArray())
            }
        }
    }
}

步驟5：編譯運行，可以使用模擬器或者真機。

步驟6：按照本文第2部分“TCP回聲服務器演示”操作即可。

4. 代碼分析

本示例的關鍵部分有兩處，第一處是開啟監(jiān)聽，就是監(jiān)聽綁定的端口，等待客戶端的連接，這個監(jiān)聽是阻塞的，如果沒有客戶端連接就會一直等待，代碼如下：

let echoClient = tcpServer.accept()

如果有客戶端連接，就會返回代表客戶端連接的套接字，本示例中就是echoClient變量。

另一處是關于客戶端連接的數(shù)據(jù)讀取和發(fā)送，因為服務端可能會同時接收多個客戶端的連接，為提高處理效率，這里新起了一個線程來專門負責客戶端連接的數(shù)據(jù)讀寫，代碼如下：

spawn {
                    try {
                        dealWithEchoClient(echoClient)
                    } catch (exp: Exception) {
                        msgHistory += "從套接字讀取數(shù)據(jù)出錯：${exp}\r\n"
                    }
                }

具體的處理在函數(shù)dealWithEchoClient中實現(xiàn)。

本示例為簡化代碼的編寫，假設客戶端發(fā)送的數(shù)據(jù)可以一次性全部接收，也就是假設不存在數(shù)據(jù)粘包問題，當然實際中可能會存在，后面文章會針對倉頡語言講解實現(xiàn)方式，關于ArkTS的實現(xiàn)方式見第本系列的第35篇《鴻蒙網(wǎng)絡編程系列35-通過數(shù)據(jù)包結(jié)束標志解決TCP粘包問題》或第36篇《鴻蒙網(wǎng)絡編程系列36-固定包頭可變包體解決TCP粘包問題》

（本文作者原創(chuàng)，除非明確授權(quán)禁止轉(zhuǎn)載）

本文源碼地址：
https://gitee.com/zl3624/harmonyos_network_samples/tree/master/code/tcp/TCPEchoServer4Cj

本系列源碼地址：
https://gitee.com/zl3624/harmonyos_network_samples