面試題：AutoReleasePool的實現(xiàn)機制

其實是一種類似棧結構的進棧出棧操作,以棧為結點構成的雙向鏈表結構,每一個線程的 autoreleasepool 其實就是一個指針的堆棧
單個自動釋放池的執(zhí)行過程就是

objc_autoreleasePoolPush() —> [object autorelease] —> objc_autoreleasePoolPop(void *)

一，概念

AutoreleasePool 顧名思義是自動釋放池的概念，就是將iOS項目開發(fā)中的對象的內(nèi)存通通都放入一個池子中，統(tǒng)一管理，如果最后這個內(nèi)存池釋放了，那所有的對象也就銷毀了。本文主要轉載來自這里

AutoreleasePool（自動釋放池）是OC中的一種內(nèi)存自動回收機制，它可以延遲加入AutoreleasePool中的變量release的時機。在正常情況下，創(chuàng)建的變量會在超出其作用域的時候release，但是如果將變量加入AutoreleasePool，那么release將延遲執(zhí)行。

二，AutoreleasePool的創(chuàng)建和釋放

2.1創(chuàng)建

  • App啟動后，蘋果在主線程 RunLoop 里注冊了兩個 Observer，其回調(diào)都是 _wrapRunLoopWithAutoreleasePoolHandler()。

  • 第一個 Observer 監(jiān)視的事件是 Entry(即將進入Loop)，其回調(diào)內(nèi)會調(diào)用 _objc_autoreleasePoolPush() 創(chuàng)建自動釋放池。其 order 是-2147483647，優(yōu)先級最高，保證創(chuàng)建釋放池發(fā)生在其他所有回調(diào)之前。

2.2釋放

  • 第二個 Observer 監(jiān)視了兩個事件： BeforeWaiting(準備進入休眠) 時調(diào)用_objc_autoreleasePoolPop() 和 _objc_autoreleasePoolPush() 釋放舊的池并創(chuàng)建新池；Exit(即將退出Loop) 時調(diào)用 _objc_autoreleasePoolPop() 來釋放自動釋放池。這個 Observer 的 order 是 2147483647，優(yōu)先級最低，保證其釋放池子發(fā)生在其他所有回調(diào)之后。

  • 在主線程執(zhí)行的代碼，通常是寫在諸如事件回調(diào)、Timer回調(diào)內(nèi)的。這些回調(diào)會被 RunLoop 創(chuàng)建好的 AutoreleasePool 環(huán)繞著，所以不會出現(xiàn)內(nèi)存泄漏，開發(fā)者也不必顯示創(chuàng)建 Pool 了。

也就是說AutoreleasePool創(chuàng)建是在一個RunLoop事件開始之前(push)，AutoreleasePool釋放是在一個RunLoop事件即將結束之前(pop)。
AutoreleasePool里的Autorelease對象的加入是在RunLoop事件中，AutoreleasePool里的Autorelease對象的釋放是在AutoreleasePool釋放時。

三，AutoreleasePool的實現(xiàn)原理以及源碼初探

在終端中使用clang -rewrite-objc命令將下面的OC代碼重寫成C++的實現(xiàn)：

#import <Foundation/Foundation.h>

int main(int argc, char * argv[]) {

    @autoreleasepool {

        NSLog(@"autorelease 的初探");

    }
    return 0;
}

在我們clang以后生成的main.cpp文件代碼中我們找到main函數(shù)代碼如下：

int main(int argc, char * argv[]) {

    /* @autoreleasepool */ { __AtAutoreleasePool __autoreleasepool; 

        NSLog((NSString *)&__NSConstantStringImpl__var_folders_3x_wf7c93yj3w1_vyck5jt84mk80000gn_T_main_8f4729_mi_0);

    }
    return 0;
}

可以看到蘋果通過聲明一個__AtAutoreleasePool類型的局部變量__autoreleasepool實現(xiàn)了@autoreleasepool{}。

  • __AtAutoreleasePool的定義如下:
