Runtime

啟動(dòng)流程

objc-os.mm的init方法是初始化的入口。

void _objc_init(void)
{
    static bool initialized = false;
    if (initialized) return;
    initialized = true;
    
    // fixme defer initialization until an objc-using image is found?
    environ_init();
    tls_init();
    static_init();
    lock_init();
    exception_init();

    _dyld_objc_notify_register(&map_images, load_images, unmap_image);
}

幾個(gè)初始化

  • environ_init，讀取環(huán)境配置方法，在這個(gè)方法里會(huì)讀取在Xcode 中配置的環(huán)境變量參數(shù)
  • tls_init，用于初始化不是使用pthread_key_create()創(chuàng)建的線程的析構(gòu)函數(shù)
  • static_init，執(zhí)行 C++ 靜態(tài)構(gòu)造函數(shù)功能
  • lock_init，初始化后臺(tái)線程和主線程優(yōu)先級(jí)
  • exception_init，異常初始化

map_images

在map_images函數(shù)中，內(nèi)部也是做了一個(gè)調(diào)用中轉(zhuǎn)。然后調(diào)用到map_images_nolock函數(shù)，內(nèi)部核心就是_read_images函數(shù)。先整體梳理一遍_(kāi)read_images函數(shù)內(nèi)部的邏輯：

  1. 加載所有類(lèi)到類(lèi)的gdb_objc_realized_classes表中。
  2. 對(duì)所有類(lèi)做重映射。
  3. 將所有SEL都注冊(cè)到namedSelectors表中。
  4. 修復(fù)函數(shù)指針遺留。
  5. 將所有Protocol都添加到protocol_map表中。
  6. 對(duì)所有Protocol做重映射。
  7. 初始化所有非懶加載的類(lèi)，進(jìn)行rw、ro等操作。
  8. 遍歷已標(biāo)記的懶加載的類(lèi)，并做初始化操作。
  9. 處理所有Category，包括Class和Meta Class。
  10. 初始化所有未初始化的類(lèi)。

load_images

在load_images函數(shù)中主要做了兩件事，

  1. 首先通過(guò)prepare_load_methods函數(shù)準(zhǔn)備Class load list和Category load list，
  2. 然后通過(guò)call_load_methods函數(shù)調(diào)用已經(jīng)準(zhǔn)備好的兩個(gè)方法列表

isa

在ARM 64之前，isa是一個(gè)指針，存儲(chǔ)著Class、Meta-Class對(duì)象的內(nèi)存地址。
ARM 64之后，isa是一個(gè)共用體，除了存儲(chǔ)Class、Meta-Class對(duì)象的內(nèi)存地址，還保存了更多的信息。ARM 64情況下，isa共用體的定義。

union isa_t 
{
    isa_t() { }
    isa_t(uintptr_t value) : bits(value) { }
    Class cls;
    uintptr_t bits;
#   define ISA_MASK        0x0000000ffffffff8ULL
#   define ISA_MAGIC_MASK  0x000003f000000001ULL
#   define ISA_MAGIC_VALUE 0x000001a000000001ULL
    struct {
        uintptr_t nonpointer        : 1;
        uintptr_t has_assoc         : 1;
        uintptr_t has_cxx_dtor      : 1;
        uintptr_t shiftcls          : 33; // MACH_VM_MAX_ADDRESS 0x1000000000
        uintptr_t magic             : 6;
        uintptr_t weakly_referenced : 1;
        uintptr_t deallocating      : 1;
        uintptr_t has_sidetable_rc  : 1;
        uintptr_t extra_rc          : 19;
#       define RC_ONE   (1ULL<<45)
#       define RC_HALF  (1ULL<<18)
    };
}

isa的位域的意義

  • nonpointer
    - 0 ，表示指針，存儲(chǔ)Class對(duì)象地址
    - 1，使用共用體，存儲(chǔ)更多信息
  • has_assoc
    - 是否設(shè)置過(guò)關(guān)對(duì)象。如果沒(méi)有，該對(duì)象會(huì)釋放地更快
  • has_cxx_dtor
    - 是否有C++析構(gòu)函數(shù)。如果沒(méi)有，該對(duì)象會(huì)釋放地更快
  • shiftcls
    - 類(lèi)對(duì)象，元類(lèi)對(duì)象的內(nèi)存地址
  • magic
    - 對(duì)象是否完成初始化
  • weakly_referenced
    - 是否被若引用指向過(guò)。如果沒(méi)有，該對(duì)象會(huì)釋放地更快
  • deallocating
    - 是否正在被釋放
  • has_sidetable_rc
    - 是否引用計(jì)數(shù)器過(guò)大，不能保存在isa中。如果過(guò)大，會(huì)保存在SideTable中
  • extra_rc
    - 保存該對(duì)象的引用計(jì)數(shù)減1

