国产高清片,人妻丰满少妇中文字幕

本文主要來分析objc_msgSend的方法查找流程
在前面的文章iOS底層原理09：類結(jié)構(gòu)分析——cache屬性中，我們分析了cache的寫入流程，在寫入流程之前，還有一個cache讀取流程，即objc_msgSend和cache_getImp

在分析之前，首先來了解什么是 Runtime文檔地址

Runtime 介紹

runtime稱為運行時，它與編譯時的區(qū)別：

運行時 是代碼跑起來，被裝載到內(nèi)存中的過程，如果此時出錯，則程序會崩潰，是一個動態(tài)階段
編譯時 是源代碼翻譯成機器能識別的代碼的過程，主要是對語言進行最基本的檢查報錯，即詞法分析、語法分析等，是一個靜態(tài)的階段

runtime有下列三種使用方式：

通過OC代碼，例如[p sayHello];
通過NSObject方法，例如iskindOfClass
通過Runtime API，例如class_getInstanceSize

探索方法的本質(zhì)

方法的本質(zhì)

在iOS底層原理06：對象的本質(zhì) & isa中，利用clang將main.m編譯成 main.cpp，理解了OC對象的本質(zhì)，同樣的，我們來看看方法在底層編譯成什么樣子

新建工程如下圖，HTPerson類中有兩個對象方法，其中sayBye方法未實現(xiàn)

image

利用clang編譯器將main.m編譯成 main.cpp：clang -rewrite-objc main.m -o main.cpp，查看編譯后的底層實現(xiàn)

