Shader邊緣光(RimLight)效果（轉(zhuǎn)）

轉(zhuǎn)自：http://m.blog.csdn.net/puppet_master/article/details/53548134

簡介

寫了兩篇簡單光照模型的shader的文章，雖然Unity自帶的shader就有diffuse和specular，效果還比自己寫的好，然而要想學(xué)好shader，基礎(chǔ)還是很重要的。不然到網(wǎng)上到處找shader，扔到項(xiàng)目里，能用就好，完全不看性能的話，遲早會(huì)出事的。今天不看光照模型了，物理渲染還沒搞懂，所以只好先來個(gè)簡單的shader玩一玩。正好最近在和某基友玩黑魂，這貨一出來總是自帶一個(gè)特效-邊緣光。于是本人強(qiáng)迫癥發(fā)作，決定研究一下這個(gè)怎么實(shí)現(xiàn)。

RimLight--邊緣發(fā)光效果，是一個(gè)比較常用的效果，實(shí)現(xiàn)簡單，在普通的光照計(jì)算后只需要兩步操作，就可以實(shí)現(xiàn)邊緣光效果?？聪旅嬉环鶊D，簡單介紹一下RimLight的原理：

所謂RimLight邊緣發(fā)光，也就是說對(duì)應(yīng)我們當(dāng)前視角方向，物體上位于邊緣的地方額外加一個(gè)光的效果。那么，怎么判斷一個(gè)點(diǎn)是否在物體的邊緣呢？就是通過法線方向和視線方向的夾角來判斷。當(dāng)視線方向V與法線方向N垂直時(shí)，這個(gè)法線對(duì)應(yīng)的面就與視線方向平行，說明當(dāng)前這個(gè)點(diǎn)對(duì)于當(dāng)前視角來說，就處在邊緣；而視線方向與法線方向一致時(shí)，這個(gè)法線對(duì)應(yīng)的面就垂直于視線方向，說明當(dāng)前是直視這個(gè)面。所以，我們就可以根據(jù)dot（N,V）來獲得視線方向與法線方向的余弦值，通過這個(gè)值來區(qū)分該像素是否處在邊緣，進(jìn)而判斷是否需要增加以及增加邊緣光的強(qiáng)弱。

邊緣光效果Unity下的實(shí)現(xiàn)

上面已經(jīng)說完了邊緣光效果的實(shí)現(xiàn)原理，下面附上完整的邊緣光效果shader，基于之前介紹過的蘭伯特光照模型，增加了邊緣光效果：

//邊緣發(fā)光Shader

//by：puppet_master

//2016.12.11

Shader "ApcShader/RimLight"

{

//屬性

Properties{

_Diffuse("Diffuse", Color) = (1,1,1,1)

_RimColor("RimColor", Color) = (1,1,1,1)

_RimPower("RimPower", Range(0.000001, 3.0)) = 0.1

_MainTex("Base 2D", 2D) = "white"{}

}

//子著色器

SubShader

{

Pass

{

//定義Tags

Tags{ "RenderType" = "Opaque" }

CGPROGRAM

//引入頭文件

#include "Lighting.cginc"

//定義Properties中的變量

fixed4 _Diffuse;

sampler2D _MainTex;

//使用了TRANSFROM_TEX宏就需要定義XXX_ST

float4 _MainTex_ST;

fixed4 _RimColor;

float _RimPower;

//定義結(jié)構(gòu)體：vertex shader階段輸出的內(nèi)容

struct v2f

{

float4 pos : SV_POSITION;

float3 worldNormal : TEXCOORD0;

float2 uv : TEXCOORD1;

//在vertex shader中計(jì)算觀察方向傳遞給fragment shader

float3 worldViewDir : TEXCOORD2;

};

//定義頂點(diǎn)shader,參數(shù)直接使用appdata_base（包含position, noramal, texcoord）

v2f vert(appdata_base v)

{

v2f o;

o.pos = mul(UNITY_MATRIX_MVP, v.vertex);

//通過TRANSFORM_TEX宏轉(zhuǎn)化紋理坐標(biāo)，主要處理了Offset和Tiling的改變,默認(rèn)時(shí)等同于o.uv = v.texcoord.xy;

o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

o.worldNormal = mul(v.normal, (float3x3)_World2Object);

//頂點(diǎn)轉(zhuǎn)化到世界空間

float3 worldPos = mul(_Object2World, v.vertex).xyz;

//可以把計(jì)算計(jì)算ViewDir的操作放在vertex shader階段，畢竟逐頂點(diǎn)計(jì)算比較省

o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;

return o;

}

//定義片元shader

fixed4 frag(v2f i) : SV_Target

{

//unity自身的diffuse也是帶了環(huán)境光，這里我們也增加一下環(huán)境光

fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;

//歸一化法線，即使在vert歸一化也不行，從vert到frag階段有差值處理，傳入的法線方向并不是vertex shader直接傳出的

fixed3 worldNormal = normalize(i.worldNormal);

//把光照方向歸一化

fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

//根據(jù)半蘭伯特模型計(jì)算像素的光照信息

fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;

//最終輸出顏色為lambert光強(qiáng)*材質(zhì)diffuse顏色*光顏色

fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;

//進(jìn)行紋理采樣

fixed4 color = tex2D(_MainTex, i.uv);

//以下為本篇主題：計(jì)算RimLight

//把視線方向歸一化

float3 worldViewDir = normalize(i.worldViewDir);

//計(jì)算視線方向與法線方向的夾角，夾角越大，dot值越接近0，說明視線方向越偏離該點(diǎn)，也就是平視，該點(diǎn)越接近邊緣

float rim = 1 - max(0, dot(worldViewDir, worldNormal));

//計(jì)算rimLight

fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);

//輸出顏色+邊緣光顏色

color.rgb = color.rgb* diffuse + rimColor;

return fixed4(color);

}

//使用vert函數(shù)和frag函數(shù)

#pragma vertex vert

#pragma fragment frag

ENDCG

}

}

