使用圖例

257107574-4b2b61cb-5181-45fd-8ae8-6c901c33ce63.png

代碼項(xiàng)目地址

直接上鏈接Github

腳本內(nèi)容

:: 關(guān)閉命令回顯
@echo off
:: 獲取管理員權(quán)限
Net session >nul 2>&1 || mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0","","runas",1)(window.close)&&exit
:: 啟用延遲變量
@setlocal EnableDelayedExpansion
:: 判斷是否具有管理員權(quán)限
fltmc>nul||(echo 請(qǐng)右鍵"以管理員身份運(yùn)行"&echo.&pause)
:: 打印Java版本
:: 通過java原生命令判斷是否具備完整環(huán)境變量
call:printJavaVersion
:: 判斷是否出現(xiàn)錯(cuò)誤信息
if %errorlevel% neq 0 (
    call:printTitle 當(dāng)前未設(shè)置環(huán)境變量
    :: 初始化Path
    call:initPath
)else (
    :: 打印環(huán)境變量
    call:printEnv
)
:: 開始選擇
call:choice
:: 窗口停駐
pause
exit
:: 初始化Path
:initPath
    @setx /M PATH "%PATH%;%%JAVA_HOME%%\bin"
    pas
goto :eof
:: 設(shè)置JAVA_HOME
:setJavaHome
    set javaBelong=%%JAVA_BELONG%%
    set javaVersion=%%JAVA_VERSION%%
    set dir=%~dp0%
    set javaHome=%dir%%javaBelong%\%javaVersion%
    @setx /M JAVA_HOME %javaHome%>nul
    echo JAVA_HOME已設(shè)置: %javaHome%
goto:eof
:: 打印環(huán)境變量
:printEnv
    call:printTitle 當(dāng)前環(huán)境變量
    echo JAVA_HOME : %JAVA_HOME%
    echo JAVA_BELONG : %JAVA_BELONG%
    echo JAVA_VERSION : %JAVA_VERSION%
goto:eof
:: 打印JDK版本
:printJavaVersion
    call:printTitle 當(dāng)前JAVA版本
    java -version
goto:eof
:: 標(biāo)題打印
:printTitle
    echo.
    echo ====================%~1====================
    echo.
goto:eof    
:: 選擇廠商
:choiceBelong
call:printTitle Java廠商切換
:: 建立廠商索引
set num=0
:: 緩存所有廠商索引
set numCache=
:: 展示所有Java廠商
for /D %%i in (%~dp0/*) do (
    :: 廠商索引累加
    set /a num+=1
    :: 緩存廠商索引
    set numCache=!numCache!!num!
    :: 輸出廠商索引：廠商
    echo !num!:%%~ni
)
echo.
:: 選擇Java廠商
set /p choise=--------------------請(qǐng)選擇Java廠商...
:: 判斷廠商索引是否包含輸入內(nèi)容
echo !numCache!|findstr %choise% >nul && (
    echo.
    :: 建立廠商索引
    set num=0
    :: 匹配索引
    for /D %%i in (%~dp0/*) do (
        set /a num+=1
        :: 判斷所選Java廠商
        if !num! == %choise% (
            :: 切入廠商目錄
            cd %%i
            :: 選擇版本
            call:choiceVersion %%i %%~ni
        )
    )
) || (
    echo 請(qǐng)輸入正確的廠商索引
    :: 重新選擇廠商
    goto choiceBelong
)
goto:eof
:: 選擇版本
:choiceVersion
    call:printTitle Java版本切換
    :: 建立版本索引
    set version=0
    :: 緩存所有版本索引
    set versionCache=
    echo !version!:上一步
    :: 展示所有Java版本
    for /D %%j in (%~1/*) do (
        :: 版本索引累加
        set /a version+=1
        :: 緩存版本索引
        set versionCache=!versionCache!!version!
        :: 輸出版本索引：版本
        echo !version!:%%~nj
    )
    echo.
    :: 選擇版本
    set /p choiseversion=--------------------請(qǐng)選擇Java版本...
    :: 判斷版本索引是否包含輸入內(nèi)容
    echo !versionCache!|findstr %choiseversion% >nul && (
        echo.
        :: 建立版本索引
        set version=0
        :: 匹配索引
        for /D %%j in (%~1/*) do (
            set /a version+=1
            :: 判斷所選Java版本
            if !version! == !choiseversion! (
                @setx /M JAVA_BELONG %~2 >nul
                echo Java廠商已切換: %~2
                @setx /M JAVA_VERSION %%~nj >nul
                echo Java版本已切換: %%~nj
                call:setJavaHome
                echo.
            )
        )
    ) || (
        echo "0"|findstr %choiseversion% >nul && (
            goto choiceBelong
        ) || (
            echo 請(qǐng)輸入正確的版本索引
            goto choiceVersion
        )
    )
goto:eof
:: 切換開始
:choice
call:choiceBelong
goto:eof

拓展

下載安裝其他廠商/版本的JDK,目錄結(jié)構(gòu)以 /廠商/版本/bin及其他目錄的形式放置在倉庫中，JavaVersionChoice.bat會(huì)自動(dòng)兼容。