前言
在mac電腦上，可以通過(guò)手動(dòng)創(chuàng)建XCode工程的方式，來(lái)實(shí)現(xiàn)iOS lib的編譯，但這種方式存在一個(gè)很明顯的缺點(diǎn)，在需要指定編譯文件的情況下，比較麻煩～CMake編譯腳本完美的解決了這個(gè)問(wèn)題，可以指定特定的文件參與編譯

安裝Xcode 和 CMake

xcode https://developer.apple.com/xcode/download

cmake OS X版本https://cmake.org/download

默認(rèn)情況 cmake 命令行可能用不了，需要命令行中輸入以下指令

export PATH=/Applications/CMake.app/Contents/bin/:$PATH

具體可參考 CMake Mac下安裝

準(zhǔn)備 iOS 工具鏈

ios.toolchain.cmake https://github.com/leetal/ios-cmake/releases

README文件中有工具鏈的使用方式

編寫(xiě)CMakeLists

ios.toolchain.cmake 工具鏈Demo中提供的CMakeLists，可以根據(jù)實(shí)際情況做下修改。

cmake_minimum_required (VERSION 3.2)
project (example-ios C CXX)
enable_testing()

MESSAGE( STATUS "CMAKE_CXX_FLAGS: " ${CMAKE_CXX_FLAGS} )

# Add some sanitary checks that the toolchain is actually working!
include(CheckCXXSymbolExists)
check_cxx_symbol_exists(kqueue sys/event.h HAVE_KQUEUE)
if(NOT HAVE_KQUEUE)
  message(STATUS "kqueue NOT found!")
else()
  message(STATUS "kqueue found!")
endif()

find_library(APPKIT_LIBRARY AppKit)
if (NOT APPKIT_LIBRARY)
  message(STATUS "AppKit.framework NOT found!")
else()
  message(STATUS "AppKit.framework found! ${APPKIT_LIBRARY}")
endif()

find_library(UIKIT_LIBRARY UIKit)
if (NOT UIKIT_LIBRARY)
  message(STATUS "UIKit.framework NOT found!")
else()
  message(STATUS "UIKit.framework found! ${UIKIT_LIBRARY}")
endif()

# Hook up XCTest for the supported plaforms (all but WatchOS)
if(NOT PLATFORM MATCHES ".*WATCHOS.*")
  # Use the standard find_package, broken between 3.14.0 and 3.14.4 at least for XCtest...
  find_package(XCTest)
  # Fallback: Try to find XCtest as host package via toochain macro (should always work)
  find_host_package(XCTest REQUIRED)
endif()

# Includes
include_directories(${example-ios_SOURCE_DIR})

# Make sure try_compile() works
include(CheckTypeSize)
check_type_size(time_t SIZEOF_TIME_T)

# Source files
set(SOURCES
  HelloWorld.cpp
  HelloWorldIOS.mm
)

# Headers
set(HEADERS
  HelloWorld.hpp
  HelloWorldIOS.h
)

# Library
if(BUILD_SHARED)
  add_library (example SHARED ${SOURCES} ${HEADERS})
  target_compile_definitions(example PUBLIC IS_BUILDING_SHARED)
  message(STATUS "Building shared version...")
else()
  add_library (example STATIC ${SOURCES} ${HEADERS})
  message(STATUS "Building static version...")
endif()

if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  set(CMAKE_INSTALL_PREFIX ${example-ios_SOURCE_DIR}/../example-app/example-lib CACHE PATH "Install path" FORCE)
endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)

# Executable
if(PLATFORM MATCHES "MAC.*")
  set(APP_NAME TestApp)
  add_executable (${APP_NAME} MACOSX_BUNDLE main.cpp)
  set_target_properties(${APP_NAME} PROPERTIES
          BUNDLE True
          MACOSX_BUNDLE_GUI_IDENTIFIER leetal.com.helloworld
          MACOSX_BUNDLE_BUNDLE_NAME helloworld
          MACOSX_BUNDLE_BUNDLE_VERSION "0.1"
          MACOSX_BUNDLE_SHORT_VERSION_STRING "0.1"
          )
  # Link the library with the executable
  target_link_libraries(${APP_NAME} example)
endif()

# Debug symbols set in XCode project
set_xcode_property(example GCC_GENERATE_DEBUGGING_SYMBOLS YES "All")

# Installation
if(PLATFORM MATCHES "MAC.*")
  install(TARGETS ${APP_NAME}
          BUNDLE DESTINATION . COMPONENT Runtime
          RUNTIME DESTINATION bin COMPONENT Runtime
          LIBRARY DESTINATION lib
          ARCHIVE DESTINATION lib/static)

  # Note Mac specific extension .app
  set(APPS "\${CMAKE_INSTALL_PREFIX}/${APP_NAME}.app")

  # Directories to look for dependencies
  set(DIRS ${CMAKE_BINARY_DIR})

  install(CODE "include(BundleUtilities)
    fixup_bundle(\"${APPS}\" \"\" \"${DIRS}\")")

  set(CPACK_GENERATOR "DRAGNDROP")
  include(CPack)
else()
  install(TARGETS example
          LIBRARY DESTINATION lib
          ARCHIVE DESTINATION lib/static)
endif()
install (FILES ${HEADERS} DESTINATION include)

編譯

cd example/example-lib
mkdir build
cd build
cmake .. -G Xcode -DCMAKE_TOOLCHAIN_FILE=../../ios.toolchain.cmake -DPLATFORM=OS64
cmake --build . --config Release

cmake .. -G Xcode -DCMAKE_TOOLCHAIN_FILE=../../ios.toolchain.cmake -DPLATFORM=OS64
指令指定了CMakeLists、工具鏈的位置及編譯架構(gòu)，會(huì)生成一個(gè)XCode工程。其中.. 表示CMakeLists文件在當(dāng)前目錄的上一個(gè)文件夾中，../表示上一個(gè)文件夾，../../表示上兩個(gè)文件夾