method_t

struct method_t {
    SEL name;       // 底層結(jié)構(gòu)類(lèi)似于char *
    const char *types;
    IMP imp;     // 該表函數(shù)的具體實(shí)現(xiàn)
};

SEL代表方法\函數(shù)名，一般叫做選擇器，底層結(jié)構(gòu)跟char *類(lèi)似

  • 可以通過(guò)@selector()和sel_registerName()獲得
  • 可以通過(guò)sel_getName()和NSStringFromSelector()
  • 不同類(lèi)中相同名字的方法，所對(duì)應(yīng)的方法選擇器是相同的

types包含了函數(shù)返回值，參數(shù)編碼的字符串

// i 24  @ 0  : 8   i 16  f 20
/*  i 24，表示所有參數(shù)占據(jù)的字節(jié)數(shù)
    @ 0，表示第一個(gè)參數(shù)，self，從第0個(gè)參數(shù)開(kāi)始
    : 8，表示第二個(gè)參數(shù)，SEL，從第8個(gè)開(kāi)始
    i 16，表示(int)age
    f 20，表示(float)height
 */
- (void)test:(int)age height:(float)height {
 
}

IMP表示函數(shù)的具體實(shí)現(xiàn)

typedef id _Nullable (*IMP)(id _Nonnull, SEL _Nonnull, ...);

cache_t

struct cache_t {
    struct bucket_t *_buckets;      // 數(shù)組
    mask_t _mask;          // 數(shù)組長(zhǎng)度
    mask_t _occupied;    // 已經(jīng)使用的長(zhǎng)度
}

struct bucket_t {
private:
    cache_key_t _key;      // SEL
    IMP _imp;
}

散列表使用的hash算法，就是&運(yùn)算

static inline mask_t cache_hash(cache_key_t key, mask_t mask) 
{
    return (mask_t)(key & mask);
}

如果發(fā)生Hash碰撞，則從前一個(gè)開(kāi)始找，直到索引為0。如果還找不到，就再?gòu)臄?shù)組最后一個(gè)，倒序開(kāi)始找。

bucket_t * cache_t::find(cache_key_t k, id receiver)
{
    assert(k != 0);

    bucket_t *b = buckets();
    mask_t m = mask();
    mask_t begin = cache_hash(k, m);
    mask_t i = begin;
    do {
        if (b[i].key() == 0  ||  b[i].key() == k) {
            return &b[i];
        }
    } while ((i = cache_next(i, m)) != begin);

    // hack
    Class cls = (Class)((uintptr_t)this - offsetof(objc_class, cache));
    cache_t::bad_cache(receiver, (SEL)k, cls);
}

子類(lèi)調(diào)用父類(lèi)方法之后，先在子類(lèi)找不到方法，然后去父類(lèi)找，

  • 也是先找父類(lèi)的緩存，再找父類(lèi)的方法列表
  • 找到之后，會(huì)把方法緩存到子類(lèi)的cache中

緩存的時(shí)候，如果緩存滿了，則清除所有緩存，并且2倍擴(kuò)容

void cache_t::expand()
{
    cacheUpdateLock.assertLocked();
    
    uint32_t oldCapacity = capacity();
    uint32_t newCapacity = oldCapacity ? oldCapacity*2 : INIT_CACHE_SIZE;

    if ((uint32_t)(mask_t)newCapacity != newCapacity) {
        // mask overflow - can't grow further
        // fixme this wastes one bit of mask
        newCapacity = oldCapacity;
    }

    reallocate(oldCapacity, newCapacity);
}

obj_msgSend()

