Long類型數值比較及反匯編分析源碼

一、問題描述

開發(fā)過程中遇到如下問題

Long a = 100L;
Long b = 100L;
System.out.println(a == b);
System.out.println(a.equals(b));
System.out.println(a == 100);
System.out.println(a.equals(100));

輸出結果：

true
true
true
false

但是當Long類型大于127時：

Long a = 128L;
Long b = 128L;
System.out.println(a == b);
System.out.println(a.equals(b));
System.out.println(a == 128);
System.out.println(a.equals(128));

輸出結果：

false
true
true
false

二、問題分析

查看源碼：java.lang.Long.java

LongCache會預先緩存-128–127范圍內的數，通過緩存頻繁請求的值代來更好的空間和時間性能，

當數據超出此范圍，則new一個Long對象；

“==”是比較的地址，超出此范圍的數據地址不一致，所以范圍內的比較是true，范圍外的數據是false；

而a==100則實現了類型的自動向上轉換，將int類型轉換成Long進行對比，所以輸出true；

在Long.java里重寫了equals()方法，先進行類型對比，在進行值的對比，所以a.equals(100)輸出false；

三、源碼分析(反匯編法)

我們先看下面的示例代碼，并思考該段代碼的輸出結果：

public class IntTest {
    public static void main(String[] args) {
        Integer a = 100, b = 100, c = 150, d = 150;
        System.out.println(a == b);
        System.out.println(c == d);
    }
}

通過運行代碼可以得到答案，程序輸出的結果分別為： true , false。

首先編譯源代碼：javac IntTest.java

然后需要對代碼進行反匯編，執(zhí)行：javap -c IntTest

反編譯后，我們得到以下代碼：

Compiled from "IntTest.java"
public class com.chujianyun.common.int_test.IntTest {
  public com.chujianyun.common.int_test.IntTest();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public static void main(java.lang.String[]);
    Code:
       0: bipush        100
       2: invokestatic  #2                  // Method java/lang/Integer.valueOf:(I)Ljava/lang/Integer;
       5: astore_1
       6: bipush        100
       8: invokestatic  #2                  // Method java/lang/Integer.valueOf:(I)Ljava/lang/Integer;
      11: astore_2
      12: sipush        150
      15: invokestatic  #2                  // Method java/lang/Integer.valueOf:(I)Ljava/lang/Integer;
      18: astore_3
      19: sipush        150
      22: invokestatic  #2                  // Method java/lang/Integer.valueOf:(I)Ljava/lang/Integer;
      25: astore        4
      27: getstatic     #3                  // Field java/lang/System.out:Ljava/io/PrintStream;
      30: aload_1
      31: aload_2
      32: if_acmpne     39
      35: iconst_1
      36: goto          40
      39: iconst_0
      40: invokevirtual #4                  // Method java/io/PrintStream.println:(Z)V
      43: getstatic     #3                  // Field java/lang/System.out:Ljava/io/PrintStream;
      46: aload_3
      47: aload         4
      49: if_acmpne     56
      52: iconst_1
      53: goto          57
      56: iconst_0
      57: invokevirtual #4                  // Method java/io/PrintStream.println:(Z)V
      60: return
}

可以明確得 "看到" 這四個 ``Integer var = ? 形式聲明的變量的確是通過 java.lang.Integer#valueOf(int) 來構造 Integer` 對象的。

接下來對匯編后的代碼進行詳細分析，如果看不懂可略過：
根據《Java Virtual Machine Specification : Java SE 8 Edition》3，后縮寫為 JVMS , 第 6 章 虛擬機指令集的相關描述以及《深入理解 Java 虛擬機》4 414-149 頁的 附錄 B “虛擬機字節(jié)碼指令表”。 我們對上述指令進行解讀：

  • 偏移為 0 的指令為：bipush 100 ，其含義是將單字節(jié)整型常量 100 推入操作數棧的棧頂；

  • 偏移為 2 的指令為：invokestatic #2 // Method java/lang/Integer.valueOf:(I)Ljava/lang/Integer; 表示調用一個 static 函數，即 java.lang.Integer#valueOf(int)；

  • 偏移為 5 的指令為：astore_1 ，其含義是從操作數棧中彈出對象引用，然后將其存到第 1 個局部變量 Slot 中；

  • 偏移 6 到 25 的指令和上面類似；

  • 偏移為 30 的指令為 aload_1 ，其含義是從第 1 個局部變量 Slot 取出對象引用（即 a），并將其壓入棧；

  • 偏移為 31 的指令為 aload_2 ，其含義是從第 2 個局部變量 Slot 取出對象引用（即 b），并將其壓入棧；

  • 偏移為 32 的指令為 if_acmpn，該指令為條件跳轉指令，if_ 后以 a 開頭表示對象的引用比較。