extern "C" __declspec(dllimport) void * objc_autoreleasePoolPush(void);
extern "C" __declspec(dllimport) void objc_autoreleasePoolPop(void *);

struct __AtAutoreleasePool {
  __AtAutoreleasePool() {atautoreleasepoolobj = objc_autoreleasePoolPush();}
  ~__AtAutoreleasePool() {objc_autoreleasePoolPop(atautoreleasepoolobj);}
  void * atautoreleasepoolobj;
};

根據(jù)構造函數(shù)和析構函數(shù)的特點（自動局部變量的構造函數(shù)是在程序執(zhí)行到聲明這個對象的位置時調(diào)用的，而對應的析構函數(shù)是在程序執(zhí)行到離開這個對象的作用域時調(diào)用），我們可以將上面兩段代碼簡化成如下形式:


int main(int argc, const char * argv[]) {

    /* @autoreleasepool */ {
        void *atautoreleasepoolobj = objc_autoreleasePoolPush();
        NSLog((NSString *)&__NSConstantStringImpl__var_folders_kb_06b822gn59df4d1zt99361xw0000gn_T_main_d39a79_mi_0);
        objc_autoreleasePoolPop(atautoreleasepoolobj);
    }

    return 0;
}

至此，我們可以分析出，單個自動釋放池的執(zhí)行過程就是objc_autoreleasePoolPush() —> [object autorelease] —> objc_autoreleasePoolPop(void *)。

來看一下objc_autoreleasePoolPush 和 objc_autoreleasePoolPop 的實現(xiàn)：

void *objc_autoreleasePoolPush(void) {
    return AutoreleasePoolPage::push();
}

void objc_autoreleasePoolPop(void *ctxt) {
    AutoreleasePoolPage::pop(ctxt);
}

上面的方法看上去是對 AutoreleasePoolPage 對應靜態(tài)方法 push 和 pop 的封裝。
下面分析一下AutoreleasePoolPage的實現(xiàn)，揭開AutoreleasePool的實現(xiàn)原理。

AutoreleasePoolPage的實現(xiàn)

AutoreleasePoolPage 是一個 C++ 中的類，它在 NSObject.mm 中的定義是這樣的：

class AutoreleasePoolPage {
#   define EMPTY_POOL_PLACEHOLDER ((id*)1)

#   define POOL_BOUNDARY nil
    static pthread_key_t const key = AUTORELEASE_POOL_KEY;
    static uint8_t const SCRIBBLE = 0xA3;  // 0xA3A3A3A3 after releasing
    static size_t const SIZE = 
#if PROTECT_AUTORELEASEPOOL
        PAGE_MAX_SIZE;  // must be multiple of vm page size
#else
        PAGE_MAX_SIZE;  // size and alignment, power of 2
#endif
    static size_t const COUNT = SIZE / sizeof(id);

    magic_t const magic;
    id *next;
    pthread_t const thread;
    AutoreleasePoolPage * const parent;
    AutoreleasePoolPage *child;
    uint32_t const depth;
    uint32_t hiwat;
};
  • magic 檢查校驗完整性的變量
  • next 指向新加入的autorelease對象
  • thread page當前所在的線程，AutoreleasePool是按線程一一對應的（結構中的thread指針指向當前線程）
  • parent 父節(jié)點 指向前一個page
  • child 子節(jié)點 指向下一個page
  • depth 鏈表的深度，節(jié)點個數(shù)
  • hiwat high water mark 數(shù)據(jù)容納的一個上限
  • EMPTY_POOL_PLACEHOLDER 空池占位
  • POOL_BOUNDARY 是一個邊界對象 nil,之前的源代碼變量名是 POOL_SENTINEL哨兵對象,用來區(qū)別每個page即每個 AutoreleasePoolPage 邊界* PAGE_MAX_SIZE = 4096, 為什么是4096呢？其實就是虛擬內(nèi)存每個扇區(qū)4096個字節(jié),4K對齊的說法。* COUNT 一個page里對象數(shù)

雙向鏈表

AutoreleasePool并沒有單獨的結構，而是由若干個AutoreleasePoolPage以雙向鏈表的形式組合而成的棧結構（分別對應結構中的parent指針和child指針）

