AutoreleasePool（自動釋放池）是OC中的一種內(nèi)存自動回收機制，它可以延遲加入AutoreleasePool中的變量release的時機。在正常情況下，創(chuàng)建的變量會在超出其作用域的時候release，但是如果將變量加入AutoreleasePool，那么release將延遲執(zhí)行。
AutoreleasePool實現(xiàn)原理
在終端中使用xcrun -sdk iphonesimulator clang -rewrite-objc main.m命令將下面的OC代碼重寫成C++的實現(xiàn)：
#import <UIKit/UIKit.h>
#import "AppDelegate.h"
int main(int argc, char * argv[]) {
@autoreleasepool {
return UIApplicationMain(argc, argv, nil, NSStringFromClass([AppDelegate class]));
}
}
在main.cpp文件代碼中我們找到main函數(shù)代碼如下：
extern "C" __declspec(dllimport) void * objc_autoreleasePoolPush(void);
extern "C" __declspec(dllimport) void objc_autoreleasePoolPop(void *);
struct __AtAutoreleasePool {
__AtAutoreleasePool() {atautoreleasepoolobj = objc_autoreleasePoolPush();}
~__AtAutoreleasePool() {objc_autoreleasePoolPop(atautoreleasepoolobj);}
void * atautoreleasepoolobj;
};
int main(int argc, char * argv[]) {
/* @autoreleasepool */ { __AtAutoreleasePool __autoreleasepool;
return UIApplicationMain(argc, argv, __null, NSStringFromClass(((Class (*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("AppDelegate"), sel_registerName("class"))));
}
}
這個結(jié)構(gòu)體會在初始化時調(diào)用 objc_autoreleasePoolPush() 方法，會在析構(gòu)時調(diào)用 objc_autoreleasePoolPop 方法。
這表明，我們的 main 函數(shù)在實際工作時其實是這樣的：
int main(int argc, const char * argv[]) {
{
void * atautoreleasepoolobj = objc_autoreleasePoolPush();
// do whatever you want
objc_autoreleasePoolPop(atautoreleasepoolobj);
}
return 0;
}
@autoreleasepool 只是幫助我們少寫了這兩行代碼而已，讓代碼看起來更美觀，然后要根據(jù)上述兩個方法來分析自動釋放池的實現(xiàn)。
它在 NSObject.mm （objc4）中的定義是這樣的：
class AutoreleasePoolPage {
magic_t const magic;
id *next;
pthread_t const thread;
AutoreleasePoolPage * const parent;//前節(jié)點
AutoreleasePoolPage *child;//后節(jié)點
uint32_t const depth;
uint32_t hiwat;
};
- magic 用于對當前 AutoreleasePoolPage 完整性的校驗
- thread 保存了當前頁所在的線程
每一個自動釋放池都是由一系列的 AutoreleasePoolPage 組成的，并且每一個 AutoreleasePoolPage 的大小都是 4096 字節(jié)（16 進制 0x1000）
#define I386_PGBYTES 4096
#define PAGE_SIZE I386_PGBYTES
雙向鏈表
自動釋放池中的 AutoreleasePoolPage 是以雙向鏈表的形式連接起來的：
parent 和 child 就是用來構(gòu)造雙向鏈表的指針。
parent和child就是用來構(gòu)造雙向鏈表的指針。parent指向前一個page, child指向下一個page。
一個AutoreleasePoolPage的空間被占滿時，會新建一個AutoreleasePoolPage對象，連接鏈表，后來的autorelease對象在新的page加入。
自動釋放池中的棧
如果我們的一個 AutoreleasePoolPage 被初始化在內(nèi)存的 0x100816000 ~ 0x100817000 中，它在內(nèi)存中的結(jié)構(gòu)如下：
其中有 56 bit 用于存儲 AutoreleasePoolPage 的成員變量，剩下的 0x100816038 ~ 0x100817000 都是用來存儲加入到自動釋放池中的對象。
begin() 和 end() 這兩個類的實例方法幫助我們快速獲取 0x100816038 ~ 0x100817000 這一范圍的邊界地址。
next 指向了下一個為空的內(nèi)存地址，如果 next 指向的地址加入一個 object，它就會如下圖所示移動到下一個為空的內(nèi)存地址中：
關(guān)于 hiwat 和 depth 在文章中并不會進行介紹，因為它們并不影響整個自動釋放池的實現(xiàn)，也不在關(guān)鍵方法的調(diào)用棧中。
POOL_SENTINEL（哨兵對象，最新的objc4為POOL_BOUNDARY）
到了這里，你可能想要知道 POOL_SENTINEL 到底是什么，還有它為什么在棧中。
首先回答第一個問題： POOL_SENTINEL 只是 nil 的別名。
#define POOL_SENTINEL nil（最新的objc4為# define POOL_BOUNDARY nil）
在每個自動釋放池初始化調(diào)用 objc_autoreleasePoolPush 的時候，都會把一個 POOL_SENTINEL push 到自動釋放池的棧頂，并且返回這個 POOL_SENTINEL 哨兵對象。
int main(int argc, const char * argv[]) {
{
void * atautoreleasepoolobj = objc_autoreleasePoolPush();
// do whatever you want
objc_autoreleasePoolPop(autoreleasepoolobj);
}
return 0;
}
上面的 atautoreleasepoolobj 就是一個 POOL_SENTINEL。
而當方法 objc_autoreleasePoolPop 調(diào)用時，就會向自動釋放池中的對象發(fā)送 release 消息，直到第一個 POOL_SENTINEL：
objc_autoreleasePoolPush 方法
了解了 POOL_SENTINEL，我們來重新回顧一下 objc_autoreleasePoolPush 方法：
void *objc_autoreleasePoolPush(void) {
return AutoreleasePoolPage::push();
}
它調(diào)用 AutoreleasePoolPage 的類方法 push，也非常簡單：
static inline void *push() {
return autoreleaseFast(POOL_SENTINEL);
}
在這里會進入一個比較關(guān)鍵的方法 autoreleaseFast，并傳入哨兵對象 POOL_SENTINEL：
static inline id *autoreleaseFast(id obj)
{
AutoreleasePoolPage *page = hotPage();
if (page && !page->full()) {
return page->add(obj);
} else if (page) {
return autoreleaseFullPage(obj, page);
} else {
return autoreleaseNoPage(obj);
}
}
上述方法分三種情況選擇不同的代碼執(zhí)行：
- 有 hotPage 并且當前 page 不滿
調(diào)用 page->add(obj) 方法將對象添加至 AutoreleasePoolPage 的棧中 - 有 hotPage 并且當前 page 已滿
調(diào)用 autoreleaseFullPage 初始化一個新的頁
調(diào)用 page->add(obj) 方法將對象添加至 AutoreleasePoolPage 的棧中 - 無 hotPage
調(diào)用 autoreleaseNoPage 創(chuàng)建一個 hotPage
調(diào)用 page->add(obj) 方法將對象添加至 AutoreleasePoolPage 的棧中
最后的都會調(diào)用 page->add(obj) 將對象添加到自動釋放池中。
hotPage 可以理解為當前正在使用的 AutoreleasePoolPage。hotPage 可以理解為當前正在使用的 AutoreleasePoolPage。
page->add 添加對象（當前 page 不滿）
id *add(id obj) 將對象添加到自動釋放池頁中：
id *add(id obj)
{
assert(!full());
unprotect();
id *ret = next; // faster than `return next-1` because of aliasing
*next++ = obj;
protect();
return ret;
}
這個方法其實就是一個壓棧的操作，將對象加入 AutoreleasePoolPage 然后移動棧頂?shù)闹羔槨?/p>
autoreleaseFullPage（當前 hotPage 已滿）
autoreleaseFullPage 會在當前的 hotPage 已滿的時候調(diào)用：
id *autoreleaseFullPage(id obj, AutoreleasePoolPage *page)
{
// The hot page is full.
// Step to the next non-full page, adding a new page if necessary.
// Then add the object to that page.
assert(page == hotPage());
assert(page->full() || DebugPoolAllocation);
do {
if (page->child) page = page->child;
else page = new AutoreleasePoolPage(page);
} while (page->full());
setHotPage(page);
return page->add(obj);
}
它會從傳入的 page 開始遍歷整個雙向鏈表，直到查找到一個未滿的 AutoreleasePoolPage
使用構(gòu)造器傳入 parent 創(chuàng)建一個新的 AutoreleasePoolPage，在查找到一個可以使用的 AutoreleasePoolPage 之后，會將該頁面標記成 hotPage，然后調(diào)動上面分析過的 page->add 方法添加對象。
autoreleaseNoPage（沒有 hotPage)
如果當前內(nèi)存中不存在 hotPage，就會調(diào)用 autoreleaseNoPage 方法初始化一個 AutoreleasePoolPage：
static id *autoreleaseNoPage(id obj) {
AutoreleasePoolPage *page = new AutoreleasePoolPage(nil);
setHotPage(page);
if (obj != POOL_SENTINEL) {
page->add(POOL_SENTINEL);
}
return page->add(obj);
}
既然當前內(nèi)存中不存在 AutoreleasePoolPage，就要從頭開始構(gòu)建這個自動釋放池的雙向鏈表，也就是說，新的 AutoreleasePoolPage 是沒有 parent 指針的。
初始化之后，將當前頁標記為 hotPage，然后會先向這個 page 中添加一個 POOL_SENTINEL 對象，來確保在 pop 調(diào)用的時候，不會出現(xiàn)異常。
最后，將 obj 添加到自動釋放池中。
objc_autoreleasePoolPop 方法
同樣，回顧一下上面提到的 objc_autoreleasePoolPop 方法：
void objc_autoreleasePoolPop(void *ctxt) {
AutoreleasePoolPage::pop(ctxt);
}
看起來傳入任何一個指針都是可以的，但是在整個工程并沒有發(fā)現(xiàn)傳入其他對象的例子。不過在這個方法中傳入其它的指針也是可行的，會將自動釋放池釋放到相應(yīng)的位置。
我們一般都會在這個方法中傳入一個哨兵對象 POOL_SENTINEL，如下圖一樣釋放對象：
AutoreleasePoolPage::pop 方法的調(diào)用：
static inline void pop(void *token) {
AutoreleasePoolPage *page = pageForPointer(token);
id *stop = (id *)token;
page->releaseUntil(stop);
if (page->child) {
if (page->lessThanHalfFull()) {
page->child->kill();
} else if (page->child->child) {
page->child->child->kill();
}
}
}
在這個方法中刪除了大量無關(guān)的代碼，以及對格式進行了調(diào)整。
該靜態(tài)方法總共做了三件事情：
使用 pageForPointer 獲取當前 token 所在的 AutoreleasePoolPage
調(diào)用 releaseUntil 方法釋放棧中的對象，直到 stop
調(diào)用 child 的 kill 方法
pageForPointer 獲取 AutoreleasePoolPage
pageForPointer 方法主要是通過內(nèi)存地址的操作，獲取當前指針所在頁的首地址：
static AutoreleasePoolPage *pageForPointer(const void *p) {
return pageForPointer((uintptr_t)p);
}
static AutoreleasePoolPage *pageForPointer(uintptr_t p) {
AutoreleasePoolPage *result;
uintptr_t offset = p % SIZE;
assert(offset >= sizeof(AutoreleasePoolPage));
result = (AutoreleasePoolPage *)(p - offset);
result->fastcheck();
return result;
}
將指針與頁面的大小，也就是 4096 取模，得到當前指針的偏移量，因為所有的 AutoreleasePoolPage 在內(nèi)存中都是對齊的：
p = 0x100816048
p % SIZE = 0x48
result = 0x100816000
而最后調(diào)用的方法 fastCheck() 用來檢查當前的 result 是不是一個 AutoreleasePoolPage。
通過檢查
magic_t結(jié)構(gòu)體中的某個成員是否為0xA1A1A1A1。
releaseUntil 釋放對象
releaseUntil 方法的實現(xiàn)如下：
void releaseUntil(id *stop) {
while (this->next != stop) {
AutoreleasePoolPage *page = hotPage();
while (page->empty()) {
page = page->parent;
setHotPage(page);
}
page->unprotect();
id obj = *--page->next;
memset((void*)page->next, SCRIBBLE, sizeof(*page->next));
page->protect();
if (obj != POOL_SENTINEL) {
objc_release(obj);
}
}
setHotPage(this);
}
它的實現(xiàn)還是很容易的，用一個 while 循環(huán)持續(xù)釋放 AutoreleasePoolPage 中的內(nèi)容，直到 next 指向了 stop 。
使用 memset 將內(nèi)存的內(nèi)容設(shè)置成 SCRIBBLE，然后使用 objc_release 釋放對象。
kill() 方法
到這里，沒有分析的方法就只剩下 kill 了，而它會將當前頁面以及子頁面全部刪除：
void kill() {
AutoreleasePoolPage *page = this;
while (page->child) page = page->child;
AutoreleasePoolPage *deathptr;
do {
deathptr = page;
page = page->parent;
if (page) {
page->unprotect();
page->child = nil;
page->protect();
}
delete deathptr;
} while (deathptr != this);
}
autorelease 方法
我們已經(jīng)對自動釋放池生命周期有一個比較好的了解，最后需要了解的話題就是 autorelease 方法的實現(xiàn)，先來看一下方法的調(diào)用棧：
- [NSObject autorelease]
└── id objc_object::rootAutorelease()
└── id objc_object::rootAutorelease2()
└── static id AutoreleasePoolPage::autorelease(id obj)
└── static id AutoreleasePoolPage::autoreleaseFast(id obj)
├── id *add(id obj)
├── static id *autoreleaseFullPage(id obj, AutoreleasePoolPage *page)
│ ├── AutoreleasePoolPage(AutoreleasePoolPage *newParent)
│ └── id *add(id obj)
└── static id *autoreleaseNoPage(id obj)
├── AutoreleasePoolPage(AutoreleasePoolPage *newParent)
└── id *add(id obj)
在 autorelease 方法的調(diào)用棧中，最終都會調(diào)用上面提到的 autoreleaseFast 方法，將當前對象加到 AutoreleasePoolPage 中。
這一小節(jié)中這些方法的實現(xiàn)都非常容易，只是進行了一些參數(shù)上的檢查，最終還要調(diào)用 autoreleaseFast 方法：
inline id objc_object::rootAutorelease() {
if (isTaggedPointer()) return (id)this;
if (prepareOptimizedReturn(ReturnAtPlus1)) return (id)this;
return rootAutorelease2();
}
__attribute__((noinline,used)) id objc_object::rootAutorelease2() {
return AutoreleasePoolPage::autorelease((id)this);
}
static inline id autorelease(id obj) {
id *dest __unused = autoreleaseFast(obj);
return obj;
}
由于在上面已經(jīng)分析過 autoreleaseFast 方法的實現(xiàn)，這里就不會多說了。
小結(jié)
整個自動釋放池 AutoreleasePool 的實現(xiàn)以及 autorelease 方法都已經(jīng)分析完了，我們再來回顧一下文章中的一些內(nèi)容：
- 自動釋放池是由 AutoreleasePoolPage 以雙向鏈表的方式實現(xiàn)的
- 當對象調(diào)用 autorelease 方法時，會將對象加入 AutoreleasePoolPage 的棧中
- 調(diào)用 AutoreleasePoolPage::pop 方法會向棧中的對象發(fā)送 release 消息
Autorelease返回值的快速釋放機制
值得一提的是，ARC下，runtime有一套對autorelease返回值的優(yōu)化策略。
比如一個工廠方法：
+ (instancetype)createSark {
return [self new];
}
// caller
Sark *sark = [Sark createSark];
秉著誰創(chuàng)建誰釋放的原則，返回值需要是一個autorelease對象才能配合調(diào)用方正確管理內(nèi)存，于是乎編譯器改寫成了形如下面的代碼：
+ (instancetype)createSark {
id tmp = [self new];
return objc_autoreleaseReturnValue(tmp); // 代替我們調(diào)用autorelease
}
// caller
id tmp = objc_retainAutoreleasedReturnValue([Sark createSark]) // 代替我們調(diào)用retain
Sark *sark = tmp;
objc_storeStrong(&sark, nil); // 相當于代替我們調(diào)用了release
一切看上去都很好，不過既然編譯器知道了這么多信息，干嘛還要勞煩autorelease這個開銷不小的機制呢？于是乎，runtime使用了一些黑魔法將這個問題解決了。
autoreleasepool使用
使用容器的block版本的枚舉器時，內(nèi)部會自動添加一個AutoreleasePool：
[array enumerateObjectsUsingBlock:^(id obj, NSUInteger idx, BOOL *stop) {
// 這里被一個局部@autoreleasepool包圍著
}];
在普通for循環(huán)和for in循環(huán)中沒有，所以，還是新版的block版本枚舉器更加方便。for循環(huán)中遍歷產(chǎn)生大量autorelease變量時，就需要手加局部AutoreleasePool
for (/**/) {
@autoreleasepool {
NSString *str = [NSString stringWithFormat:@"xxx"];
}
}
AutoreleasePool的創(chuàng)建和銷毀
App啟動后，蘋果在主線程 RunLoop 里注冊了兩個 Observer，其回調(diào)都是 _wrapRunLoopWithAutoreleasePoolHandler()。
第一個 Observer 監(jiān)視的事件是 Entry(即將進入Loop)，其回調(diào)內(nèi)會調(diào)用 _objc_autoreleasePoolPush() 創(chuàng)建自動釋放池。其 order 是-2147483647，優(yōu)先級最高，保證創(chuàng)建釋放池發(fā)生在其他所有回調(diào)之前。
第二個 Observer 監(jiān)視了兩個事件： BeforeWaiting(準備進入休眠) 時調(diào)用_objc_autoreleasePoolPop() 和 _objc_autoreleasePoolPush() 釋放舊的池并創(chuàng)建新池；Exit(即將退出Loop) 時調(diào)用 _objc_autoreleasePoolPop() 來釋放自動釋放池。這個 Observer 的 order 是 2147483647，優(yōu)先級最低，保證其釋放池子發(fā)生在其他所有回調(diào)之后。
在主線程執(zhí)行的代碼，通常是寫在諸如事件回調(diào)、Timer回調(diào)內(nèi)的。這些回調(diào)會被 RunLoop 創(chuàng)建好的 AutoreleasePool 環(huán)繞著，所以不會出現(xiàn)內(nèi)存泄漏，開發(fā)者也不必顯示創(chuàng)建 Pool 了。
子線程autorelease對象的釋放時機
@property (weak) id obj;
- (void)viewDidLoad {
[super viewDidLoad];
// Do any additional setup after loading the view.
[NSThread detachNewThreadSelector:@selector(createAndConfigObserverInSecondaryThread) toTarget:self withObject:nil];
}
- (void)createAndConfigObserverInSecondaryThread{
__autoreleasing id test = [NSObject new];
NSLog(@"obj = %@", test);
_obj = test;
[[NSThread currentThread] setName:@"test runloop thread"];
NSLog(@"thread ending");
}
_obj = test;代碼行斷點
watchpoint set variable _obj（監(jiān)聽_obj的銷毀）
沒有runloop
static void tls_dealloc(void *p)
{
if (p == (void*)EMPTY_POOL_PLACEHOLDER) {
// No objects or pool pages to clean up here.
return;
}
// reinstate TLS value while we work
setHotPage((AutoreleasePoolPage *)p);
if (AutoreleasePoolPage *page = coldPage()) {
if (!page->empty()) pop(page->begin()); // pop all of the pools
if (DebugMissingPools || DebugPoolAllocation) {
// pop() killed the pages already
} else {
page->kill(); // free all of the pages
}
}
// clear TLS value so TLS destruction doesn't loop
setHotPage(nil);
}
在這找到了if (!page->empty()) pop(page->begin());這句關(guān)鍵代碼。再往上看一點，在_pthread_exit時會執(zhí)行下面這個函數(shù)
void
_pthread_tsd_cleanup(pthread_t self)
{
#if !VARIANT_DYLD
int j;
// clean up dynamic keys first
for (j = 0; j < PTHREAD_DESTRUCTOR_ITERATIONS; j++) {
pthread_key_t k;
for (k = __pthread_tsd_start; k <= self->max_tsd_key; k++) {
_pthread_tsd_cleanup_key(self, k);
}
}
self->max_tsd_key = 0;
// clean up static keys
for (j = 0; j < PTHREAD_DESTRUCTOR_ITERATIONS; j++) {
pthread_key_t k;
for (k = __pthread_tsd_first; k <= __pthread_tsd_max; k++) {
_pthread_tsd_cleanup_key(self, k);
}
}
#endif // !VARIANT_DYLD
}
也就是說thread在退出時會釋放自身資源，這個操作就包含了銷毀autoreleasepool，在tls_delloc中，執(zhí)行了pop操作。
這個實驗本該到此就結(jié)束了，對于文章開始的問題在這里也已經(jīng)有了答案，線程在銷毀時會清空autoreleasepool。但是上述這個例子中的線程并沒有加入runloop，只是一個一次性的線程?，F(xiàn)在給這個線程加入runloop來看看效果會是怎么樣的。
有runloop
參考的GNU實現(xiàn)結(jié)論：
在GNU的實現(xiàn)中，targer執(zhí)行相應(yīng)的action操作是在[self acceptInputForMode: mode beforeDate: d];中，可以看到在runMode: (NSString)mode beforeDate: (NSDate)date方法中，其實是包裹了一個autoreleasepool的，也就是arp，如果在深入一些函數(shù)里面，發(fā)現(xiàn)其實很多地方都有autoreleasepool的函數(shù)，所以即使是我們自定義的source，執(zhí)行函數(shù)中沒有釋放autoreleasepool的操作也不用擔心，系統(tǒng)在各個關(guān)鍵入口都給我們加了這些操作。
文章到此就告一段落了，還有一種port source，也就是source1，這種source我沒有去看，好奇的同學可以去看一看如果有什么不對我們一起討論。
總結(jié)
- 子線程在使用autorelease對象時，如果沒有autoreleasepool會在autoreleaseNoPage中懶加載一個出來。
- 在runloop的run:beforeDate，以及一些source的callback中，有autoreleasepool的push和pop操作，總結(jié)就是系統(tǒng)在很多地方都差不多autorelease的管理操作。
- 就算插入沒有pop也沒關(guān)系，在線程exit的時候會釋放資源，執(zhí)行AutoreleasePoolPage::tls_dealloc，在這里面會清空autoreleasepool。
參考：
https://draveness.me/autoreleasepool#AutoreleasePoolPage
http://blog.sunnyxx.com/2014/10/15/behind-autorelease/
https://suhou.github.io/2018/01/21/%E5%B8%A6%E7%9D%80%E9%97%AE%E9%A2%98%E7%9C%8B%E6%BA%90%E7%A0%81----%E5%AD%90%E7%BA%BF%E7%A8%8BAutoRelease%E5%AF%B9%E8%B1%A1%E4%BD%95%E6%97%B6%E9%87%8A%E6%94%BE/
https://blog.ibireme.com/2015/05/18/runloop/
Demo地址：
autoreleasepool
