Replugin源碼解析之replugin-host-gradle

概述

關(guān)于replugin介紹及簡單使用可以參照官方文檔,在這里不再累述。本文之前需要對自定義gradle插件有一定基礎(chǔ)以方便理解，參見Gradle學(xué)習(xí)-----Gradle自定義插件。
NOTE：文中會提及兩種插件，請閱讀本文時注意提及插件的上下文情景，避免混淆概念

1：replugin插件：即replugin插件化框架所指的插件，這個插件指android應(yīng)用業(yè)務(wù)拆分出的獨(dú)立模塊，是android應(yīng)用或模塊。
2：gradle插件(本文及上文鏈接重點(diǎn))：即gradle構(gòu)建所需的構(gòu)建插件，是gradle應(yīng)用或模塊。

目錄概覽

\qihoo\RePlugin\replugin-host-gradle\src            
│         
└─main        
    ├─groovy       
    │  └─com            
    │      └─qihoo360     
    │          └─replugin      
    │              └─gradle      
    │                  └─host     
    │                      │  AppConstant.groovy                     # 程序常量定義類
    │                      │  RePlugin.groovy    <====== (入口)  # 針對宿主的特定構(gòu)建任務(wù)創(chuàng)建及調(diào)度
    │                      │  
    │                      ├─creator
    │                      │  │  FileCreators.groovy                # 組裝生成器
    │                      │  │  IFileCreator.groovy                # 文件生成器接口
    │                      │  │  
    │                      │  └─impl
    │                      │      ├─java
    │                      │      │      RePluginHostConfigCreator.groovy        # RePluginHostConfig.java 生成器
    │                      │      │      
    │                      │      └─json
    │                      │              PluginBuiltinJsonCreator.groovy        # plugins-builtin.json 生成器
    │                      │              PluginInfo.groovy                      # 插件信息模型
    │                      │              PluginInfoParser.groovy                # 從 manifest 的 xml 中抽取 PluginInfo信息
    │                      │              
    │                      └─handlemanifest
    │                              ComponentsGenerator.groovy        # 動態(tài)生成插件化框架中需要的組件
    │                              
    └─resources
        └─META-INF
            └─gradle-plugins
                    replugin-host-gradle.properties                  # 指定 gradle 插件實(shí)現(xiàn)類

入口類鏈接

分解

1：預(yù)生成AndroidManifest.xml中的組件坑位

@Override
    public void apply(Project project) {

        println "${TAG} Welcome to replugin world ! "

        this.project = project

        /* Extensions */
        project.extensions.create(AppConstant.USER_CONFIG, RepluginConfig) //讀取gradle配置中的repluginHostConfig配置

        if (project.plugins.hasPlugin(AppPlugin)) {

            def android = project.extensions.getByType(AppExtension)
            android.applicationVariants.all { variant ->

                addShowPluginTask(variant)

                if (config == null) {
                    config = project.extensions.getByName(AppConstant.USER_CONFIG)
                    checkUserConfig(config)
                }

                def appID = variant.generateBuildConfig.appPackageName
                println "${TAG} appID: ${appID}"
                def newManifest = ComponentsGenerator.generateComponent(appID, config)

                ...
            }
        }
    }
  • 首先,將RepluginConfig類的常量配置信息賦值給AppConstant.USER_CONFIG(即repluginHostConfig)配置，在接下來checkUserConfig(config)用到。當(dāng)如果我們不配置，則默認(rèn)配置如下
class RepluginConfig {

    /** 自定義進(jìn)程的數(shù)量(除 UI 和 Persistent 進(jìn)程) */
    def countProcess = 3

    /** 是否使用常駐進(jìn)程？ */
    def persistentEnable = true

    /** 常駐進(jìn)程名稱（也就是上面說的 Persistent 進(jìn)程，開發(fā)者可自定義）*/
    def persistentName = ':GuardService'

    /** 背景不透明的坑的數(shù)量 */
    def countNotTranslucentStandard = 6
    def countNotTranslucentSingleTop = 2
    def countNotTranslucentSingleTask = 3
    def countNotTranslucentSingleInstance = 2

