最新內(nèi)容會更新在主站深入淺出區(qū)塊鏈社區(qū)
原文鏈接:智能合約語言 Solidity 教程系列10 - 完全理解函數(shù)修改器

這是Solidity教程系列文章第10篇，帶大家完全理解Solidity的函數(shù)修改器。
Solidity系列完整的文章列表請查看分類-Solidity。

寫在前面

Solidity 是以太坊智能合約編程語言，閱讀本文前，你應(yīng)該對以太坊、智能合約有所了解，
如果你還不了解，建議你先看以太坊是什么

歡迎訂閱區(qū)塊鏈技術(shù)專欄閱讀更全面的分析文章。

函數(shù)修改器(Function Modifiers)

函數(shù)修改器(Modifiers)可以用來改變一個(gè)函數(shù)的行為。比如用于在函數(shù)執(zhí)行前檢查某種前置條件。

如果熟悉Python的同學(xué)，會發(fā)現(xiàn)函數(shù)修改器的作用和Python的裝飾器很相似。

修改器是一種可被繼承合約屬性，同時(shí)還可被繼承的合約重寫(override)。下面我們來看一段示例代碼：

pragma solidity ^0.4.11;

contract owned {
    function owned() public { owner = msg.sender; }
    address owner;

    // 定義了一個(gè)函數(shù)修改器，可被繼承
    //  修飾時(shí)，函數(shù)體被插入到 “_;” 處
    // 不符合條件時(shí)，將拋出異常
    modifier onlyOwner {
        require(msg.sender == owner);
        _;
    }
}

contract mortal is owned {
    //  使用繼承的`onlyOwner` 
    function close() public onlyOwner {
        selfdestruct(owner);
    }
}

contract priced {
    // 函數(shù)修改器可接收參數(shù)
    modifier costs(uint price) {
        if (msg.value >= price) {
            _;
        }
    }
}

contract Register is priced, owned {
    mapping (address => bool) registeredAddresses;
    uint price;

    function Register(uint initialPrice) public { price = initialPrice; }

    // 需要提供payable 以接受以太
    function register() public payable costs(price) {
        registeredAddresses[msg.sender] = true;
    }

    function changePrice(uint _price) public onlyOwner {
        price = _price;
    }
}

上面onlyOwner就是定義的一個(gè)函數(shù)修改器，當(dāng)用這個(gè)修改器區(qū)修飾一個(gè)函數(shù)時(shí)，則函數(shù)必須滿足onlyOwner的條件才能運(yùn)行，這里的條件是：必須是合約的創(chuàng)建這才能調(diào)用函數(shù)，否則拋出異常。
我們在實(shí)現(xiàn)一個(gè)可管理、增發(fā)、兌換、凍結(jié)等高級功能的代幣文章中就使用了這個(gè)函數(shù)修改器。

多個(gè)修改器

如果同一個(gè)函數(shù)有多個(gè)修改器，他們之間以空格隔開，修飾器會依次檢查執(zhí)行。

在修改器中或函數(shù)內(nèi)的顯式的return語句，僅僅跳出當(dāng)前的修改器或函數(shù)。返回的變量會被賦值，但執(zhí)行流會在前一個(gè)修改器后面定義的"_"后繼續(xù)執(zhí)行， 如：

contract Mutex {
    bool locked;
    modifier noReentrancy() {
        require(!locked);
        locked = true;
        _;
        locked = false;
    }

    // 防止遞歸調(diào)用
    // return 7 之后，locked = false 依然會執(zhí)行
    function f() public noReentrancy returns (uint) {
        require(msg.sender.call());
        return 7;
    }
}

修改器的參數(shù)可以是任意表達(dá)式。在此上下文中，所有的函數(shù)中引入的符號，在修改器中均可見。但修改器中引入的符號在函數(shù)中不可見，因?yàn)樗鼈冇锌赡鼙恢貙憽?/p>

深入理解修改器的執(zhí)行次序

再來看一個(gè)復(fù)雜一點(diǎn)的例子，來深入理解修改器：

pragma solidity ^0.4.11;


contract modifysample {

    uint a = 10;
    
    modifier mf1 (uint b) {
        uint c = b;
        _;
        c = a;
        a = 11;
    }
    
     modifier mf2 () {
        uint c = a;
        _;
    }
    
    modifier mf3() {
        a = 12;
        return ;
        _;
        a = 13;
    }
    
    function test1() mf1(a) mf2 mf3 public   {
        a = 1;
    }
    
     function test2() public constant returns (uint)   {
        return a;  
    }  
}

上面的智能合約運(yùn)行test1()之后，狀態(tài)變量a的值是多少， 是1， 11， 12，還是13呢？
答案是 11, 大家可以運(yùn)行下test2獲取下a值。

我們來分析一下 test1， 它擴(kuò)展之后是這樣的：

uint c = b;
        uint c = a;
            a = 12;
            return ;
            _;
            a = 13;
c = a;
a = 11;

這個(gè)時(shí)候就一目了然了，最后a 為11， 注意第5及第6行是不是執(zhí)行的。

參考視頻

我們也推出了目前市面上最全的視頻教程：深入詳解以太坊智能合約語言Solidity

目前我們也在招募體驗(yàn)師，可以點(diǎn)擊鏈接了解。

參考文獻(xiàn)

官方文檔-Function Modifiers

如果你想和認(rèn)識我，和我建立聯(lián)系，歡迎加入知識星球深入淺出區(qū)塊鏈，我會在星球?yàn)榇蠹医獯鸺夹g(shù)問題，作為星友福利，星友可加入我創(chuàng)建的區(qū)塊鏈技術(shù)群，群內(nèi)已經(jīng)聚集了100多位區(qū)塊鏈技術(shù)愛好者。

深入淺出區(qū)塊鏈 - 系統(tǒng)學(xué)習(xí)區(qū)塊鏈，打造最好的區(qū)塊鏈技術(shù)博客。