image

parent和child就是用來構造雙向鏈表的指針。parent指向前一個page, child指向下一個page。
一個AutoreleasePoolPage的空間被占滿時，會新建一個AutoreleasePoolPage對象，連接鏈表，后來的autorelease對象在新的page加入。

objc_autoreleasePoolPush

image

每當自動釋放池調(diào)用objc_autoreleasePoolPush時都會把邊界對象放進棧頂,然后返回邊界對象,用于釋放。

atautoreleasepoolobj = objc_autoreleasePoolPush();

atautoreleasepoolobj就是返回的邊界對象(POOL_BOUNDARY)

push實現(xiàn)如下：

void *objc_autoreleasePoolPush(void) {
    return AutoreleasePoolPage::push();
}

它調(diào)用AutoreleasePoolPage的類方法push：

static inline void *push() {
   return autoreleaseFast(POOL_BOUNDARY);
}

在這里會進入一個比較關鍵的方法autoreleaseFast，并傳入邊界對象(POOL_BOUNDARY)：

static inline id *autoreleaseFast(id obj)
{
   AutoreleasePoolPage *page = hotPage();
   if (page && !page->full()) {
       return page->add(obj);
   } else if (page) {
       return autoreleaseFullPage(obj, page);
   } else {
       return autoreleaseNoPage(obj);
   }
}

上述方法分三種情況選擇不同的代碼執(zhí)行：

  • 有 hotPage 并且當前 page 不滿，調(diào)用 page->add(obj) 方法將對象添加至 AutoreleasePoolPage 的棧中
  • 有 hotPage 并且當前 page 已滿，調(diào)用 autoreleaseFullPage 初始化一個新的頁，調(diào)用 page->add(obj) 方法將對象添加至 AutoreleasePoolPage 的棧中
  • 無 hotPage，調(diào)用 autoreleaseNoPage 創(chuàng)建一個 hotPage，調(diào)用 page->add(obj) 方法將對象添加至 AutoreleasePoolPage 的棧中

最后的都會調(diào)用 page->add(obj) 將對象添加到自動釋放池中。
hotPage 可以理解為當前正在使用的 AutoreleasePoolPage。

AutoreleasePoolPage::autorelease(id obj)

autorelease方法的實現(xiàn)，先來看一下方法的調(diào)用棧：

- [NSObject autorelease]
└── id objc_object::rootAutorelease()
    └── id objc_object::rootAutorelease2()
        └── static id AutoreleasePoolPage::autorelease(id obj)
            └── static id AutoreleasePoolPage::autoreleaseFast(id obj)
                ├── id *add(id obj)
                ├── static id *autoreleaseFullPage(id obj, AutoreleasePoolPage *page)
                │   ├── AutoreleasePoolPage(AutoreleasePoolPage *newParent)
                │   └── id *add(id obj)
                └── static id *autoreleaseNoPage(id obj)
                    ├── AutoreleasePoolPage(AutoreleasePoolPage *newParent)
                    └── id *add(id obj)

在autorelease方法的調(diào)用棧中，最終都會調(diào)用上面提到的 autoreleaseFast方法，將當前對象加到AutoreleasePoolPage 中。

這一小節(jié)中這些方法的實現(xiàn)都非常容易，只是進行了一些參數(shù)上的檢查，最終還要調(diào)用autoreleaseFast方法：

inline id objc_object::rootAutorelease() {
    if (isTaggedPointer()) return (id)this;
    if (prepareOptimizedReturn(ReturnAtPlus1)) return (id)this;

    return rootAutorelease2();
}

__attribute__((noinline,used)) id objc_object::rootAutorelease2() {
    return AutoreleasePoolPage::autorelease((id)this);
}

static inline id autorelease(id obj) {
   id *dest __unused = autoreleaseFast(obj);
   return obj;
}