//??clang編譯后的底層實現(xiàn)
HTPerson *p = ((HTPerson *(*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("HTPerson"), sel_registerName("alloc"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)p, sel_registerName("sayHello"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)p, sel_registerName("sayBye"));

通過上述代碼可以看出，方法的本質(zhì)就是objc_msgSend消息發(fā)送

運行程序，可以編譯成功，但是運行時發(fā)生崩潰，unrecognized selector sent to instance xxx，是我們開發(fā)過程中經(jīng)常遇到的錯誤

image

通過Runtime API調(diào)用方法

直接調(diào)用objc_msgSend，需要導(dǎo)入頭文件#import <objc/message.h>
需要將target --> Build Setting --> enable strict checking of obc_msgSend calls 設(shè)置為NO，將嚴(yán)厲的檢查機制關(guān)掉，否則objc_msgSend的參數(shù)會報錯
運行程序，查看打印結(jié)果

image

我們發(fā)現(xiàn)打印結(jié)果是一致的，所以[p sayHello]; 等價于objc_msgSend(p, sel_registerName("sayHello")); 和 objc_msgSend(p, @selector(sayHello));

objc_msgSendSuper方法探究

我們可以通過objc_msgSendSuper來跳過本類，去父類中找方法實現(xiàn)

定義兩個類HTPerson和HTStudent，都有- (void)sayHello的方法實現(xiàn)

image

objc4-818源碼中，查看objc_msgSendSuper方法如下

image

objc_super結(jié)構(gòu)體源碼

image

打印結(jié)果如下

image

【問題】 objc_msgSend 和 objc_msgSendSuper 是如何找到方法實現(xiàn)的？帶著這個問題，我們來探索objc_msgSend的源碼實現(xiàn)

objc_msgSend 快速查找流程分析

在objc4-818源碼中，搜索objc_msgSend，發(fā)現(xiàn)都是匯編代碼實現(xiàn)的，由于我們?nèi)粘ｉ_發(fā)的都是架構(gòu)是arm64，所以主要來分析arm64.s中的objc_msgSend源碼實現(xiàn)

image

【補充知識】-- Tagged Pointer對象

64位系統(tǒng)與Tagged Pointer對象博客地址
在64位系統(tǒng)中，如果我們真正使用一個指針來存儲NSNumber實例，那么我們首先需要一個8字節(jié)的指針，另外需要一塊內(nèi)存存儲NSNumber實例，這通常又是8字節(jié)。這樣的內(nèi)存開銷是比較大的。蘋果對于NSNumber和NSDate對象，改成了用Tagged Pointer來存儲，簡單來說，Tagged Pointer是一個假的指針，它的值不再是另一個地址，而就是對應(yīng)變量的值。

Tagged Pointer主要有以下3個特點：

Tagged Pointer專門用來存儲小的對象，例如NSNumber和NSDate
Tagged Pointer指針的值不再是地址了，而是真正的值。所以，實際上它不再是一個對象了，它只是一個披著對象皮的普通變量而已！所以，它的內(nèi)存并不存儲在堆中，也不需要malloc和free。
在內(nèi)存讀取上有著3倍的效率（以前是尋址->發(fā)消息->獲取值，現(xiàn)在直接獲取值），創(chuàng)建時比以前快106倍。

objc_msgSend 匯編源碼

objc_msgSend是消息發(fā)送的源碼的入口，使用匯編實現(xiàn)的，_objc_msgSend源碼實現(xiàn)如下

//---- 消息發(fā)送 -- 匯編入口--objc_msgSend主要是拿到接收者的isa信息
    ENTRY _objc_msgSend
//---- 無窗口
    UNWIND _objc_msgSend, NoFrame
//---- p0和空對比，即判斷接收者是否存在，其中p0是objc_msgSend的第一個參數(shù)-消息接收者receiver
    cmp p0, #0          // nil check and tagged pointer check
//---- arm64架構(gòu) --支持taggedpointer（小對象類型）的流程
#if SUPPORT_TAGGED_POINTERS
    b.le    LNilOrTagged        //  (MSB tagged pointer looks negative)
#else
    b.eq    LReturnZero
#endif
//---- 從對象的首地址中取值，即拿到isa，存入 p13寄存器
    ldr p13, [x0]       // p13 = isa
//---- 在64位架構(gòu)下通過 p16 = isa（p13） & ISA_MASK，拿出shiftcls信息，得到class信息
    GetClassFromIsa_p16 p13, 1, x0  // p16 = class
LGetIsaDone:
    // calls imp or objc_msgSend_uncached
//---- 如果有isa，走到CacheLookup 即緩存查找流程，也就是所謂的sel-imp快速查找流程
    CacheLookup NORMAL, _objc_msgSend, __objc_msgSend_uncached

#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
    b.eq    LReturnZero     // nil check
    GetTaggedClass
    b   LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif

LReturnZero:
    // x0 is already zero
    mov x1, #0
    movi    d0, #0
    movi    d1, #0
    movi    d2, #0
    movi    d3, #0
    ret

    END_ENTRY _objc_msgSend

objc_msgSend匯編源碼主要有以下幾步：

【第一步】判斷objc_msgSend方法的第一個參數(shù)receiver是否為空
- 如果支持tagged pointer，并且p0 <= 0x0，跳轉(zhuǎn)至LNilOrTagged
  - 如果小對象為空，則直接返回空，即LReturnZero
  - 如果小對象（指的是NSNumber或者NSDate對象）不為空，則處理小對象的獲得class，走到【第二步】
- 如果不支持tagged pointer，并且receiver為空，直接返回，跳轉(zhuǎn)至LReturnZero
- 如果即不是小對象，receiver也不為空，有以下兩步
  - 從receiver中取出isa存入p13寄存器
  - 通過 GetClassFromIsa_p16中，arm64架構(gòu)下通過 isa & ISA_MASK 獲取shiftcls位域的類信息，即class，GetClassFromIsa_p16的匯編實現(xiàn)如下，然后走到【第二步】

.macro GetClassFromIsa_p16 src, needs_auth, auth_address /* note: auth_address is not required if !needs_auth */

//---- 此處用于watchOS
#if SUPPORT_INDEXED_ISA
    // Indexed isa
    mov p16, \src           // optimistically set dst = src
    tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f  // done if not non-pointer isa
    // isa in p16 is indexed
    adrp    x10, _objc_indexed_classes@PAGE
    add x10, x10, _objc_indexed_classes@PAGEOFF
    ubfx    p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS  // extract index
    ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
1:

//---- 用于64位系統(tǒng)
#elif __LP64__
.if \needs_auth == 0 // _cache_getImp takes an authed class already
    mov p16, \src
.else
    // 64-bit packed isa
//---- p16 = class（類收地址） = isa & ISA_MASK(位運算 & 即獲取isa中的shiftcls信息)
    ExtractISA p16, \src, \auth_address
.endif
#else
//---- 用于32位系統(tǒng)
    // 32-bit raw isa
    mov p16, \src

#endif

.endmacro

【第二步】獲取isa完畢，進入快速查找流程CacheLookup NORMAL

CacheLookup(緩存查找)匯編源碼

//---- CacheLookup NORMAL, _objc_msgSend, __objc_msgSend_uncached
//---- 此時的參數(shù)：x0：receiver； x1: selector； x16: isa（類的首地址）
.macro CacheLookup Mode, Function, MissLabelDynamic, MissLabelConstant
    //
    // Restart protocol:
    //
    //   As soon as we're past the LLookupStart\Function label we may have
    //   loaded an invalid cache pointer or mask.
    //
    //   When task_restartable_ranges_synchronize() is called,
    //   (or when a signal hits us) before we're past LLookupEnd\Function,
    //   then our PC will be reset to LLookupRecover\Function which forcefully
    //   jumps to the cache-miss codepath which have the following
    //   requirements:
    //
    //   GETIMP:
    //     The cache-miss is just returning NULL (setting x0 to 0)
    //
    //   NORMAL and LOOKUP:
    //   - x0 contains the receiver
    //   - x1 contains the selector
    //   - x16 contains the isa
    //   - other registers are set as per calling conventions
    //

    mov x15, x16            // stash the original isa
LLookupStart\Function:
    // p1 = SEL, p16 = isa
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16_BIG_ADDRS
    ldr p10, [x16, #CACHE]              // p10 = mask|buckets
    lsr p11, p10, #48           // p11 = mask
    and p10, p10, #0xffffffffffff   // p10 = buckets
    and w12, w1, w11            // x12 = _cmd & mask
//---- 【64位真機】
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
//---- #define CACHE (2 * __SIZEOF_POINTER__)，其中 __SIZEOF_POINTER__表示pointer的大小 ，即 2*8 = 16
//---- p11 = mask|buckets -- 從x16（即isa）中平移16字節(jié)，取出cache 存入p11寄存器 -- isa距離cache 正好16字節(jié)：isa（8字節(jié)）-superClass（8字節(jié)）-cache（mask高16位 + buckets低48位）
    ldr p11, [x16, #CACHE]          // p11 = mask|buckets
#if CONFIG_USE_PREOPT_CACHES  // arm64架構(gòu)下 == 1
#if __has_feature(ptrauth_calls) // A12 以上
    tbnz    p11, #0, LLookupPreopt\Function
    and p10, p11, #0x0000ffffffffffff   // p10 = buckets
#else
//---- p10等于 buckets的首地址
    and p10, p11, #0x0000fffffffffffe   // p10 = buckets
//---- tbnz p11, #0，表示_bucketsAndMaybeMask的第0為!=0時，跳轉(zhuǎn)到LLookupPreopt\Function
    tbnz    p11, #0, LLookupPreopt\Function
#endif
//---- eor表示異或 p1=_cmd，p12 = (_cmd ^ (_cmd >> 7))
    eor p12, p1, p1, LSR #7
//---- p11 >> 48 得到mask； x12 = (_cmd ^ (_cmd >> 7)) & mask； 這一步主要是hash計算下標(biāo)index
    and p12, p12, p11, LSR #48      // x12 = (_cmd ^ (_cmd >> 7)) & mask
#else
    and p10, p11, #0x0000ffffffffffff   // p10 = buckets
    and p12, p1, p11, LSR #48       // x12 = _cmd & mask
#endif // CONFIG_USE_PREOPT_CACHES
//--- 【非64位真機】
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    ldr p11, [x16, #CACHE]              // p11 = mask|buckets
    and p10, p11, #~0xf         // p10 = buckets
    and p11, p11, #0xf          // p11 = maskShift
    mov p12, #0xffff
    lsr p11, p12, p11           // p11 = mask = 0xffff >> p11
    and p12, p1, p11            // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif

/**
 ---- 此時幾個參數(shù)分別代表：
 - p10 = buckets;
 - p12 = (_cmd ^ (_cmd >> 7)) & mask  即hash下標(biāo);
 - p16 = isa（類的首地址）
 - p11 = _bucketsAndMaybeMask
 - p13 = hash下標(biāo)對應(yīng)的bucket地址
 */
//---- PTRSHIFT = 3； p13 = p10 + (p12 << 1+3) 這一步就是為了找到 下標(biāo)對應(yīng)的 bucket的位置
    add p13, p10, p12, LSL #(1+PTRSHIFT)
                        // p13 = buckets + ((_cmd & mask) << (1+PTRSHIFT))

                        // do {
//---- ldp操作兩個寄存器，從hash下標(biāo)對應(yīng)的bucket地址中 取出對應(yīng)的 imp 和 sel， 然后p13的地址向左平移1步長（hash沖突，重新計算下標(biāo)，與cache_t 中的insert算法相同）
1:  ldp p17, p9, [x13], #-BUCKET_SIZE   //     {imp, sel} = *bucket--
//---- 比較sel 與要調(diào)用的_cmd是否相等
    cmp p9, p1              //     if (sel != _cmd) {
//---- b.ne (not equal)不相等，跳轉(zhuǎn)到#3繼續(xù)執(zhí)行
    b.ne    3f              //         scan more
                        //     } else {
//---- CacheHit緩存命中，即在緩存中已經(jīng)有這個方法了，直接返回imp
2:  CacheHit \Mode              // hit:    call or return imp
                        //     }
//---- 如果p9為空，即 sel == 0，表示緩存中沒有這個方法，跳轉(zhuǎn)到__objc_msgSend_uncached
3:  cbz p9, \MissLabelDynamic       //     if (sel == 0) goto Miss;
//---- 如果bucket >= buckets（沒有越界），繼續(xù)跳轉(zhuǎn)到1流程，查找bucket
    cmp p13, p10            // } while (bucket >= buckets)
    b.hs    1b

    // wrap-around:
    //   p10 = first bucket
    //   p11 = mask (and maybe other bits on LP64)
    //   p12 = _cmd & mask
    //
    // A full cache can happen with CACHE_ALLOW_FULL_UTILIZATION.
    // So stop when we circle back to the first probed bucket
    // rather than when hitting the first bucket again.
    //
    // Note that we might probe the initial bucket twice
    // when the first probed slot is the last entry.

//---- 遍歷緩存至 buckets首地址還沒有找到，則跳到最后一個bucket的位置，繼續(xù)向前查找，
/**
 ---- 此時幾個參數(shù)分別代表：
 - p10 = buckets;
 - p12 = (_cmd ^ (_cmd >> 7)) & mask  即hash下標(biāo);
 - p16 = isa（類的首地址）
 - p11 = _bucketsAndMaybeMask
 - p13 = hash下標(biāo)對應(yīng)的bucket地址
 */
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16_BIG_ADDRS
    add p13, p10, w11, UXTW #(1+PTRSHIFT)
                        // p13 = buckets + (mask << 1+PTRSHIFT)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
//---- 將p13定位到最后一個 bucket的位置
    add p13, p10, p11, LSR #(48 - (1+PTRSHIFT))
                        // p13 = buckets + (mask << 1+PTRSHIFT)
                        // see comment about maskZeroBits
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    add p13, p10, p11, LSL #(1+PTRSHIFT)
                        // p13 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif

//---- p12 = 第一次hash 計算的index
    add p12, p10, p12, LSL #(1+PTRSHIFT)
                        // p12 = first probed bucket

//---- 向前循環(huán)查找方法
                        // do {
//---- ldp操作兩個寄存器，從hash下標(biāo)對應(yīng)的bucket地址中 取出對應(yīng)的 imp 和 sel， 然后p13的地址向左平移1步長（hash沖突，重新計算下標(biāo)，與cache_t 中的insert算法相同）
4:  ldp p17, p9, [x13], #-BUCKET_SIZE   //     {imp, sel} = *bucket--
//---- 比較sel 與要調(diào)用的_cmd是否相等
    cmp p9, p1              //     if (sel == _cmd)
//---- 如果相等，CacheHit緩存命中，即在緩存中已經(jīng)有這個方法了，跳轉(zhuǎn)到 【2流程】，然后返回imp
    b.eq    2b              //         goto hit
    cmp p9, #0              // } while (sel != 0 &&
    ccmp    p13, p12, #0, ne        //     bucket > first_probed)
//---- b.hi 表示無符號大于，繼續(xù)循環(huán)執(zhí)行，跳轉(zhuǎn)【4流程】
    b.hi    4b

LLookupEnd\Function:

LLookupRecover\Function:
//---- 跳轉(zhuǎn)至__objc_msgSend_uncached，即進入慢速查找流程
    b   \MissLabelDynamic

主要分為以下幾步

【第一步】通過cache首地址平移16字節(jié)（因為在objc_class中，首地址距離cache正好16字節(jié)，即isa 占8字節(jié)，superClass占8字節(jié)）獲取cahce，cache中高16位存mask，低48位存buckets，即p11 = cache
【第二步】從cache中分別取出buckets和mask，并由mask根據(jù)哈希算法計算出哈希下標(biāo)
- 通過cache和掩碼（即0x0000fffffffffffe）的 & 運算，將高16位mask抹零，得到buckets指針地址，即p10 = buckets
- 將cache右移48位，得到mask，即p11 = mask
- 將objc_msgSend的參數(shù)p1（即第二個參數(shù)_cmd）& msak，通過哈希算法，得到需要查找存儲sel-imp的bucket下標(biāo)index，即p12 = index = _cmd & mask，為什么通過這種方式呢？因為在存儲sel-imp時，也是通過同樣哈希算法計算哈希下標(biāo)進行存儲，所以讀取也需要通過同樣的方式讀取，如下所示
  
  image
【第三步】根據(jù)所得的哈希下標(biāo)index 和 buckets首地址，取出哈希下標(biāo)對應(yīng)的bucket
- 其中PTRSHIFT等于3，左移4位（即2^4 = 16字節(jié)）的目的是計算出一個bucket實際占用的大小，結(jié)構(gòu)體bucket_t中sel占8字節(jié)，imp占8字節(jié)
- 根據(jù)計算的哈希下標(biāo)index 乘以 單個bucket占用的內(nèi)存大小，得到內(nèi)存中的偏移量
- 通過buckets首地址 + 偏移量，獲取哈希下標(biāo)index對應(yīng)的bucket地址
【第四步】根據(jù)獲取的bucket，取出其中的imp存入p17，即p17 = imp，取出sel存入p9，即p9 = sel
【第五步】第一次遞歸循環(huán)
- 比較獲取的bucket中sel 與 objc_msgSend的第二個參數(shù)的_cmd(即p1)是否相等
- 如果相等，則直接跳轉(zhuǎn)至CacheHit，即緩存命中，返回imp
- 如果不相等，有以下幾種情況
  - 如果sel == 0，說明buckets中沒有有方法，會跳轉(zhuǎn)至__objc_msgSend_uncached，即進入慢速查找流程
  - 如果當(dāng)前bucket >= buckets的第一個元素，則繼續(xù)向前查找，重復(fù)【第五步】第一次遞歸循環(huán)
  - 如果發(fā)生越界，將bucket定位到buckets的最后一個位置
【第六步】第二次遞歸循環(huán)
- 重復(fù)【第五步】的操作，繼續(xù)向前查找，直到【第二步】計算的哈希下標(biāo)
- 如果沒有找到，跳轉(zhuǎn)至__objc_msgSend_uncached，即進入慢速查找流程

緩存快速查找流程圖

流程圖-待補充

色偷偷精品伊人,欧洲久久精品,欧美综合婷婷骚逼,国产AV主播,国产最新探花在线,九色在线视频一区,伊人大交九欧美,1769亚洲,黄色成人av

iOS底層原理10：消息流程分析之快速查找

iOS底層原理10：消息流程分析之快速查找

Runtime 介紹

探索方法的本質(zhì)

方法的本質(zhì)

通過Runtime API調(diào)用方法

objc_msgSendSuper方法探究

objc_msgSend 快速查找流程分析

【補充知識】-- Tagged Pointer對象

objc_msgSend 匯編源碼

CacheLookup(緩存查找)匯編源碼

緩存快速查找流程圖

相關(guān)閱讀更多精彩內(nèi)容

友情鏈接更多精彩內(nèi)容

色偷偷精品伊人,欧洲久久精品,欧美综合婷婷骚逼,国产AV主播,国产最新探花在线,九色在线视频一区,伊人大交九 欧美,1769亚洲,黄色成人av

iOS底層原理10：消息流程分析之快速查找

Runtime 介紹

探索方法的本質(zhì)

方法的本質(zhì)

通過Runtime API調(diào)用方法

objc_msgSendSuper方法探究

objc_msgSend 快速查找流程分析

【補充知識】-- Tagged Pointer對象

objc_msgSend 匯編源碼

CacheLookup(緩存查找)匯編源碼

緩存快速查找流程圖

相關(guān)閱讀更多精彩內(nèi)容

友情鏈接更多精彩內(nèi)容

色偷偷精品伊人,欧洲久久精品,欧美综合婷婷骚逼,国产AV主播,国产最新探花在线,九色在线视频一区,伊人大交九欧美,1769亚洲,黄色成人av