Gradle 獲取svn版本號(hào)

1. Project層下的 * build.gradle * 文件

buildscript {
    repositories {
        maven{ url 'http://maven.oschina.net/content/groups/public/'}//OSC的maven倉(cāng)庫(kù)鏡像
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.1.0'
        classpath group: 'org.tmatesoft.svnkit', name: 'svnkit', version: '1.8.11' //引入svn插件
    }
}

2. Module層下的 ** build.gradle ** 文件 加入以下
3. 第一行導(dǎo)包

import org.tmatesoft.svn.core.wc.*

2. 定義函數(shù)

def getSvnRevision() {
    ISVNOptions options = SVNWCUtil.createDefaultOptions(true);
    SVNClientManager clientManager = SVNClientManager.newInstance(options);
    SVNStatusClient statusClient = clientManager.getStatusClient();
    SVNStatus status = statusClient.doStatus(projectDir, false);
    SVNRevision revision = status.getCommittedRevision();
    return revision.getNumber();
}

附

自己項(xiàng)目中使用的Gradle文件

1. project.build

buildscript {
    repositories {
        maven{ url 'http://maven.oschina.net/content/groups/public/'}
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.1.0'
        classpath group: 'org.tmatesoft.svnkit', name: 'svnkit', version: '1.8.11'
    }
}
allprojects {
    repositories {
        maven{ url 'http://maven.oschina.net/content/groups/public/'}
        jcenter()
        mavenCentral()
        maven {
            url "https://jitpack.io"
        }
    }
}

2. moudle.build

import org.tmatesoft.svn.core.wc.*

apply plugin: 'com.android.application'

//配置android annotations
//apply plugin: 'com.neenbedankt.android-apt'

def getSvnRevision() {
    ISVNOptions options = SVNWCUtil.createDefaultOptions(true);
    SVNClientManager clientManager = SVNClientManager.newInstance(options);
    SVNStatusClient statusClient = clientManager.getStatusClient();
    SVNStatus status = statusClient.doStatus(projectDir, false);
    SVNRevision revision = status.getCommittedRevision();
    return revision.getNumber();
}

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.3"
    defaultConfig {
        applicationId "cn.mobilizer.wenxun"
        minSdkVersion 14
        targetSdkVersion 23
        versionCode 1
        versionName "1.0.2.${getSvnRevision()}"
        ndk {
            //設(shè)置支持的SO庫(kù)架構(gòu)
            abiFilters 'armeabi' //, 'x86', 'armeabi-v7a', 'x86_64', 'arm64-v8a'
        }
    }
    
    //簽名文件最好不放在這里
    signingConfigs {
        release {
            keyAlias 'release'
            keyPassword 'release'
            storeFile file('sign/release.keystore')
            storePassword 'release'
        }
    }

    buildTypes {
        release {
            println 'release  -- build'
            //自定義字段
            buildConfigField "boolean", "LOG_DEBUG", "false"
            //混淆
            minifyEnabled false
            //移除無(wú)用的res文件(必須混淆)
            shrinkResources true
            zipAlignEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            //簽名文件
            signingConfig signingConfigs.mobilizer
            //對(duì)生成的apk 進(jìn)行重命名,及制定到相對(duì)目錄
            applicationVariants.all { variant ->
                println "release baseName --> ${variant.baseName}" //xxx-release,xxx-debug
                println "release name --> ${variant.name}"
                variant.outputs.each { output ->
                    def outputFile = output.outputFile
                    println "release outputFile.name --> ${outputFile.name}"
                    if (outputFile != null && outputFile.name.endsWith('.apk')) {
                        def fileName;
                        if (variant.baseName.endsWith('release')) {
                            fileName = "xxxxx_${versionName}.apk"
                        } else if (variant.baseName.endsWith('debug')) {
                            fileName = "xxxxx_debug_${versionName}.apk"
                        }
                        def rootDir = (new File(outputFile.parent)).parentFile.parentFile.parentFile;
                        output.outputFile = new File("${rootDir}/apk/${getSvnRevision()}", fileName)
                        println "release after change outputFile.name --> ${outputFile}"
                    }
                }
            }
        }

        debug {
            buildConfigField "boolean", "LOG_DEBUG", "true"
            signingConfig signingConfigs.xxxxx
        }
    }

    sourceSets {
        main {
            java.srcDirs = ['src/main/java']
            res.srcDirs = ['src/main/res', 'src/main/res-lib', 'src/main/res-config']
        }
    }
    productFlavors {
        play {
        }
        gfan{
        }
        //...
    }
}
dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    testCompile 'junit:junit:4.12'
    compile 'com.android.support:appcompat-v7:23.3.0'
    compile 'com.android.support:design:23.3.0'
}