    /** 背景透明的坑的數(shù)量 */
    def countTranslucentStandard = 2
    def countTranslucentSingleTop = 2
    def countTranslucentSingleTask = 2
    def countTranslucentSingleInstance = 3

    /** 宿主中聲明的 TaskAffinity 的組數(shù) */
    def countTask = 2

    /**
     * 是否使用 AppCompat 庫
     * com.android.support:appcompat-v7:25.2.0
     */
    def useAppCompat = false

    /** HOST 向下兼容的插件版本 */
    def compatibleVersion = 10

    /** HOST 插件版本 */
    def currentVersion = 12

    /** plugins-builtin.json 文件名自定義,默認(rèn)是 "plugins-builtin.json" */
    def builtInJsonFileName = "plugins-builtin.json"

    /** 是否自動管理 plugins-builtin.json 文件,默認(rèn)自動管理 */
    def autoManageBuiltInJsonFile = true

    /** assert目錄下放置插件文件的目錄自定義,默認(rèn)是 assert 的 "plugins" */
    def pluginDir = "plugins"

    /** 插件文件的后綴自定義,默認(rèn)是".jar" 暫時支持 jar 格式*/
    def pluginFilePostfix = ".jar"

    /** 當(dāng)發(fā)現(xiàn)插件目錄下面有不合法的插件 jar (有可能是特殊定制 jar)時是否停止構(gòu)建,默認(rèn)是 true */
    def enablePluginFileIllegalStopBuild = true
}

  • 判斷project中是否含有AppPlugin類型插件，即我們在宿主項(xiàng)目中是應(yīng)用了該類型插件，也就是是否在build.gradle中寫了：apply plugin: 'com.android.application'.所以，我們在使用apply plugin: 'replugin-host-gradle'時，必須在apply plugin: 'com.android.application'之后。
    如果希望判斷是否有l(wèi)ibraryPlugin,可以這樣寫：if (project.plugins.hasPlugin(LibraryPlugin))

  • 獲取project中的AppExtension類型extension，即com.android.application projects的android extension.也就是在你的app模塊的build.gradle中定義的閉包：android { ...}
    遍歷android extension的Application variants 列表。這可以說是 Hook Android gradle 插件的一種方式，因?yàn)橥ㄟ^遍歷applicationVariants，你可以修改屬性，名字，描述，輸出文件名等，如果是Android library庫，那么就將applicationVariants替換為libraryVariants。我們在app的build.gradle中這樣定義過閉包：

buildTypes {
     release {
         applicationVariants.all { variant ->
             variant.outputs.each { output ->
                 def outputFile = output.outputFile
                 def fileName = "xxx_${variant.productFlavors[0].name}_v${defaultConfig.versionName}_${releaseTime()}.apk"
                 output.outputFile = new File(outputFile.parent, fileName)
             }
         }
     }
 }

其實(shí)這也是一種插件的創(chuàng)建方式，Hook Android gradle 插件動態(tài)修改variants屬性值，修改打包輸出的apk文件名。
創(chuàng)建自定義gradle插件，Gradle提供了多種方式（Gradle學(xué)習(xí)-----Gradle自定義插件提過）：
1：在build.gradle腳本中直接創(chuàng)建（上述代碼即是）
2：在獨(dú)立Module中創(chuàng)建（replugin-host-gradle即是）

  • 調(diào)用 addShowPluginTask(variant)方法，代碼如下
// 添加 【查看所有插件信息】 任務(wù)
    def addShowPluginTask(def variant) {
        def variantData = variant.variantData
        def scope = variantData.scope
        def showPluginsTaskName = scope.getTaskName(AppConstant.TASK_SHOW_PLUGIN, "")
        def showPluginsTask = project.task(showPluginsTaskName)

        showPluginsTask.doLast {
            IFileCreator creator = new PluginBuiltinJsonCreator(project, variant, config)
            def dir = creator.getFileDir()

            if (!dir.exists()) {
                println "${AppConstant.TAG} The ${dir.absolutePath} does not exist "
                println "${AppConstant.TAG} pluginsInfo=null"
                return
            }

            String fileContent = creator.getFileContent()
            if (null == fileContent) {
                return
            }

            new File(dir, creator.getFileName()).write(fileContent, 'UTF-8')
        }
        showPluginsTask.group = AppConstant.TASKS_GROUP

        //get mergeAssetsTask name
        String mergeAssetsTaskName = variant.getVariantData().getScope().getMergeAssetsTask().name
        //get real gradle task
        def mergeAssetsTask = project.tasks.getByName(mergeAssetsTaskName)

        //depend on mergeAssetsTask so that assets have been merged
        if (mergeAssetsTask) {
            showPluginsTask.dependsOn mergeAssetsTask
        }

    }

