1. 問題描述
ANSYS的諸多結(jié)構(gòu)建模分析技術(shù)，往往需要一個(gè)最簡單的案例進(jìn)行測試。所有問題中，最簡單、最有代表性的問題即為：簡支鋼梁的重力加載分析。
麻雀雖小，五臟俱全。極簡算例包含了ANSYS結(jié)構(gòu)分析的所有必要過程：
image_1b1qut4d1s53lst1cjjds38ug16.png-37.5kB
2. 技術(shù)背景
采用ANSYS命令流建模，保證模型的通用性。
3. 解決方案
建模參數(shù)：
- 材料：鋼材；
- 梁長：10m；
- 邊界：簡支；
- 荷載：自重；
- 單元：beam188;
4. 實(shí)施示例
4.1 文件頭
!---------------------------------------------------------------------
! 題目：鋼材簡支梁結(jié)構(gòu)分析
! 要點(diǎn)：1. 簡支鋼梁建模
! 2. 加載：重力加載
! 3. 彎矩圖繪制
! FRANK2015,HIT,2016.11.18
!---------------------------------------------------------------------
FINI
/CLEAR
4.2 幾何建模
!---------------------------------幾何建模 ---------------------------
/PREP7
K,1,0 ! 支座點(diǎn)
K,2,10
L,1,2
image_1b1qv2bq5b11e04v291cpl187m1j.png-15.2kB
4.2 材料參數(shù)
!---------------------------------材料參數(shù) ---------------------------
MP,EX,1,2.0E11 ! 鋼材，彈性模量
MP,PRXY,1,0.3 ! 彈性模量
MP,Dens,1,7800 ! 密度
ET,1,BEAM188 ! 三維梁單元
KEYOPT,1,3,3 ! 定義三次形函數(shù)
SECTYPE,1,BEAM,RECT ! 矩形截面
SECDATA,0.5,1
4.3 網(wǎng)格劃分
!---------------------------------網(wǎng)格劃分 ---------------------------
LSEL,ALL
LATT,1,,1,,,,1 ! 附加單元材料屬性
LESIZE,ALL,,,10 ! 劃分10段網(wǎng)格
LMESH,ALL ! 生成有限單元
n1 = node(0,0,0) ! 提取坐標(biāo)節(jié)點(diǎn)
n2 = node(10,0,0)
4.4 邊界條件
!---------------------------------邊界條件 ---------------------------
D,n1,UY,,,,,UZ,ROTX,ROTZ ! 簡支梁端支座
D,n1,UX
D,n2,UY,,,,,UZ,ROTX,ROTZ
/PNUM,ELEM,1 ! 顯示單元號(hào)
/PBC,ALL ! 顯示約束
4.5 重力加載求解
!-------------------------------重力求解 ---------------------------
/SOLU
ANTYPE,STATIC
ACEL,,,9.8 ! z向重力加載
SOLVE
FINISH
此處，ANSYS的Z方向重力為默認(rèn)方向，直接輸入重力加速度9.8即可。
4.6 后處理
!---------------------------------后處理 ---------------------------
/POST1
PLDISP,1 ! 變形圖
ETABLE,MI,SMISC,2 ! MY
ETABLE,MJ,SMISC,15
PLLS,MI,MJ,1 ! 彎矩圖
位移圖.png-26kB
彎矩圖.png-33.7kB
5. 常見問題
精簡代碼如下：
FINI
/CLEAR
!---------------------------------幾何建模 ---------------------------
/PREP7
K,1,0 ! 支座點(diǎn)
K,2,10
L,1,2
!---------------------------------材料參數(shù) ---------------------------
MP,EX,1,2.0E11 ! 鋼材，彈性模量
MP,PRXY,1,0.3 ! 彈性模量
MP,Dens,1,7800 ! 密度
ET,1,BEAM188 ! 三維梁單元
KEYOPT,1,3,3 ! 定義三次形函數(shù)
SECTYPE,1,BEAM,RECT ! 矩形截面
SECDATA,0.5,1
!---------------------------------網(wǎng)格劃分 ---------------------------
LSEL,ALL
LATT,1,,1,,,,1 ! 附加單元材料屬性
LESIZE,ALL,,,10 ! 劃分10段網(wǎng)格
LMESH,ALL ! 生成有限單元
n1 = node(0,0,0) ! 提取坐標(biāo)節(jié)點(diǎn)
n2 = node(10,0,0)
!---------------------------------支座約束 ---------------------------
D,n1,UY,,,,,UZ,ROTX,ROTZ ! 簡支梁端支座
D,n1,UX
D,n2,UY,,,,,UZ,ROTX,ROTZ
/PNUM,ELEM,1 ! 顯示單元號(hào)
/PBC,ALL ! 顯示約束
!---------------------------------求解 ---------------------------
/SOLU
ANTYPE,STATIC
ACEL,,,9.8 ! z向重力加載
SOLVE
FINISH
!---------------------------------后處理 ---------------------------
/POST1
PLDISP,1 ! 變形圖
ETABLE,MI,SMISC,2 ! MY
ETABLE,MJ,SMISC,15
PLLS,MI,MJ,1 ! 彎矩圖
本文用時(shí) 30 m。