OC中的方法調(diào)用，都是轉(zhuǎn)換成調(diào)用obj_msgSend()函數(shù)。整個(gè)過(guò)程可以分成3個(gè)階段：

  • 消息發(fā)送：根據(jù)OC對(duì)象模型圖，從子類(lèi)到父類(lèi)，去找方法
  • 動(dòng)態(tài)方法解析：可能會(huì)向類(lèi)對(duì)象添加方法
  • 消息轉(zhuǎn)發(fā)：可能將該方法調(diào)用，轉(zhuǎn)到其他對(duì)象去調(diào)用。
_class_lookupMethodAndLoadCache3
lookUpImpOrForward
getMethodNoSuper_nolock、search_method_list、log_and_fill_cache
cache_getImp、log_and_fill_cache、getMethodNoSuper_nolock、log_and_fill_cache
_class_resolveInstanceMethod
_objc_msgForward_impcache

匯編調(diào)用

由于obj_msgSend()調(diào)用十分頻繁，所以obj_msgSend()有一部分是使用匯編實(shí)現(xiàn)的。
一般如果是C函數(shù)是objc_msgSend，則對(duì)應(yīng)的匯編函數(shù)就是加上下劃線_objc_msgSend
匯編做了如下工作：

  • 判斷receiver是否為nil，如果是nil就直接返回
  • 查找緩存，如果緩存沒(méi)有命中，就在方法列表查找方法
objc-msg-arm64.s
ENTRY _objc_msgSend
b.le    LNilOrTagged
CacheLookup NORMAL
.macro CacheLookup
.macro CheckMiss
STATIC_ENTRY __objc_msgSend_uncached
.macro MethodTableLookup
__class_lookupMethodAndLoadCache3

查找方法

匯編函數(shù)是__class_lookupMethodAndLoadCache3，則對(duì)應(yīng)的runtime方法是_class_lookupMethodAndLoadCache3
在C函數(shù)還是會(huì)查找一遍緩存，原因是：再執(zhí)行到這次的查找緩存之前，可能動(dòng)態(tài)添加一些方法，緩存方法變化。

  • 在本類(lèi)進(jìn)行查找
    1. 再次查找緩存，
    2. 查找方法，在本類(lèi)對(duì)象的方法列表，還可以分成二分查找（如果已經(jīng)排好序）和線性查找。如果找到了，會(huì)進(jìn)行緩存
  • 不斷地向上，在父類(lèi)進(jìn)行查找。不管是
    1. 先找父類(lèi)的緩存。如果找到了，在自己的類(lèi)緩存
    2. 在找父類(lèi)的方法列表。如果找到了，在自己的類(lèi)緩存

動(dòng)態(tài)方法解析

當(dāng)通過(guò)上面的方法查找，找不到方法，就會(huì)進(jìn)入動(dòng)態(tài)方法解析。

  • 通過(guò)triedResolver，只解析一次
  • goto retry會(huì)重新進(jìn)入方法查找：先查找本類(lèi)緩存，在找本類(lèi)方法列表；再父類(lèi)
  if (resolver  &&  !triedResolver) {
        runtimeLock.unlockRead();
        _class_resolveMethod(cls, sel, inst);
        runtimeLock.read();
        // Don't cache the result; we don't hold the lock so it may have 
        // changed already. Re-do the search from scratch instead.
        triedResolver = YES;
        goto retry;
    }

使用如下示例代碼，進(jìn)行動(dòng)態(tài)方法解析

void c_anotherMethod(id self, SEL _cmd)
{
    NSLog(@"c_another class method");
}

- (void)anotherTest {
    NSLog(@"instance %s",__func__);
}

+ (BOOL)resolveClassMethod:(SEL)sel
{
    if (sel == @selector(test)) {
        // 第一個(gè)參數(shù)是object_getClass(self)
        class_addMethod(object_getClass(self), sel, (IMP)c_anotherMethod, "v16@0:8");
        return YES;
    }
    return [super resolveClassMethod:sel];
}

+ (BOOL)resolveInstanceMethod:(SEL)sel {
    if (sel == @selector(test)) {
        Method anotherMethod = class_getInstanceMethod(self, @selector(anotherTest));
        class_addMethod(self,
                        sel,
                        method_getImplementation(anotherMethod),
                        method_getTypeEncoding(anotherMethod));
        return YES;
    }
    
    return [super resolveInstanceMethod:sel];
}

消息轉(zhuǎn)發(fā)

消息轉(zhuǎn)發(fā).png