但是方法內(nèi)指定的task并未掛到android gradle task上，即task不會執(zhí)行。這個task是方便調(diào)試時查看插件信息的.

  • 接下來調(diào)用 checkUserConfig，源碼如下：
 /**
     * 檢查用戶配置項(xiàng)
     */
    def checkUserConfig(config) {
/*
        def persistentName = config.persistentName
        if (persistentName == null || persistentName.trim().equals("")) {
            project.logger.log(LogLevel.ERROR, "\n---------------------------------------------------------------------------------")
            project.logger.log(LogLevel.ERROR, " ERROR: persistentName can'te be empty, please set persistentName in replugin. ")
            project.logger.log(LogLevel.ERROR, "---------------------------------------------------------------------------------\n")
            System.exit(0)
            return
        }
*/
        doCheckConfig("countProcess", config.countProcess)
        doCheckConfig("countTranslucentStandard", config.countTranslucentStandard)
        doCheckConfig("countTranslucentSingleTop", config.countTranslucentSingleTop)
        doCheckConfig("countTranslucentSingleTask", config.countTranslucentSingleTask)
        doCheckConfig("countTranslucentSingleInstance", config.countTranslucentSingleInstance)
        doCheckConfig("countNotTranslucentStandard", config.countNotTranslucentStandard)
        doCheckConfig("countNotTranslucentSingleTop", config.countNotTranslucentSingleTop)
        doCheckConfig("countNotTranslucentSingleTask", config.countNotTranslucentSingleTask)
        doCheckConfig("countNotTranslucentSingleInstance", config.countNotTranslucentSingleInstance)
        doCheckConfig("countTask", config.countTask)

        println '--------------------------------------------------------------------------'
//        println "${TAG} appID=${appID}"
        println "${TAG} useAppCompat=${config.useAppCompat}"
        // println "${TAG} persistentName=${config.persistentName}"
        println "${TAG} countProcess=${config.countProcess}"

        println "${TAG} countTranslucentStandard=${config.countTranslucentStandard}"
        println "${TAG} countTranslucentSingleTop=${config.countTranslucentSingleTop}"
        println "${TAG} countTranslucentSingleTask=${config.countTranslucentSingleTask}"
        println "${TAG} countTranslucentSingleInstance=${config.countTranslucentSingleInstance}"
        println "${TAG} countNotTranslucentStandard=${config.countNotTranslucentStandard}"
        println "${TAG} countNotTranslucentSingleTop=${config.countNotTranslucentSingleTop}"
        println "${TAG} countNotTranslucentSingleTask=${config.countNotTranslucentSingleTask}"
        println "${TAG} countNotTranslucentSingleInstance=${config.countNotTranslucentSingleInstance}"

        println "${TAG} countTask=${config.countTask}"
        println '--------------------------------------------------------------------------'
    }

讀取一開始加載進(jìn)來的repluginHostConfig配置信息做數(shù)據(jù)類型正確性校驗(yàn)。

  • 關(guān)鍵代碼，下面一行代碼，搞定了宿主中AndroidManifest.xml中的組件坑位生成，注意，結(jié)合結(jié)構(gòu)概覽中的gradle Flow 看，這里只是生成組件坑位的xml代碼，最終的xml文件是在后續(xù)的task中拼裝出來的，稍后會講到。
def newManifest = ComponentsGenerator.generateComponent(appID, config)

該方法源碼如下：

