在前一篇文章中，提到了如何在 Spock 中測(cè)試 Static 的 Method，以彌補(bǔ) Spock 在這個(gè)部份的不足。當(dāng)時(shí)使用的是 PowerMock 1.6.2，只不過(guò)隨著時(shí)間的推移，最新的 Mockito 與 PowerMock 組合，在與 Spock 的集成上并不順利。

Mockito 目前已經(jīng)發(fā)展到第二版，但是要在這個(gè)版本的 Mockito 上使用 PowerMock，依據(jù)官方的說(shuō)明仍然還停留在試驗(yàn)性質(zhì)的版本，目前最新可取得的版本是 1.7.0RC4。

如果使用前一篇文章提到的，以 @Rule 的方式來(lái)啟動(dòng) PowerMock：

import org.junit.Rule
import org.mockito.Mockito
import org.powermock.api.mockito.PowerMockito
import org.powermock.core.classloader.annotations.PrepareForTest
import org.powermock.modules.junit4.rule.PowerMockRule
import spock.lang.Specification

@PrepareForTest([TestClass.class])
class MockStaticMethodSpec extends Specification {

    @Rule
    PowerMockRule mPowerMockRule = new PowerMockRule();

    def "測(cè)試靜態(tài)方法"() {
        setup :
        PowerMockito.mockStatic(TestClass.class)

        when :
        Mockito.when(TestClass.staticMethod()).thenReturn("測(cè)試用字串")

        then :
        TestClass.staticMethod() == "測(cè)試用字串"
    }

}

原本可以順利運(yùn)行的測(cè)試用例，在運(yùn)行測(cè)試時(shí)會(huì)出現(xiàn) NullPointerException。

這個(gè)問(wèn)題在網(wǎng)絡(luò)上的信息不多，如果無(wú)法解決，就要回到 JUnit + Mockito + PowerMock 的方案，原本 Spock 所帶來(lái)的優(yōu)勢(shì)就失去了，是一個(gè)很兩難的抉擇。

所幸在研讀 PowerMock 的官方文檔時(shí)，提到了一個(gè)新的功能。在 PowerMock 1.6.0 開始，PowerMockRunner 可以 Delegate 另一個(gè) JUnit Runner，以取代無(wú)法使用 JUnit Rule 的情況。

而在 Specification 的 Source Code 中可以看到，Spock 是使用名為 Sputnik 的 JUnit Runner。

所以把之前的 Code 改成以下的內(nèi)容：

import org.junit.runner.RunWith
import org.mockito.Mockito
import org.powermock.api.mockito.PowerMockito
import org.powermock.core.classloader.annotations.PrepareForTest
import org.powermock.modules.junit4.PowerMockRunner
import org.powermock.modules.junit4.PowerMockRunnerDelegate
import org.spockframework.runtime.Sputnik
import spock.lang.Specification

@RunWith(PowerMockRunner.class)
@PowerMockRunnerDelegate(Sputnik.class)
@PrepareForTest([TestClass.class])
class MockStaticMethodSpec extends Specification {

    def "測(cè)試靜態(tài)方法"() {
        setup :
        PowerMockito.mockStatic(TestClass.class)

        when :
        Mockito.when(TestClass.staticMethod()).thenReturn("測(cè)試用字串")

        then :
        TestClass.staticMethod() == "測(cè)試用字串"
    }

}

而 build.gradle 可以更精簡(jiǎn)：

apply plugin: 'java'
apply plugin: 'groovy'

dependencies {
    testCompile 'org.codehaus.groovy:groovy-all:2.4.7'
    testCompile 'org.spockframework:spock-core:1.1-groovy-2.4'
    testCompile 'org.objenesis:objenesis:2.5.1'
    testCompile 'cglib:cglib-nodep:3.2.5'
    testCompile 'org.mockito:mockito-core:2.8.9'
    testCompile 'org.powermock:powermock-api-mockito2:1.7.0RC4'
    testCompile 'org.powermock:powermock-module-junit4:1.7.0RC4'
}

透過(guò) PowerMockRunner 的 Delegation，在 Spock 1.1 及 1.0 上，基本的功能都可以正常的運(yùn)行，只不過(guò)會(huì)有以下額外的訊息出現(xiàn)。

Notifications are not supported for behaviour ALL_TESTINSTANCES_ARE_CREATED_FIRST
Notifications are not supported when all test-instances are created first!

由于不是 Production 的 Code，所以只要能運(yùn)行，有點(diǎn)訊息或是使用的是非正式的版本，都還在可接受的范圍內(nèi)。

更多深入的文章請(qǐng)參閱 http://www.itdecent.cn/u/fea63707e07f