由于該指令有以下特性：
if_acmpeq 比較棧兩個引用類型數值，相等則跳轉
if_acmpne 比較棧兩個引用類型數值，不相等則跳轉

  • 由于 Integer 的緩存問題，所以 a 和 b 引用指向同一個地址，因此此條件不成立（成立則跳轉到偏移為 39 的指令處），執(zhí)行偏移為 35 的指令。

  • 偏移為 35 的指令: iconst_1，其含義為將常量 1 壓棧（ Java 虛擬機中 boolean 類型的運算類型為 int ，其中 true 用 1 表示，詳見 2.11.1 數據類型和 Java 虛擬機。

  • 然后執(zhí)行偏移為 36 的 goto 指令，跳轉到偏移為 40 的指令。

  • 偏移為 40 的指令：invokevirtual #4 // Method java/io/PrintStream.println:(Z)V。

可知參數描述符為 Z ，返回值描述符為 V。

根據 4.3.2 字段描述符 ，可知 FieldType 的字符為 Z 表示 boolean 類型， 值為 true 或 false。
根據 4.3.3 字段描述符 ，可知返回值為 void。

因此可以知，最終調用了 java.io.PrintStream#println(boolean) 函數打印棧頂常量即 true。

  • 然后比較執(zhí)行偏移 43 到 57 之間的指令，比較 c 和 d， 打印 false 。

  • 執(zhí)行偏移為 60 的指令，即 retrun ，程序結束。

同樣地我們也編寫一個Long類型的示例片段：

public class LongTest {

    public static void main(String[] args) {
        Long a = -128L, b = -128L, c = 150L, d = 150L;
        System.out.println(a == b);
        System.out.println(c == d);
    }
}

得到下面反編譯的代碼：

public class com.imooc.basic.learn_int.LongTest {
  public com.imooc.basic.learn_int.LongTest();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public static void main(java.lang.String[]);
    Code:
       0: ldc2_w        #2                  // long -128l
       3: invokestatic  #4                  // Method java/lang/Long.valueOf:(J)Ljava/lang/Long;
       6: astore_1
       7: ldc2_w        #2                  // long -128l
      10: invokestatic  #4                  // Method java/lang/Long.valueOf:(J)Ljava/lang/Long;
      13: astore_2
      14: ldc2_w        #5                  // long 150l
      17: invokestatic  #4                  // Method java/lang/Long.valueOf:(J)Ljava/lang/Long;
      20: astore_3
      21: ldc2_w        #5                  // long 150l
      24: invokestatic  #4                  // Method java/lang/Long.valueOf:(J)Ljava/lang/Long;
      27: astore        4
      29: getstatic     #7                  // Field java/lang/System.out:Ljava/io/PrintStream;
      32: aload_1
      33: aload_2
      34: if_acmpne     41
      37: iconst_1
      38: goto          42
      41: iconst_0
      42: invokevirtual #8                  // Method java/io/PrintStream.println:(Z)V
      45: getstatic     #7                  // Field java/lang/System.out:Ljava/io/PrintStream;
      48: aload_3
      49: aload         4
      51: if_acmpne     58
      54: iconst_1
      55: goto          59
      58: iconst_0
      59: invokevirtual #8                  // Method java/io/PrintStream.println:(Z)V
      62: return
}

我們從上述代碼中發(fā)現 Long var = ? 的確是通過 java.lang.Long#valueOf(long) 來構造對象的。

三、解決問題方案

對于Long類型的對比，不要用“==”，盡量避免Long類型的直接對比

將Long轉換成基本類型再進行比較：a.longValue() == b.longValue()，或者0 == Long.compare(a, b)；

?著作權歸作者所有,轉載或內容合作請聯(lián)系作者
【社區(qū)內容提示】社區(qū)部分內容疑似由AI輔助生成，瀏覽時請結合常識與多方信息審慎甄別。
平臺聲明：文章內容（如有圖片或視頻亦包括在內）由作者上傳并發(fā)布，文章內容僅代表作者本人觀點，簡書系信息發(fā)布平臺，僅提供信息存儲服務。

相關閱讀更多精彩內容

友情鏈接更多精彩內容