def static generateComponent(def applicationID, def config) {
         // 是否使用 AppCompat 庫（涉及到默認(rèn)主題）
         if (config.useAppCompat) {
             themeNTS = THEME_NTS_NOT_APP_COMPAT
         } else {
             themeNTS = THEME_NTS_NOT_USE_APP_COMPAT
         }

         def writer = new StringWriter()
         def xml = new MarkupBuilder(writer)

         /* UI 進(jìn)程 */
         xml.application {
             /* 透明坑 */
             config.countTranslucentStandard.times {
                 activity(
                         "${name}": "${applicationID}.${infix}N1NRTS${it}",
                         "${cfg}": "${cfgV}",
                         "${exp}": "${expV}",
                         "${ori}": "${oriV}",
                         "${theme}": "${themeTS}")
                 ...
             }

             ...

             /* 不透明坑 */
             config.countNotTranslucentStandard.times{

             }
             ...

         }
         // 刪除 application 標(biāo)簽
         def normalStr = writer.toString().replace("<application>", "").replace("</application>", "")

 //        println "${TAG} normalStr: ${normalStr}"

         // 將單進(jìn)程和多進(jìn)程的組件相加
         normalStr + generateMultiProcessComponent(applicationID, config)
     }

主要作用就是基于 Groovy 的 MarkupBuilder api，根據(jù) RepluginConfig 類中的配置，拼出組件坑位的xml 字符串。就像搭積木一樣，以其中一組作為研究。

config.countTranslucentStandard.times {
             activity(
                     "${name}": "${applicationID}.${infix}N1NRTS${it}",
                     "${cfg}": "${cfgV}",
                     "${exp}": "${expV}",
                     "${ori}": "${oriV}",
                     "${theme}": "${themeTS}")
         }

NOTE:config.countTranslucentStandard.times含義：根據(jù)config.countTranslucentStandard的值循環(huán)
生成的坑位：

<activity
         android:theme="@ref/0x01030010"
         android:name="com.qihoo360.replugin.sample.host.loader.a.ActivityN1NRTS0"
         android:exported="false"
         android:screenOrientation="1"
         android:configChanges="0x4b0" />

即：替換

生成 RePluginHostConfig 配置文件

@Override
    public void apply(Project project) {

       ...

        if (project.plugins.hasPlugin(AppPlugin)) {

            def android = project.extensions.getByType(AppExtension)
            android.applicationVariants.all { variant ->

                ...

                def variantData = variant.variantData
                def scope = variantData.scope

                //host generate task
                def generateHostConfigTaskName = scope.getTaskName(AppConstant.TASK_GENERATE, "HostConfig")
                def generateHostConfigTask = project.task(generateHostConfigTaskName)

                generateHostConfigTask.doLast {
                    FileCreators.createHostConfig(project, variant, config)
                }
                generateHostConfigTask.group = AppConstant.TASKS_GROUP

                //depends on build config task
                String generateBuildConfigTaskName = variant.getVariantData().getScope().getGenerateBuildConfigTask().name
                def generateBuildConfigTask = project.tasks.getByName(generateBuildConfigTaskName)
                if (generateBuildConfigTask) {
                    generateHostConfigTask.dependsOn generateBuildConfigTask
                    generateBuildConfigTask.finalizedBy generateHostConfigTask
                }

                ...

            }
        }
    }

繼續(xù)回到 apply 方法，接下來該到生成 RePluginHostConfig 的時候了，即 注釋中的host generate task

  • 首先生成了 HostConfig 的gradle task 名字，并調(diào)用project的task()方法創(chuàng)建此Task。
  • 指定了 generateHostConfigTask 的task任務(wù)：自動創(chuàng)建RePluginHostConfig.java至BuildConfig目錄。
 generateHostConfigTask.doLast {
     FileCreators.createHostConfig(project, variant, config)
 }

注：createHostConfig(...)也是根據(jù)配置類 RepluginConfig中的配置信息拼裝生成的java文件。

//depends on build config task
if (generateBuildConfigTask) {
 generateHostConfigTask.dependsOn generateBuildConfigTask
 generateBuildConfigTask.finalizedBy generateHostConfigTask
}