//前面的Shader失效的話，使用默認(rèn)的Diffuse

FallBack "Diffuse"

}

下面看一下加了邊緣光后的效果，普通diffuse shader：

白色邊緣光效果：

黃色邊緣光效果：

增加景深效果和Bloom效果，Bloom可以把亮的部分處理得更亮，有一種光線溢出的效果，而景深效果可以突出我們要表現(xiàn)的重點(diǎn)。唉，最近發(fā)現(xiàn)自己身陷后處理不能自拔啊....

通過Mask圖控制邊緣光

我們把邊緣光效果加大到一定程度，就快成了自發(fā)光效果，但是上面的shader有個(gè)問題，就是全身都會(huì)自發(fā)光。如下圖所示：

如果只希望盔甲部分有自發(fā)光效果，而其他部分沒有自發(fā)光，我們就需要用Mask圖來控制了，我們用一張Alpha8的灰度圖來控制是否開啟邊緣光效果，將上面的shader簡單修改一下，增加Mask圖的通道：

//邊緣發(fā)光Shader

//by：puppet_master

//2016.12.11

Shader "ApcShader/RimLight"

{

//屬性

Properties{

_Diffuse("Diffuse", Color) = (1,1,1,1)

_RimColor("RimColor", Color) = (1,1,1,1)

_RimPower("RimPower", Range(0.000001, 20.0)) = 0.1

_RimMask("RimMask", 2D) = "white"{}

_MainTex("Base 2D", 2D) = "white"{}

}

//子著色器

SubShader

{

Pass

{

//定義Tags

Tags{ "RenderType" = "Opaque" }

CGPROGRAM

//引入頭文件

#include "Lighting.cginc"

//定義Properties中的變量

fixed4 _Diffuse;

sampler2D _MainTex;

//使用了TRANSFROM_TEX宏就需要定義XXX_ST

float4 _MainTex_ST;

sampler2D _RimMask;

fixed4 _RimColor;

float _RimPower;

//定義結(jié)構(gòu)體：vertex shader階段輸出的內(nèi)容

struct v2f

{

float4 pos : SV_POSITION;

float3 worldNormal : TEXCOORD0;

float2 uv : TEXCOORD1;

//在vertex shader中計(jì)算觀察方向傳遞給fragment shader

float3 worldViewDir : TEXCOORD2;

};

//定義頂點(diǎn)shader,參數(shù)直接使用appdata_base（包含position, noramal, texcoord）

v2f vert(appdata_base v)

{

v2f o;

o.pos = mul(UNITY_MATRIX_MVP, v.vertex);

//通過TRANSFORM_TEX宏轉(zhuǎn)化紋理坐標(biāo)，主要處理了Offset和Tiling的改變,默認(rèn)時(shí)等同于o.uv = v.texcoord.xy;

o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

o.worldNormal = mul(v.normal, (float3x3)_World2Object);

//頂點(diǎn)轉(zhuǎn)化到世界空間

float3 worldPos = mul(_Object2World, v.vertex).xyz;

//可以把計(jì)算計(jì)算ViewDir的操作放在vertex shader階段，畢竟逐頂點(diǎn)計(jì)算比較省

o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;

return o;

}

//定義片元shader

fixed4 frag(v2f i) : SV_Target

{

//unity自身的diffuse也是帶了環(huán)境光，這里我們也增加一下環(huán)境光

fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;

//歸一化法線，即使在vert歸一化也不行，從vert到frag階段有差值處理，傳入的法線方向并不是vertex shader直接傳出的

fixed3 worldNormal = normalize(i.worldNormal);

//把光照方向歸一化

fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

//根據(jù)半蘭伯特模型計(jì)算像素的光照信息

fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;

//最終輸出顏色為lambert光強(qiáng)*材質(zhì)diffuse顏色*光顏色

fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;

//進(jìn)行紋理采樣

fixed4 color = tex2D(_MainTex, i.uv);

//以下為本篇主題：計(jì)算RimLight

//把視線方向歸一化

float3 worldViewDir = normalize(i.worldViewDir);

//計(jì)算視線方向與法線方向的夾角，夾角越大，dot值越接近0，說明視線方向越偏離該點(diǎn)，也就是平視，該點(diǎn)越接近邊緣

float rim = 1 - max(0, dot(worldViewDir, worldNormal));

//計(jì)算RimLight

fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);

//通過RimMask控制是否有邊緣光,Rim目前存在一張Alpha8類型的圖片中

fixed rimMask = tex2D(_RimMask, i.uv).a;

//輸出顏色+邊緣光顏色

color.rgb = color.rgb* diffuse + rimColor * (1 - rimMask);

return fixed4(color);

}

//使用vert函數(shù)和frag函數(shù)

#pragma vertex vert

#pragma fragment frag

ENDCG

}

}

