學習筆記
《x86匯編語言：從實模式到保護模式》
http://www.itdecent.cn/p/d481cb547e9f
c06_mbr.asm
;代碼清單6-1
;文件名：c06_mbr.asm
;文件說明：硬盤主引導扇區(qū)代碼
;創(chuàng)建日期：2011-4-12 22:12
jmp near start
mytext db 'L',0x07,'a',0x07,'b',0x07,'e',0x07,'l',0x07,' ',0x07,'o',0x07,\
'f',0x07,'f',0x07,'s',0x07,'e',0x07,'t',0x07,':',0x07
number db 0,0,0,0,0
start:
mov ax,0x07c0 ;設置數(shù)據(jù)段基地址
mov ds,ax
mov ax,0xb800 ;設置附加段基地址
mov es,ax
cld
mov si,mytext
mov di,0
mov cx,(number-mytext)/2 ;實際上等于 13
rep movsw
;得到標號所代表的偏移地址
mov ax,number
;計算各個數(shù)位
mov bx,ax
mov cx,5 ;循環(huán)次數(shù)
mov si,10 ;除數(shù)
digit:
xor dx,dx
div si
mov [bx],dl ;保存數(shù)位
inc bx
loop digit
;顯示各個數(shù)位
mov bx,number
mov si,4
show:
mov al,[bx+si]
add al,0x30
mov ah,0x04
mov [es:di],ax
add di,2
dec si
jns show
mov word [es:di],0x0744
jmp near $
times 510-($-$$) db 0
db 0x55,0xaa
運行測試
c06_mbr.asm
代碼說明
- 邏輯地址
0x0000:0x7c00
對應的物理地址是 0x07c00
該地址又是段0x07c0的起始地址
等價的邏輯地址是 0x07c0:0x0000
------------------------------------------
mov ax,0x07c0 ;設置數(shù)據(jù)段基地址
mov ds,ax
- 批量復制
源數(shù)據(jù) ds:si
目的地址 es:di
按字節(jié)傳遞 movsb
按字傳遞 movsw
正向傳遞 cld 低地址到高地址 DF = 0
反向傳遞 std 高地址到低地址 DF = 1
指令前綴 rep （repeat） ：CX不為零則重復
批量復制
--------------------------------
cld
mov si,mytext
mov di,0
mov cx,(number-mytext)/2 ;實際上等于 13
rep movsw
--------------------------------
- Intel 8086 ：
[BX] [SI] [DI] [BP]
BX （Base Address Register）基址寄存器
SI （Source Index）源索引寄存器
DI (Destination Index）目標索引寄存器
[bx+si]
[bx+di]
[bp+si]
[bp+di]
AX （Accumulator）累加器
CX（Counter）計數(shù)器
DX（ Data）數(shù)據(jù)寄存器
- inc 指令
inc al
inc byte [bx]
inc word [label_a]
- div 指令
dividnd dw 0x3f0 ;被除數(shù)
divisor db 0x3f ; 除數(shù)
...
mov ax,[dividnd]
div byte [divisor]
-
cbw（convert byte to word）、cwd（convert word to double word）
《x86匯編語言：從實模式到保護模式》 cbw cwd
《x86匯編語言：從實模式到保護模式》 第84頁
- 無符號數(shù)與有符號數(shù) 范圍
無符號數(shù)
8位 0~255
16位 0~65535
32位 0~4294967295
有符號數(shù)
8位 -128~-1 0~127
16位 -32768~-1 0~32767
- 無符號數(shù)除法 div 、有符號數(shù)除法 idiv
《x86匯編語言：從實模式到保護模式》有符號數(shù)除法 idiv
《x86匯編語言：從實模式到保護模式》 第86頁
- 現(xiàn)有指令對標志位的影響
《x86匯編語言：從實模式到保護模式》 現(xiàn)有指令對標志位的影響
《x86匯編語言：從實模式到保護模式》 第90頁
-
jns show條件轉移指令
如果未設置符號位SF，則轉移到標號 show 所在的位置處執(zhí)行；
有符號位 SF（sign flag）
《x86匯編語言：從實模式到保護模式》 jns show 條件轉移指令
當顯示完最后一個數(shù)位后，SI的內(nèi)容是零，執(zhí)行dec si指令后，由于產(chǎn)生了借位，實際的運算結果是0xffff（SI只能容納16個比特），因其最高位是“1”，故處理器將標志位SF置為“1”，表明當前SI中的結果可以理解為一個負數(shù)（-1）。于是，指向jns show時，條件不滿足，接著執(zhí)行后面指令。
《x86匯編語言：從實模式到保護模式》 第88頁
- 各種比較結果和相應的條件轉移指令
《x86匯編語言：從實模式到保護模式》條件轉移指令
《x86匯編語言：從實模式到保護模式》 第90頁
《x86匯編語言：從實模式到保護模式》 表6-1 各種比較結果和相應的條件轉移指令
《x86匯編語言：從實模式到保護模式》 第91頁
《x86匯編語言：從實模式到保護模式》 表6-1 各種比較結果和相應的條件轉移指令（續(xù)表）
《x86匯編語言：從實模式到保護模式》 第92頁
-
$與$$
jmp near $
等價于
infi: jmp near infi
$ 是當前行的匯編地址
-------------------------------------
$$ 是NASM匯編器提供的另一個標記，代表當前匯編節(jié)(段）的起始匯編地址
--------------------------------------
times 510-($-$$) db 0
db 0x55,0xaa
主引導扇區(qū)512個字節(jié)，要求最后兩個字節(jié)分別是 0x55,0xaa，多余部分用零填充
Bochs 調(diào)試
- 調(diào)試命令
n 命令 越過循環(huán)體
可以越過rep 、loop循環(huán)
u 命令 反匯編：根據(jù)機器指令生成可讀的匯編語言指令
u/2 指定反匯編的條數(shù)為2
info eflags 查看標志寄存器：小寫說明標志位0、大寫為1
info eflags 查看標志寄存器：小寫說明標志位0、大寫為1
檢測點6.5 使用反匯編命令定位到第53行jmp near $.png
- 調(diào)試過程記錄
Next at t=0
(0) [0x0000fffffff0] f000:fff0 (unk. ctxt): jmpf 0xf000:e05b ; ea5be000f0
<bochs:1> s
Next at t=1
(0) [0x0000000fe05b] f000:e05b (unk. ctxt): xor ax, ax ; 31c0
<bochs:2> b 0x7c00
<bochs:3> c
...
<bochs:30> s
Next at t=17404890
(0) [0x000000007c60] 0000:7c60 (unk. ctxt): jns .-16 (0x00007c52) ; 79f0
<bochs:31> u/3
00007c60: ( ): jns .-16 ; 79f0
00007c62: ( ): mov word ptr es:[di], 0x0744 ; 26c7054407
00007c67: ( ): jmp .-3 ; e9fdff
<bochs:32> b 0x7c67
<bochs:33> c
(0) Breakpoint 2, 0x0000000000007c67 in ?? ()
Next at t=17404920
(0) [0x000000007c67] 0000:7c67 (unk. ctxt): jmp .-3 (0x00007c67) ; e9fdff
<bochs:34>
參考
- [050][匯編語言]flag標志寄存器
- [052][匯編語言]檢測點11.2（有符號數(shù)運算判斷溢出OF的具體做法）