首先是調(diào)用forwardingTargetForSelector:，如果返回不為nil，就進(jìn)入target的方法調(diào)用流程。forwarding:沒(méi)有開(kāi)源，可以通過(guò)逆向，了解其實(shí)現(xiàn)的。
如果最終能夠走到forwardInvocation:，即使forwardInvocation:是空實(shí)現(xiàn)，該方法調(diào)用也能成功完成。

  1. 調(diào)用forwardInvocation之前，系統(tǒng)會(huì)先調(diào)用resolveInstanceMethod:，傳入的selector為_forwardStackInvocation:
  2. 如果實(shí)現(xiàn)methodSignatureForSelector :，但是沒(méi)有實(shí)現(xiàn)forwardInvocation :，也會(huì)unrecognized selector 
- (id)forwardingTargetForSelector:(SEL)aSelector {
    return [[ForwardTarget alloc] init];
}

// 方法簽名：返回值類(lèi)型、參數(shù)類(lèi)型
- (NSMethodSignature *)methodSignatureForSelector:(SEL)aSelector
{
    if (aSelector == @selector(test)) {
        return [NSMethodSignature signatureWithObjCTypes:"v24@0:8@16"];
    }
    return [super methodSignatureForSelector:aSelector];
}

// NSInvocation封裝了一個(gè)方法調(diào)用，包括：方法調(diào)用者、方法名、方法參數(shù)
//    anInvocation.target 方法調(diào)用者
//    anInvocation.selector 方法名
//    anInvocation.methodSignature methodSignatureForSelector:方法返回的
//    [anInvocation getArgument:NULL atIndex:0]
- (void)forwardInvocation:(NSInvocation *)anInvocation
{
    [anInvocation invokeWithTarget:[[ForwardTarget alloc] init]];
}

Super

[super message]的底層實(shí)現(xiàn)，最初是objc_msgSendSuper(arg, sel)，其中第一個(gè)參數(shù)是結(jié)構(gòu)體，該結(jié)構(gòu)體包含兩個(gè)成員變量：

  1. 消息接收者，就是子類(lèi)實(shí)例對(duì)象
  2. 父類(lèi)類(lèi)對(duì)象，找方法會(huì)從父類(lèi)類(lèi)對(duì)象開(kāi)始找
struct objc_super {
    __unsafe_unretained _Nonnull id receiver; // 消息接收者
    __unsafe_unretained _Nonnull Class super_class; // 消息接收者的父類(lèi)
};

后來(lái)實(shí)現(xiàn)變成objc_msgSendSuper2(arg, sel)，第一個(gè)參數(shù)是結(jié)構(gòu)體，其成員變量是：

  1. 消息接收者，仍然是子類(lèi)對(duì)象
  2. 消息接收者的類(lèi)對(duì)象。但是其內(nèi)部實(shí)現(xiàn)，仍然是獲取父類(lèi)類(lèi)對(duì)象，從父類(lèi)開(kāi)始找
struct objc_super2 {
    __unsafe_unretained _Nonnull id receiver; // 消息接收者
    __unsafe_unretained _Nonnull Class current_class; // 消息接收者的類(lèi)對(duì)象
};

- (instancetype)init
{
    if (self = [super init]) {
        NSLog(@"[self class] = %@", [self class]); // MJStudent
        NSLog(@"[self superclass] = %@", [self superclass]); // MJPerson

        NSLog(@"--------------------------------");

        // objc_msgSendSuper({self, [MJPerson class]}, @selector(class));
        NSLog(@"[super class] = %@", [super class]); // MJStudent
        NSLog(@"[super superclass] = %@", [super superclass]); // MJPerson
    }
    return self;
}

isKindOf

objc的源碼如下，要特別注意的是

  1. + (BOOL)isKindOfClass:，要求傳入的是metaClass，但是最后一步會(huì)走到NSObject的class對(duì)象。
// 這句代碼的方法調(diào)用者不管是哪個(gè)類(lèi)（只要是NSObject體系下的），都返回YES
NSLog(@"%d", [NSObject isKindOfClass:[NSObject class]]); // 1
NSLog(@"%d", [NSObject isMemberOfClass:[NSObject class]]); // 0
NSLog(@"%d", [MJPerson isKindOfClass:[Person class]]); // 0
NSLog(@"%d", [MJPerson isMemberOfClass:[Person class]]); // 0

