在國家藥監(jiān)局藥審中心2020年發(fā)布的《藥物臨床試驗數據遞交指導原則（試行）》這份文件中，其中 臨床試驗數據相關資料的格式 這部分里面有這樣一個要求：

每個字符型變量的長度，應該設置為在此研究所有數據集里該變量的最大實際變量值長度，有效控制文件的大小。

image.png

也就是說，我們在創(chuàng)建SPEC的過程中，可能會為變量提前設定好長度，但是在遞交的過程中，需要用變量實際的長度進行遞交。

所以今天展示一下如何重新為變量設定長度。

proc datasets library = work memtype = data kill nolist;   
run;    
quit;

data template;
  length make $30 model $80 type  $200; 
  make="";
  model="";
  type=""; 
run;

data test;
  set sashelp.cars;
run;

data lengthtest;
  make="今天是一個好日子";output;
  make="SAS Pro length test";output;
  
  model="2574萬元獎金今天領了";output;
  type="這僅僅只是一個測試，測試長度的測試，看下實際長度是多少";output;
  DriveTrain="my length is 15";output;


run;

data lengthtest2; 
  set template lengthtest; 
run;


%macro adjlen (dsn=,exc=,dsout=);
 
  proc contents data=&dsn out= tempcont(keep=name length type where=(TYPE eq 2 and NAME not in (&exc)))  noprint;
  run;

  proc sql noprint;
    select 'max (length('||compress(name)||')) as '||compress(name) into: var separated by ', ' from tempcont;
  quit;
  %put &var;

  proc sql noprint; 
    create table max_count as select &var from &dsn; 
  quit; 

  proc transpose data= max_count out= tp;
  run;

  proc sql noprint;
    select compress(_name_)||' character ('||strip(put(col1,best.))||')' into: variable separated by ', ' from tp; 
    alter table &dsn modify &variable;
  quit;
  %put &variable;

  data &dsout;
    set  &dsn;
  run;

/*  proc datasets lib=work memtype=data nolist; delete tempcont chk max_count tp ;*/
/*  quit;*/
%mend;
%adjlen(dsn=lengthtest2,exc=%str("DriveTrain"),dsout=lengthout);

邏輯就是

先通過proc contents獲取目標數據集的變量
然后通過proc sql獲取每個變量的實際長度，并轉換成宏變量
最后通過proc sql的alter和modify語句重新為變量賦值長度。

上面的程序自己看吧，這里順便講講proc sql的alter語句

Syntax:

Adds columns to, drops columns from, and changes column attributes in an existing table. Adds, modifies, and drops integrity constraints from an existing table.

①：增加新變量

data test;
  length subjid $20. x $8 y 8;
  subjid="S001";x="ABC";y=100;output;
  subjid="S002";x="XYZ";y=50;output;
  label x="字母" y="數字";
run;

proc sql;
  alter table test add newvar character,paramn integer,mhstdtc date ;
quit;

image.png

newvar /paramn /mhstdtc 是新變量，后面跟著的是 這個變量是什么類型的，字符型還是數值型。用alter語句生成新變量，變量的值初始時都是空，如果我們要為變量賦值，只能通過proc sql的update語句。
②：update語句賦值

proc sql;
  alter table test add newvar character,paramn integer,mhstdtc date ;
quit;

proc sql;
  update  test set newvar="SAS PRO" ,paramn=7,mhstdtc=23147 ;  /*會對整個變量都填充值，不需要重新創(chuàng)建新的數據集就能查看內容*/
quit;

proc sql;
  update  test set newvar="SAS PRO" ,paramn=7,mhstdtc=23147 where subjid="S001";  /*對指定行添加值；這樣需要重新創(chuàng)建一個數據集，需要注意的是添加日期型變量的時候只能是數字*/
quit;

data test2;
  set test;
run;

image.png

③：alter刪除變量

proc sql;
  alter table test2 drop newvar  ;
quit;

④：改變變量屬性，比如長度或者標簽，需要通過alter和modify語句實現，注意的是對數值型變量無效。

proc sql;
  alter table test modify subjid char(4) label="受試者",x char(3)  ;
quit;

image.png