//前面的Shader失效的話，使用默認(rèn)的Diffuse

FallBack "Diffuse"

}

我們把下面這張自發(fā)光Mask圖賦給材質(zhì)：

通過采樣這張Mask就能控制那部分開啟自發(fā)光，那部分關(guān)閉自發(fā)光了：

調(diào)整Mask圖，也可以得到一些比較好玩的效果：

動(dòng)態(tài)RimLight效果

看了一篇博文，其中的邊緣光使用了一張動(dòng)態(tài)圖，達(dá)到了流動(dòng)的效果，感謝作者的無私分享，于是我也嘗試一下動(dòng)態(tài)RimLight的效果。其實(shí)思路跟上面的Mask圖一樣，只不過這次改成一張掃面線類型的紋理，然后通過這張紋理的采樣滾動(dòng)，達(dá)到動(dòng)態(tài)的效果。一提到動(dòng)態(tài)效果，我們第一個(gè)想到的應(yīng)該就是_Time向量，這個(gè)向量中幾個(gè)值都是跟時(shí)間相關(guān)的，我們?nèi)绻鰟?dòng)態(tài)效果，肯定少不了和這個(gè)變量打交道，關(guān)于_Time及其變種，可以參考這篇文章，我們這里用_Time.y就可以獲得時(shí)間了。

我們用一張Mask紋理，白色代表有邊緣光，黑色無邊緣光，通過采樣這張Mask紋理，控制模型上顯示邊緣光的部分：

動(dòng)態(tài)RimLight的shader如下：

//邊緣發(fā)光Shader

//by：puppet_master

//2016.12.11

Shader "ApcShader/RimLight"