因?yàn)榇藅ask中創(chuàng)建的RePluginHostConfig.java希望放置到編譯輸出目錄..\replugin-sample\host\app\build\generated\source\buildConfig\{productFlavors}\{buildTypes}\...下，所以此task依賴于生成 BuildConfig.java 的task并設(shè)置為 BuildConfigTask 執(zhí)行完后，就執(zhí)行HostConfigTask。
關(guān)于gradle 的 task 相關(guān)知識，可以去gradle 官網(wǎng)或某搜索引擎查看學(xué)習(xí)，屬于字典型知識點(diǎn)，需要時候查閱下。

生成 plugins-builtin.json 插件信息文件

@Override
    public void apply(Project project) {

       ...

        if (project.plugins.hasPlugin(AppPlugin)) {

            def android = project.extensions.getByType(AppExtension)
            android.applicationVariants.all { variant ->

                ...

                //json generate task
                def generateBuiltinJsonTaskName = scope.getTaskName(AppConstant.TASK_GENERATE, "BuiltinJson")
                def generateBuiltinJsonTask = project.task(generateBuiltinJsonTaskName)

                generateBuiltinJsonTask.doLast {
                    FileCreators.createBuiltinJson(project, variant, config)
                }
                generateBuiltinJsonTask.group = AppConstant.TASKS_GROUP

                //depends on mergeAssets Task
                String mergeAssetsTaskName = variant.getVariantData().getScope().getMergeAssetsTask().name
                def mergeAssetsTask = project.tasks.getByName(mergeAssetsTaskName)
                if (mergeAssetsTask) {
                    generateBuiltinJsonTask.dependsOn mergeAssetsTask
                    mergeAssetsTask.finalizedBy generateBuiltinJsonTask
                }

                ...

            }
        }
    }

繼續(xù)回到 apply 方法，接下來該到生成 plugins-builtin.json 這個包含了插件信息的文件的時候了，即 注釋中的json generate task。

  • 首先生成個gradle task 名字，并調(diào)用project的task()方法創(chuàng)建此Task。
  • 指定了 generateBuiltinJsonTask 的task任務(wù)：掃描宿主\assets\plugins目錄下的插件文件，并基于apk文件規(guī)則解析出插件信息，包名，版本號等，然后拼裝成json文件。
generateBuiltinJsonTask.doLast {
 FileCreators.createBuiltinJson(project, variant, config)
}

設(shè)置 generateBuiltinJsonTask 的執(zhí)行依賴

//depends on build config task
if (mergeAssetsTask) {
 generateBuiltinJsonTask.dependsOn mergeAssetsTask
 mergeAssetsTask.finalizedBy generateBuiltinJsonTask
}

因?yàn)榇藅ask中創(chuàng)建的 plugins-builtin.json 希望放置到編譯輸出目錄...\replugin-sample\host\app\build\intermediates\assets\{productFlavors}\{buildTypes}\...下，所以此task依賴于merge assets文件 的task并設(shè)置為 mergeAssetsTask 執(zhí)行完后，就執(zhí)行BuiltinJsonTask。

拼裝 AndroidManifest.xml

output.processManifest.doLast {
    def manifestPath = output.processManifest.outputFile.absolutePath
    def updatedContent = new File(manifestPath).getText("UTF-8").replaceAll("</application>", newManifest + "</application>")
    new File(manifestPath).write(updatedContent, 'UTF-8')
}
  • 將坑位 xml 字符串 與 原有xml <application></application> 標(biāo)簽內(nèi)的配置信息合二為一。
    至此，replugin-host-gradle 插件的工作就全部結(jié)束了。
最后編輯于 ：
?著作權(quán)歸作者所有,轉(zhuǎn)載或內(nèi)容合作請聯(lián)系作者
【社區(qū)內(nèi)容提示】社區(qū)部分內(nèi)容疑似由AI輔助生成，瀏覽時請結(jié)合常識與多方信息審慎甄別。
平臺聲明：文章內(nèi)容（如有圖片或視頻亦包括在內(nèi)）由作者上傳并發(fā)布，文章內(nèi)容僅代表作者本人觀點(diǎn)，簡書系信息發(fā)布平臺，僅提供信息存儲服務(wù)。

相關(guān)閱讀更多精彩內(nèi)容

友情鏈接更多精彩內(nèi)容