估計政策效應(yīng)常用的方法有：工具變量法、斷點回歸、傾向得分匹配法、雙重差分法、合成控制法等。我們在這里介紹雙重差分法。
一、模型引入
假設(shè)現(xiàn)要修一條鐵路，其必然會有穿過的和沒有穿過的城市?，F(xiàn)在我們想知道鐵路修好以后，被鐵路穿過的城市經(jīng)濟增長是不是更快了？
為了回答上面的問題，我們至少需要觀察兩期情況即修鐵路前（t=0）和修鐵路后（t=1）。同時我們設(shè)如果城市i被穿過，我們記Di=1，反之Di=0。
模型引入
如上圖的處理效應(yīng)即為“修鐵路”這項政策的效應(yīng)。
treat組（處理組）：受政策干預——結(jié)果Di=1
control組（對照組）：未受政策干預——結(jié)果Di=0
以上的關(guān)鍵在于處理組如果未受到政策干預，其時間效應(yīng)或趨勢應(yīng)該與控制組一樣。
二、前提條件
1.使用前提
（1）政策不能是“一刀切”類型，即存在受政策影響的實驗組和不受政策影響的對照組
（2）至少兩年的面板數(shù)據(jù)，如果是截面數(shù)據(jù)一般也別考慮了
2.模型前提
（1）平行趨勢（CT）假設(shè)：處理組和對照組有共同趨勢，在政策干預之前，處理組和控制組的結(jié)果效應(yīng)的趨勢應(yīng)該是一樣的。
（2）SUTVA條件：政策干預只影響處理組，不會對控制組產(chǎn)生交互影響，或者政策干預不會產(chǎn)生外溢效應(yīng)；
（3）線性形式條件：潛在結(jié)果變量同處理變量和時間變量滿足線性條件。
由此可見DID的使用條件較為嚴苛，并不能隨意使用。
三、模型構(gòu)造
模型構(gòu)造1
du 表明了一刀切政策無法適用DID；dt表明了截面數(shù)據(jù)無法使用。
模型構(gòu)造2
四、穩(wěn)健性檢驗
為了證明所有的效應(yīng)是由政策實施所引起的，必須做穩(wěn)健性檢驗，主要體現(xiàn)在兩個方面：
1.平行趨勢檢驗
如果是多年面板數(shù)據(jù)可以通過畫圖或者回歸的方法來檢驗平行趨勢假設(shè)。
（1）畫圖：畫出實驗組時期和對照組時期的時間趨勢圖，如果兩條線的走勢完全一致或基本一致，說明CT假設(shè)是滿足的。
（2）回歸：將模型構(gòu)造中dt項改為“年份虛擬變量”，政策實施前有a年就有a個年份虛擬變量，以及與du相乘的a個交互項。此時交互項反映的是“政策實施前年份，實驗組和對照組的差異”。如果這a個交互項不顯著，即說明政策實施前實驗組和對照組不存在明顯的差別，從而滿足CT假設(shè)。一般，“都不顯著”可以稍微放松，即便存在一兩個顯著的情況，但只要a個交互項聯(lián)合不顯著，也是滿足CT假設(shè)。
2.安慰劑檢驗
安慰劑檢驗核心思想即即虛構(gòu)處理組進行回歸。
第一步：選取政策實施之前的年份進行處理，例如，政策發(fā)生在2014年，研究區(qū)間為2013-2015年。我們可以把研究區(qū)間向前移動到2011-2013年，并假定政策實施年份為2012年，然后進行回歸。
第二步：選取已知的并不受政策實施影響的群組作為處理組進行回歸。
如果不同虛構(gòu)方式下的DID估計量的回歸結(jié)果依然顯著，說明原來的估計結(jié)果很有可能出現(xiàn)了偏誤。
此外還可以利用不同不同的對照組進行回歸，看研究結(jié)論是否依然一致?；蛘哌x取一個完全不受政策干預影響的因素作為被解釋變量進行回歸，如果DID估計量的回歸結(jié)果依然顯著，說明原來的估計結(jié)果很有可能出現(xiàn)了偏誤。
注：以上如果回歸結(jié)果顯著，說明原結(jié)果是一定有問題的，而如果回歸結(jié)果不顯著，并不一定能表明原結(jié)果沒問題。
五、Stata命令詳解
1.數(shù)據(jù)下載地址
http://dss.princeton.edu/training/Panel101.dta
2.數(shù)據(jù)背景介紹
歷史上A、B、C、D、E、F、G這7個地區(qū)非常相似，然而1994年后E、F和G三個地區(qū)（實驗組）頒布了一項政策，其余4個地區(qū)（控制組）沒有。
3.DID基準回歸
*定義工作環(huán)境
cd C:\Users\Administrator\Desktop
*導入數(shù)據(jù)
use panel101,clear
*假設(shè)政策執(zhí)行時間為1994年，設(shè)置虛擬變量
gen time = (year >= 1994)&!missing(year)
*假設(shè)政策執(zhí)行地為大于4的地方，設(shè)置虛擬變量
gen treated = (country >4)&!missing(country)
*構(gòu)建DID估計量，即時間和空間的交互項
gen did = time*treated
*第一種DID回歸設(shè)計
reg y did time treated,r
方法1
顯然在10%水平上，政策實施有顯著的負效應(yīng)
*第二種DID回歸設(shè)計
reg y time##treated,r
方法2
同樣的在第二種方法中，無需設(shè)置交互項，結(jié)果是一樣的
*第三種DID回歸設(shè)計
**安裝外部命令
ssc install diff
**估計DID
diff y, t(treated) p(time)
方法3
在第三種方法里，直接使用diff命令，快速實現(xiàn)方法一的三步驟，結(jié)果一樣
4.平行趨勢檢驗
以上的基準回歸只有當?shù)貐^(qū)在政策前足夠相似才能夠保證DID提取的是政策的因果效應(yīng)，所以研究者需要知道兩組地區(qū)在政策前有多大差異。實現(xiàn)這一目標的方法是將年份虛擬變量乘以實驗組虛擬變量，這一交互項就可以捕捉兩組地區(qū)在每一年份的差異。
如果兩組地區(qū)的確有著平行趨勢的話，那么預期在1994年前的那些交互項的回歸結(jié)果將不顯著，而1994年后的將顯著。
**生成年份虛擬變量與實驗組虛擬變量的交互項(此處選在政策前后各3年)
gen Dyear = year-1994
gen Before3 = (Dyear==-3&treated==1)
gen Before2 = (Dyear==-2&treated==1)
gen Before1 = (Dyear==-1&treated==1)
gen Current = (Dyear==0&treated==1)
gen After1 = (Dyear==1&treated==1)
gen After2 = (Dyear==2&treated==1)
gen After3 = (Dyear==3&treated==1)
**將以上交互項作為解釋變量進行回歸
xtreg y time treated Before3 Before2 Before1 Current After1 After2 After3 i.year, fe
est sto reg
CT檢驗1
可以看出Before3 Before2 Before1 的系數(shù)均不顯著，After1的系數(shù)負向顯著
**采用coefplot命令畫圖
ssc install coefplot
coefplot reg,keep(Before3 Before2 Before1 Current After1 After2 After3) vertical recast(connect) yline(0)
保留關(guān)鍵變量: keep(Before2 Before1 Current After1 After2 After3_)*
轉(zhuǎn)置: vertical*
系數(shù)連線，觀察動態(tài)效果: recast(connect)*
增加直線y=0: yline(0)*
CT檢驗2
結(jié)果發(fā)現(xiàn)系數(shù)在政策前的確在0附近波動，而政策后一年系數(shù)顯著為負，但很快又回到0附近。這說明實驗組和控制組的確是可以進行比較的，而政策效果可能出現(xiàn)在頒布后一年，隨后又很快消失。
六、參考資料
1.雙重差分模型的平行趨勢假定如何檢驗？ —— coefplot命令來告訴你
2.那些年，我們用過的DID
3.DID與政策評估（附Stata實現(xiàn)）
4.【Stata教程】如何進行平行趨勢檢驗
55人點贊
作者：凡有言說
鏈接：http://www.itdecent.cn/p/cd8cd6904dcc
來源：簡書
著作權(quán)歸作者所有。商業(yè)轉(zhuǎn)載請聯(lián)系作者獲得授權(quán)，非商業(yè)轉(zhuǎn)載請注明出處。