{

//屬性

Properties{

_Diffuse("Diffuse", Color) = (1,1,1,1)

_RimColor("RimColor", Color) = (1,1,1,1)

_RimPower("RimPower", Range(0.000001, 20.0)) = 0.1

_RimMask("RimMask", 2D) = "white"{}

_MainTex("Base 2D", 2D) = "white"{}

_RimSpeed("RimSpeed", Range(-10, 10)) = 1.0

}

//子著色器

SubShader

{

Pass

{

//定義Tags

Tags{ "RenderType" = "Opaque" }

CGPROGRAM

//引入頭文件

#include "Lighting.cginc"

//定義Properties中的變量

fixed4 _Diffuse;

sampler2D _MainTex;

//使用了TRANSFROM_TEX宏就需要定義XXX_ST

float4 _MainTex_ST;

sampler2D _RimMask;

fixed4 _RimColor;

float _RimPower;

float _RimSpeed;

//定義結(jié)構(gòu)體：vertex shader階段輸出的內(nèi)容

struct v2f

{

float4 pos : SV_POSITION;

float3 worldNormal : TEXCOORD0;

float2 uv : TEXCOORD1;

//在vertex shader中計(jì)算觀察方向傳遞給fragment shader

float3 worldViewDir : TEXCOORD2;

};

//定義頂點(diǎn)shader,參數(shù)直接使用appdata_base（包含position, noramal, texcoord）

v2f vert(appdata_base v)

{

v2f o;

o.pos = mul(UNITY_MATRIX_MVP, v.vertex);

//通過TRANSFORM_TEX宏轉(zhuǎn)化紋理坐標(biāo)，主要處理了Offset和Tiling的改變,默認(rèn)時(shí)等同于o.uv = v.texcoord.xy;

o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

o.worldNormal = mul(v.normal, (float3x3)_World2Object);

//頂點(diǎn)轉(zhuǎn)化到世界空間

float3 worldPos = mul(_Object2World, v.vertex).xyz;

//可以把計(jì)算計(jì)算ViewDir的操作放在vertex shader階段，畢竟逐頂點(diǎn)計(jì)算比較省

o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;

return o;

}

//定義片元shader

fixed4 frag(v2f i) : SV_Target

{

//unity自身的diffuse也是帶了環(huán)境光，這里我們也增加一下環(huán)境光

fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;

//歸一化法線，即使在vert歸一化也不行，從vert到frag階段有差值處理，傳入的法線方向并不是vertex shader直接傳出的

fixed3 worldNormal = normalize(i.worldNormal);

//把光照方向歸一化

fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

//根據(jù)半蘭伯特模型計(jì)算像素的光照信息

fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;

//最終輸出顏色為lambert光強(qiáng)*材質(zhì)diffuse顏色*光顏色

fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;

//進(jìn)行紋理采樣

fixed4 color = tex2D(_MainTex, i.uv);

//以下為本篇主題：計(jì)算RimLight

//把視線方向歸一化

float3 worldViewDir = normalize(i.worldViewDir);

//計(jì)算視線方向與法線方向的夾角，夾角越大，dot值越接近0，說明視線方向越偏離該點(diǎn)，也就是平視，該點(diǎn)越接近邊緣

float rim = 1 - max(0, dot(worldViewDir, worldNormal));

//計(jì)算RimLight

fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);

//通過RimMask控制是否有邊緣光,Rim目前存在一張Alpha8類型的圖片中

fixed rimMask = tex2D(_RimMask, i.uv + float2(0 , _Time.y * _RimSpeed)).r;

//輸出顏色+邊緣光顏色

color.rgb = color.rgb* diffuse + rimColor * (1-rimMask);

return fixed4(color);

}

//使用vert函數(shù)和frag函數(shù)

#pragma vertex vert

#pragma fragment frag

ENDCG

}

}

//前面的Shader失效的話，使用默認(rèn)的Diffuse

FallBack "Diffuse"

}

來一張Gif截圖（旁邊好像有什么搶鏡了）：

Unity Shader中可用的變量類型整理

在傳遞參數(shù)時(shí)總是忘了能傳遞哪些類型的參數(shù)，記錄一下，方便以后查找，這種東西也沒必要死記硬背下來，需要的時(shí)候幾秒鐘之內(nèi)能找到就好了。

//Float類型，下面對(duì)應(yīng)變量可以用flaot,half,fixed

_Name("Inspector Name", Float) = defaultValue

//Float類型,可以用一個(gè)滑動(dòng)條控制范圍,下面對(duì)應(yīng)變量可以用float,half,fixed

_Name("Inspector Name", Range(min, max)) = defaultValue

//顏色類型，下面對(duì)應(yīng)變量可以用float4,half4,fixed4，如果是顏色，盡量fixed4

_Name("Inspector Name", Color) = (defaultValue.r, defaultValue.g, defaultValue.b, defaultValue.a)

//2D紋理類型,默認(rèn)紋理可以為空，白，黑，灰，凹凸，下面對(duì)應(yīng)變量sampler2D

_Name("Inspector Name", 2D) = "" / "white" / "black" / "gray" / "bump"{options}

//長方形紋理，非2次方大小的紋理，其同上

_Name("Inspector Name", Rect) = "" / "white" / "black" / "gray" / "bump"{options}

//立方體貼圖CubeMap

_Name("Inspector Name", Cube) = "" {options}

//傳遞一個(gè)Vector4向量

_Name("Inspector Name", Vector) = (defaultValue.x, defaultValue.y, defaultValue.z, defaultValue.w)

//注：上面紋理后面{}里面是一些紋理TexGen，LightmapMode光照模式等內(nèi)容

最后編輯于 ：
?著作權(quán)歸作者所有,轉(zhuǎn)載或內(nèi)容合作請(qǐng)聯(lián)系作者
【社區(qū)內(nèi)容提示】社區(qū)部分內(nèi)容疑似由AI輔助生成，瀏覽時(shí)請(qǐng)結(jié)合常識(shí)與多方信息審慎甄別。
平臺(tái)聲明：文章內(nèi)容（如有圖片或視頻亦包括在內(nèi)）由作者上傳并發(fā)布，文章內(nèi)容僅代表作者本人觀點(diǎn)，簡書系信息發(fā)布平臺(tái)，僅提供信息存儲(chǔ)服務(wù)。

相關(guān)閱讀更多精彩內(nèi)容

友情鏈接更多精彩內(nèi)容