libjsonutils
├── CMakeLists.txt
├── include
│   └── jsonutils
│       └── json_utils.h
├── src
│   ├── file_utils.h
│   └── json_utils.cpp
└── test
    ├── CMakeLists.txt
    └── src
        └── test_main.cpp

我們注意到，include/中有json_utils.h頭文件，這是我們想對外暴露的公共文件；而src/中有額外的頭文件file_utils.h，這個(gè)文件僅在構(gòu)建中使用，不想對外暴露。這兩個(gè)頭文件都應(yīng)該在構(gòu)建的時(shí)候被包含（include） ；另一方面，jsontuils的使用者又僅僅需要知道公開的頭文件，因此INTERFACE_INCLUDE_DIRS只需要包含include/，而沒有src/。
為此，可以在CMakeLists.txt使用如下代碼（這里使用了CMake的generator expression特性）：

add_library(JSONUtils src/json_utils.cpp)
target_include_directories(JSONUtils
    PUBLIC 
        $<INSTALL_INTERFACE:include>    
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    PRIVATE
        ${CMAKE_CURRENT_SOURCE_DIR}/src
)

對于目標(biāo)的依賴項(xiàng)，同樣有INTERFACE和PRIVATE的區(qū)分。
比如：

find_package(Boost 1.55 REQUIRED COMPONENTS regex)
find_package(RapidJSON 1.0 REQUIRED MODULE)

target_link_libraries(JSONUtils
    PUBLIC
        Boost::boost RapidJSON::RapidJSON
    PRIVATE
        Boost::regex
)

這種情況，rapidjson和Boost::boost都應(yīng)當(dāng)被定義成接口類型的依賴，并被傳遞到目標(biāo)的使用者那邊，因?yàn)橛脩羲鶎?dǎo)入的頭文件中調(diào)用了這兩個(gè)庫的工具。這意味著JSONUtils的用戶不僅需要JSONUtils的接口屬性，同時(shí)也需要其接口類型的依賴的接口屬性（在我們的情況下，定義了boost和rapidjson的公共頭文件），甚至接口類型的依賴的接口類型的依賴的接口屬性，等等。
對于CMake而言，它會(huì)將Boost::boost和RapidJSON::RapidJson的所有接口屬性添加到JSONUtils的接口屬性中。這意味著JSONUtils的用戶會(huì)傳遞獲取依賴鏈條上所有的接口屬性。
另一方面Boost::regex則僅在我們目標(biāo)的內(nèi)部使用，并且可以作為私有依賴。這種情況下，Boost::regex的接口屬性會(huì)被添加到JSONUtils的私有屬性中，而不會(huì)傳遞到用戶那里。

導(dǎo)入目標(biāo)

當(dāng)我們執(zhí)行find_package(Boost 1.55 REQUIRED COMPONENTS regex)的時(shí)候，CMake實(shí)際執(zhí)行了FindBoost.cmake腳本，并由此導(dǎo)入了目標(biāo)Boost::boost和Boost::regex，這是為什么我們能通過target_link_libraries()來依賴這些目標(biāo)。
然而部分第三方庫并不那么守規(guī)矩，比如RapidJSON的RapidJSONConfig.cmake：

get_filename_component(RAPIDJSON_CMAKE_DIR "${CMAKE_CURRENT_LIST_FILE}" PATH)
set(RAPIDJSON_INCLUDE_DIRS "/usr/include")
message(STATUS "RapidJSON found. Headers: ${RAPIDJSON_INCLUDE_DIRS}")

它實(shí)際上并沒有定義目標(biāo)，只是定義了RAPIDJSON_INCLUDE_DIRS一個(gè)變量。
這種情況，我們可以自己編寫FindRapidJSON.cmake文件：

# FindRapidJSON.cmake
#
# Finds the rapidjson library
#
# This will define the following variables
#
#    RapidJSON_FOUND
#    RapidJSON_INCLUDE_DIRS
#
# and the following imported targets
#
#     RapidJSON::RapidJSON
#
# Author: Pablo Arias - pabloariasal@gmail.com

find_package(PkgConfig)
pkg_check_modules(PC_RapidJSON QUIET RapidJSON)

find_path(RapidJSON_INCLUDE_DIR
    NAMES rapidjson.h
    PATHS ${PC_RapidJSON_INCLUDE_DIRS}
    PATH_SUFFIXES rapidjson
)

set(RapidJSON_VERSION ${PC_RapidJSON_VERSION})

mark_as_advanced(RapidJSON_FOUND RapidJSON_INCLUDE_DIR RapidJSON_VERSION)

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(RapidJSON
    REQUIRED_VARS RapidJSON_INCLUDE_DIR
    VERSION_VAR RapidJSON_VERSION
)

if(RapidJSON_FOUND)
    set(RapidJSON_INCLUDE_DIRS ${RapidJSON_INCLUDE_DIR})
endif()

if(RapidJSON_FOUND AND NOT TARGET RapidJSON::RapidJSON)
    add_library(RapidJSON::RapidJSON INTERFACE IMPORTED)
    set_target_properties(RapidJSON::RapidJSON PROPERTIES
        INTERFACE_INCLUDE_DIRECTORIES "${RapidJSON_INCLUDE_DIR}"
    )