- (BOOL)isMemberOfClass:(Class)cls {
    return [self class] == cls;
}

- (BOOL)isKindOfClass:(Class)cls {
    for (Class tcls = [self class]; tcls; tcls = tcls->superclass) {
        if (tcls == cls) return YES;
    }
    return NO;
}

+ (BOOL)isMemberOfClass:(Class)cls {
    return object_getClass((id)self) == cls;
}

+ (BOOL)isKindOfClass:(Class)cls {
    for (Class tcls = object_getClass((id)self); tcls; tcls = tcls->superclass) {
        if (tcls == cls) return YES;
    }
    return NO;
}

面試題

以下代碼中，是否能夠正常打印

@interface Person : NSObject
@property (copy, nonatomic) NSString *name;

- (void)print;
@end

@implementation MJPerson

- (void)print
{
    NSLog(@"my name is %@", self->_name);
}

@end

- (void)viewDidLoad {
    [super viewDidLoad];
    
    id cls = [MJPerson class];

    void *obj = &cls;

    [(__bridge id)obj print];
}

首先分析，變量之間的關(guān)系，如下圖所示

  1. 與正常調(diào)用實(shí)例方法的結(jié)構(gòu)相同，都包含指針變量，對(duì)象的ISA指針，類(lèi)對(duì)象
  2. 所以可以調(diào)用到print方法
    變量之間的關(guān)系.png

執(zhí)行方法時(shí)，棧中變量地址的位置，如下圖所示

  1. 棧中的變量地址是從高到低，即先出現(xiàn)的變量，占據(jù)高地址
  2. [super viewDidLoad];，上文說(shuō)過(guò)，會(huì)有一個(gè)結(jié)構(gòu)體變量；接著是cls，接著是obj
  3. 根據(jù)實(shí)例對(duì)象的結(jié)構(gòu)圖，訪問(wèn)name成員變量，就是訪問(wèn)self占據(jù)的指針
    棧中的變量地址.png

API使用

  • 成員變量是基本數(shù)據(jù)類(lèi)型，需要先轉(zhuǎn)成指針，再bridge
    // 創(chuàng)建類(lèi)
    Class newClass = objc_allocateClassPair([NSObject class], "MJDog", 0);
    class_addIvar(newClass, "_age", 4, 1, @encode(int));
    class_addIvar(newClass, "_weight", 4, 1, @encode(int));
    class_addMethod(newClass, @selector(run), (IMP)run, "v@:");
    // 注冊(cè)類(lèi)
    objc_registerClassPair(newClass);
    // 如果是基本數(shù)據(jù)類(lèi)型，需要先轉(zhuǎn)成指針，再bridge
    object_setIvar(person, ageIvar, (__bridge id)(void *)10);

具體應(yīng)用

  • 利用關(guān)聯(lián)對(duì)象（AssociatedObject）給分類(lèi)添加屬性
  • 遍歷類(lèi)的所有成員變量（修改textfield的占位文字顏色、字典轉(zhuǎn)模型、自動(dòng)歸檔解檔）
  • 交換方法實(shí)現(xiàn)（交換系統(tǒng)的方法，method_exchangeImplementions會(huì)清空方法緩存
  • 利用消息轉(zhuǎn)發(fā)機(jī)制解決方法找不到的異常問(wèn)題
+ (void)load { 
    static dispatch_once_t onceToken; 
    dispatch_once(&onceToken, ^{ 
        Class aClass = [self class]; 
 
        SEL originalSelector = @selector(viewWillAppear:); 
        SEL swizzledSelector = @selector(xxx_viewWillAppear:); 
 
        Method originalMethod = class_getInstanceMethod(aClass, originalSelector); 
        Method swizzledMethod = class_getInstanceMethod(aClass, swizzledSelector); 
        
        // When swizzling a class method, use the following:
        // Class aClass = object_getClass((id)self);
        // ...
        // Method originalMethod = class_getClassMethod(aClass, originalSelector);
        // Method swizzledMethod = class_getClassMethod(aClass, swizzledSelector);
 
        BOOL didAddMethod = 
            class_addMethod(aClass, 
                originalSelector, 
                method_getImplementation(swizzledMethod), 
                method_getTypeEncoding(swizzledMethod)); 
 
        if (didAddMethod) { 
            class_replaceMethod(aClass, 
                swizzledSelector, 
                method_getImplementation(originalMethod), 
                method_getTypeEncoding(originalMethod)); 
        } else { 
            method_exchangeImplementations(originalMethod, swizzledMethod); 
        } 
    }); 
}