autorelease函數(shù)和push函數(shù)一樣，關鍵代碼都是調(diào)用autoreleaseFast函數(shù)向自動釋放池的鏈表棧中添加一個對象，
不過push函數(shù)的入棧的是一個邊界對象，而autorelease函數(shù)入棧的是需要加入autoreleasepool的對象。

objc_autoreleasePoolPop
image

自動釋放池釋放是傳入 push 返回的邊界對象,

objc_autoreleasePoolPop(atautoreleasepoolobj);

然后將邊界對象指向的這一頁 AutoreleasePoolPage 內(nèi)的對象釋放
atautoreleasepoolobj就是返回的邊界對象(POOL_BOUNDARY)

AutoreleasePoolPage::pop()實現(xiàn)：

static inline void pop(void *token)   // token指針指向棧頂?shù)牡刂?{
    AutoreleasePoolPage *page;
    id *stop;

    page = pageForPointer(token);   // 通過棧頂?shù)牡刂氛业綄膒age
    stop = (id *)token;
    if (DebugPoolAllocation  &&  *stop != POOL_SENTINEL) {
        // This check is not valid with DebugPoolAllocation off
        // after an autorelease with a pool page but no pool in place.
        _objc_fatal("invalid or prematurely-freed autorelease pool %p; ", 
                    token);
    }

    if (PrintPoolHiwat) printHiwat();   // 記錄最高水位標記

    page->releaseUntil(stop);   // 從棧頂開始操作出棧，并向棧中的對象發(fā)送release消息，直到遇到第一個哨兵對象

    // memory: delete empty children
    // 刪除空掉的節(jié)點
    if (DebugPoolAllocation  &&  page->empty()) {
        // special case: delete everything during page-per-pool debugging
        AutoreleasePoolPage *parent = page->parent;
        page->kill();
        setHotPage(parent);
    } else if (DebugMissingPools  &&  page->empty()  &&  !page->parent) {
        // special case: delete everything for pop(top) 
        // when debugging missing autorelease pools
        page->kill();
        setHotPage(nil);
    } 
    else if (page->child) {
        // hysteresis: keep one empty child if page is more than half full
        if (page->lessThanHalfFull()) {
            page->child->kill();
        }
        else if (page->child->child) {
            page->child->child->kill();
        }
    }
}

該過程主要分為兩步：

  • page->releaseUntil(stop)，對棧頂（page->next）到stop地址（POOL_SENTINEL）之間的所有對象調(diào)用objc_release()，進行引用計數(shù)減1
  • 清空page對象page->kill()，有兩句注釋

// hysteresis: keep one empty child if this page is more than half full
// special case: delete everything for pop(0)
除非是pop(0)方式調(diào)用，這樣會清理掉所有page對象；
否則，在當前page存放的對象大于一半時，會保留一個空的子page，
這樣估計是為了可能馬上需要新建page節(jié)省創(chuàng)建page的開銷。

小結

  • 自動釋放池是一個個 AutoreleasePoolPage 組成的一個page是4096字節(jié)大小,每個 AutoreleasePoolPage 以雙向鏈表連接起來形成一個自動釋放池
  • 當對象調(diào)用 autorelease 方法時，會將對象加入 AutoreleasePoolPage 的棧中
  • pop 時是傳入邊界對象,然后對page 中的對象發(fā)送release 的消息

作者：攜YOU手同行
鏈接：http://www.itdecent.cn/p/7b8f6d443057
來源：簡書
著作權歸作者所有。商業(yè)轉載請聯(lián)系作者獲得授權，非商業(yè)轉載請注明出處。

?著作權歸作者所有,轉載或內(nèi)容合作請聯(lián)系作者
【社區(qū)內(nèi)容提示】社區(qū)部分內(nèi)容疑似由AI輔助生成，瀏覽時請結合常識與多方信息審慎甄別。
平臺聲明：文章內(nèi)容（如有圖片或視頻亦包括在內(nèi)）由作者上傳并發(fā)布，文章內(nèi)容僅代表作者本人觀點，簡書系信息發(fā)布平臺，僅提供信息存儲服務。

相關閱讀更多精彩內(nèi)容

友情鏈接更多精彩內(nèi)容