endif()

導(dǎo)出自己的庫

如果想讓自己的工程能夠被別人通過簡單的命令使用：

find_package(JSONUtils 1.0 REQUIRED)
target_link_libraries(example JSONUtils::JSONUtils)

我們需要做兩件事：首先，需要導(dǎo)出目標(biāo)JSONUtils::JSONUtils；隨后，需要允許下游應(yīng)用find_package(JSONUtils)的時(shí)候能夠?qū)脒@個(gè)目標(biāo)。
首先我們要將目標(biāo)導(dǎo)出到一個(gè)能夠?qū)肽繕?biāo)的JSONUtilsTargets.cmake：

include(GNUInstallDirs)
install(TARGETS JSONUtils
    EXPORT jsonutils-targets
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
)

install(EXPORT jsonutils-targets
  FILE
    JSONUtilsTargets.cmake
  NAMESPACE
    JSONUtils::
  DESTINATION
    ${CMAKE_INSTALL_LIBDIR}/cmake/JSONUtils
)

這樣，我們安裝了一個(gè)JSONUtilsTargets.cmake文件，這里面包含了導(dǎo)入JSONUtils的命令，只需要在別的文件中使用這個(gè)文件就可以導(dǎo)入。
下一步，我們制作一個(gè)JSONUtilsConfig.cmake：

get_filename_component(JSONUtils_CMAKE_DIR "${CMAKE_CURRENT_LIST_FILE}" PATH)
include(CMakeFindDependencyMacro)

find_dependency(Boost 1.55 REQUIRED COMPONENTS regex)
find_dependency(RapidJSON 1.0 REQUIRED MODULE)

if(NOT TARGET JSONUtils::JSONUtils)
    include("${JSONUtils_CMAKE_DIR}/JSONUtilsTargets.cmake")
endif()

大型工程

在第一部分介紹的都是基本命令，對于大型工程來說，會(huì)用到一些不太常用的概念或者功能。

什么是Project？

對于大型工程來說，project的概念變得更為重要。通常來說，簡單的工程只需要有一個(gè)project，而對于復(fù)雜的工程，有可能會(huì)出現(xiàn)project的嵌套。
Project通常指的是一個(gè)邏輯上相對獨(dú)立、完整，能夠獨(dú)立編譯的集合。通常來說，如果某一個(gè)CMakeLists.txt文件中出現(xiàn)了project()命令，那你應(yīng)該能以該文件所在的目錄為根目錄進(jìn)行一次完整的編譯。
（https://stackoverflow.com/questions/26878379/in-cmake-what-is-a-project）該命令也會(huì)如上文所說的，影響CMAKE_PROJECT_NAME等變量的值。

文件組織

文件組織方式就見仁見智了。不過通常來說，為了方便cmake的管理，建議以modules的形式扁平地組織，并且在每個(gè)module中設(shè)置有限的文件層次。比如說我們有一個(gè)moduleA，其下面有src、include和test三個(gè)目錄，而在include目錄下面，再根據(jù)具體的功能分為不同的目錄，再下一級就只有頭文件。
這樣在添加頭文件目錄的時(shí)候，統(tǒng)一添加為*/moduleA/include，而在源文件或者其他頭文件包含的時(shí)候，可以從include下一級目錄開始：#include "abc/a.hpp"。

模塊下的CMakeLists.txt

在一個(gè)模塊下，可以遵循以下規(guī)律編寫CMakeLists.txt：

1. 設(shè)置內(nèi)部模塊依賴
2. 搜索內(nèi)部依賴模塊的頭文件和庫文件
3. 設(shè)置項(xiàng)目內(nèi)第三方模塊依賴
4. 搜索項(xiàng)目內(nèi)第三方模塊依賴庫的頭文件和庫文件
5. 設(shè)置和搜索本地的外部依賴庫
6. 添加編譯目標(biāo)
7. 包含頭文件目錄、鏈接庫文件
8. 設(shè)置安裝規(guī)則（比如一些配置文件）
9. 設(shè)置單元測試

頭文件暴露

有的時(shí)候，有些頭文件只供內(nèi)部使用，不想暴露在install后的頭文件目錄里。那就將其放在src路徑下。

依賴順序管理

CMake中鏈接庫的順序是a依賴b，那么b放在a的后面。
例如目標(biāo)test依賴a庫、b庫， a庫又依賴b庫，那么順序如下：
target_link_libraries(test a b)
另外，假如目標(biāo)test依賴a庫， a庫又依賴b庫，但test不直接依賴b庫，那么test不用鏈接b庫。
如果在一個(gè)工程中有多個(gè)target，那么可以用add_dependencies(<target> [<target-dependency>]...)命令，來定義依賴關(guān)系。這樣CMake會(huì)首先編譯被依賴的目標(biāo)，隨后再編譯依賴的目標(biāo)。

INTERFACE|PUBLIC|PRIVATE

INTERFACE|PUBLIC|PRIVATE

如何調(diào)試

nm -a <target>命令查看符號表。
如果出現(xiàn)

Undefined symbols for architecture x86_64:
  "_main"

可能是在沒有main的cpp文件定義add_executable。
構(gòu)造函數(shù)和析構(gòu)函數(shù)聲明了就要定義，要么用default。