數(shù)組和字典的方法交換

集合類(lèi)型，由于使用了類(lèi)簇.

  • 可變數(shù)組真正的類(lèi)型是__NSArrayM
  • 可變字典真正的類(lèi)型是__NSDictionaryM
  • 不可變字典真正的類(lèi)型是__NSDictionaryI 
   static dispatch_once_t onceToken;
    dispatch_once(&onceToken, ^{
       // 類(lèi)簇：NSString、NSArray、NSDictionary，真實(shí)類(lèi)型是其他類(lèi)型
        Class cls = NSClassFromString(@"__NSArrayM");
        Method method1 = class_getInstanceMethod(cls, @selector(insertObject:atIndex:));
        Method method2 = class_getInstanceMethod(cls, @selector(my_insertObject:atIndex:));
        method_exchangeImplementations(method1, method2);
    });

    static dispatch_once_t onceToken;
    dispatch_once(&onceToken, ^{
        Class cls = NSClassFromString(@"__NSDictionaryM");
        Method method1 = class_getInstanceMethod(cls, @selector(setObject:forKeyedSubscript:));
        Method method2 = class_getInstanceMethod(cls, @selector(my_setObject:forKeyedSubscript:));
        method_exchangeImplementations(method1, method2);
        
        Class cls2 = NSClassFromString(@"__NSDictionaryI");
        Method method3 = class_getInstanceMethod(cls2, @selector(objectForKeyedSubscript:));
        Method method4 = class_getInstanceMethod(cls2, @selector(my_objectForKeyedSubscript:));
        method_exchangeImplementations(method3, method4);
    });
最后編輯于 ：
?著作權(quán)歸作者所有,轉(zhuǎn)載或內(nèi)容合作請(qǐng)聯(lián)系作者
【社區(qū)內(nèi)容提示】社區(qū)部分內(nèi)容疑似由AI輔助生成，瀏覽時(shí)請(qǐng)結(jié)合常識(shí)與多方信息審慎甄別。
平臺(tái)聲明：文章內(nèi)容（如有圖片或視頻亦包括在內(nèi)）由作者上傳并發(fā)布，文章內(nèi)容僅代表作者本人觀點(diǎn)，簡(jiǎn)書(shū)系信息發(fā)布平臺(tái)，僅提供信息存儲(chǔ)服務(wù)。

相關(guān)閱讀更多精彩內(nèi)容

  • 轉(zhuǎn)至元數(shù)據(jù)結(jié)尾創(chuàng)建： 董瀟偉，最新修改于： 十二月 23, 2016 轉(zhuǎn)至元數(shù)據(jù)起始第一章:isa和Class一....
    40c0490e5268閱讀 2,058評(píng)論 0贊 9
  • 這篇文章完全是基于南峰子老師博客的轉(zhuǎn)載 這篇文章完全是基于南峰子老師博客的轉(zhuǎn)載 這篇文章完全是基于南峰子老師博客的...
    西木閱讀 30,892評(píng)論 33贊 466
  • 參考鏈接： http://www.cnblogs.com/ioshe/p/5489086.html 簡(jiǎn)介 Runt...
    樂(lè)樂(lè)的簡(jiǎn)書(shū)閱讀 2,249評(píng)論 0贊 9
  • 我們常常會(huì)聽(tīng)說(shuō) Objective-C 是一門(mén)動(dòng)態(tài)語(yǔ)言，那么這個(gè)「動(dòng)態(tài)」表現(xiàn)在哪呢？我想最主要的表現(xiàn)就是 Obje...
    Ethan_Struggle閱讀 2,338評(píng)論 0贊 7
  • 有時(shí)候心甘情愿的去做一些事情，是不會(huì)感到累的，越是辛苦，倒越是覺(jué)得幸福。遇到他之前，我從來(lái)沒(méi)有想過(guò)什么是喜歡，在遇...
    七汐子閱讀 320評(píng)論 0贊 2

友情鏈接更多精彩內(nèi)容