1、新建立一個VB6工程，
2、菜單：工程--添加模塊 按“打開”這樣就添加了一個新模塊，名為Module1,保存為Module1.bas
3、在Module1中寫下如下代碼：

Option Explicit
Public Const MAX_TOOLTIP As Integer = 64
Public Const NIF_ICON = &H2
Public Const NIF_MESSAGE = &H1
Public Const NIF_TIP = &H4
Public Const NIM_ADD = &H0
Public Const NIM_DELETE = &H2
Public Const WM_MOUSEMOVE = &H200
Public Const WM_LBUTTONDOWN = &H201
Public Const WM_LBUTTONUP = &H202
Public Const WM_LBUTTONDBLCLK = &H203
Public Const WM_RBUTTONDOWN = &H204
Public Const WM_RBUTTONUP = &H205
Public Const WM_RBUTTONDBLCLK = &H206
Public Const SW_RESTORE = 9
Public Const SW_HIDE = 0
Public nfIconData As NOTIFYICONDATA
Public Type NOTIFYICONDATA
cbSize As Long
hWnd As Long
uID As Long
uFlags As Long
uCallbackMessage As Long
hIcon As Long
szTip As String * MAX_TOOLTIP
End Type
Public Declare Function ShowWindow Lib "user32" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long
Public Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long

360截圖20210125133610976.jpg

4、在Form1的QueryUnload事件中寫入如下代碼：

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    Call Shell_NotifyIcon(NIM_DELETE, nfIconData)
End Sub

5、在Form1的窗口事件中寫下如下代碼：

Private Sub Form_Resize()
    If Me.WindowState = vbMinimized Then
      ''MsgBox "最小化"
          '以下把程序放入System Tray====================================System Tray Begin
            With nfIconData
              .hWnd = Me.hWnd
              .uID = Me.Icon
              .uFlags = NIF_ICON Or NIF_MESSAGE Or NIF_TIP
              .uCallbackMessage = WM_MOUSEMOVE
              .hIcon = Me.Icon.Handle
              '定義鼠標(biāo)移動到托盤上時顯示的Tip
              .szTip = App.Title + "(版本 " & App.Major & "." & App.Minor & "." & App.Revision & ")" & vbNullChar
              .cbSize = Len(nfIconData)
            End With
            Call Shell_NotifyIcon(NIM_ADD, nfIconData)
            '=============================================================System Tray End
            Me.Hide
    
    ElseIf Me.WindowState = vbMaximized Then
      ''  MsgBox "最大化"
    ElseIf Me.WindowState = vbNormal Then
       '' MsgBox "正常狀態(tài)"
    End If
End Sub

6、托盤點(diǎn)擊彈出，在Form1的MouseMove事件中寫下如下代碼：

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dim lMsg As Single
    lMsg = X / Screen.TwipsPerPixelX
    Select Case lMsg
      Case WM_LBUTTONUP
       'MsgBox "請用鼠標(biāo)右鍵點(diǎn)擊圖標(biāo)!", vbInformation, "實時播音專家"
       '單擊左鍵，顯示窗體
       ShowWindow Me.hWnd, SW_RESTORE
       '下面兩句的目的是把窗口顯示在窗口最頂層
       'Me.Show
       'Me.SetFocus
       '' Case WM_RBUTTONUP
       '' PopupMenu MenuTray '如果是在系統(tǒng)Tray圖標(biāo)上點(diǎn)右鍵，則彈出菜單MenuTray
       '' Case WM_MOUSEMOVE
       '' Case WM_LBUTTONDOWN
       '' Case WM_LBUTTONDBLCLK
       '' Case WM_RBUTTONDOWN
       '' Case WM_RBUTTONDBLCLK
       '' Case Else
    End Select
End Sub

360截圖20210125134405930.jpg

參考：https://blog.csdn.net/karl_han/article/details/12087571