“計(jì)算機(jī)圖形學(xué)第一定律：如果它看起來是對的，那么它就是對的?！?/h6>

在基于物理渲染（PBR）之前，主要受硬件計(jì)算水平的影響，人們不能像PBR那樣使用真實(shí)世界的物理法則進(jìn)行光照渲染。轉(zhuǎn)而根據(jù)自己的經(jīng)驗(yàn)使用一些開銷不那么大的近似計(jì)算進(jìn)行渲染。裴祥風(fēng)提出的Phong光照明模型一直是基于經(jīng)驗(yàn)的光照明模型當(dāng)中的經(jīng)典。后來Blinn簡化了其中關(guān)于高光的計(jì)算，改進(jìn)后的光照明模型被成為Blinn-Phong光照明模型。

Blinn-Phong光照明可表達(dá)為：c_result = c_ambient + c_diffuse+c_specular

其中：

1，環(huán)境光 c_ambient ：
c_ambient = g_ambient
g_ambient：環(huán)境光常量（通過全局光照明烘焙后可知的常量）

2，漫反射 c_diffuse ：
c_diffuse = (c_light + m_diffuse) * max(0, n * ** l)
c_light：光照顏色
m_diffuse：材質(zhì)的漫反射顏色
n：法線
** l：指向光源的矢量

3，高光反射 c_specular
c_specular = (c_light + m_specular) * max(0,v * h)^m_shininess
c_light：光照顏色
m_specular：材質(zhì)的高光反射顏色
v：指向觀察者的矢量
h：h = normalize(v + l)
m_shininess：反光度

因此c_result = g_ambient + (c_light + m_diffuse) * max(0, n * ** l) + (c_light + m_specular) * max(0,v** * h)^m_shininess

Blinn使用了Halfway的簡化計(jì)算取代了Reflected

用Unity Shader實(shí)現(xiàn)一個(gè)Blinn-Phong光照明模型

現(xiàn)在的Unity5+渲染主要推薦使用PBR方式，即Standard材質(zhì)，Legacy中多是使用Phong光照明模型實(shí)現(xiàn)的。如果要自己定制一些特效Shader也可以使用Phong光照明模型，那么我們首先要書寫一個(gè)基礎(chǔ)的Blinn-Phong光照明模型的Shader

Shader "Unlit/PhongLightModel"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}//主貼圖
        _MainColor ("Main Color", Color) = (1.0, 1.0, 1.0, 1.0)//主顏色，默認(rèn)白色
        _SpecularColor ("Specular Color", Color) = (0, 0, 0, 1.0)//高光顏色，默認(rèn)黑色
        _Shininess ("Gloss", Range(0.0, 10)) = 0.5//反光度
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
            #include "Lighting.cginc" 

            struct a2v
            {
                float4 vertex : POSITION;//頂點(diǎn)
                float2 uv : TEXCOORD0;//uv
                float3 normal : NORMAL;//法線
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;//頂點(diǎn)
                float3 worldLightDir:TEXCOORD1;//世界坐標(biāo)系下的指向光源的矢量
                float3 worldNormal:TEXCOORD2;//世界坐標(biāo)系下法線
                float3 worldViewDir :TEXCOORD3; //世界坐標(biāo)系下的指向觀察者的矢量
                float4 pos : SV_POSITION;//裁剪坐標(biāo)下的頂點(diǎn)
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _SpecularColor;
            fixed4 _MainColor;
            float _Shininess;
            
            v2f vert (a2v v)
            {
                v2f o;

                //使用UNITY_MATRIX_MVP矩陣做仿射變換，把模型空間下的頂點(diǎn)轉(zhuǎn)到裁剪坐標(biāo)下
                o.pos = mul(UNITY_MATRIX_MVP,v.vertex);
                
                //取得世界坐標(biāo)系下的法線,UnityObjectToWorldNormal()在UnityCG.cginc被定義
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                //取得世界坐標(biāo)系下的指向光源的矢量，WorldSpaceLightDir()在UnityCG.cginc被定義
                o.worldLightDir = WorldSpaceLightDir(v.vertex);

                //取得世界坐標(biāo)系下的指向觀察者的矢量，WorldSpaceLightDir()在UnityCG.cginc被定義
                o.worldViewDir = WorldSpaceViewDir(v.vertex);

                //uv采樣
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                //歸一化
                fixed3 normalizedLightDir  = normalize(i.worldLightDir);
                fixed3 normalizedNormal = normalize(i.worldNormal);
                fixed3 normalizedViewDir = normalize(i.worldViewDir);

                //像素顏色采樣
                fixed3 albedo = tex2D(_MainTex, i.uv);
                
                //計(jì)算環(huán)境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                //計(jì)算漫反射
                fixed3 diffuse = (_LightColor0.rgb * albedo) * saturate(dot(normalizedNormal,normalizedLightDir));

                //計(jì)算高光
                fixed3 halfDir = normalize(normalizedViewDir + normalizedLightDir);
                fixed3 specular = (_SpecularColor.rgb * _LightColor0.rgb) * pow(saturate(dot(halfDir,normalizedNormal )),_Shininess);

                return fixed4((ambient+diffuse+specular),1);
            }
            ENDCG
        }
    }
    FallBack  "Specular"
}

要控制各種向量的點(diǎn)積大于0，否則取0（小于0會(huì)是完全相反的方向，甚至表現(xiàn)為光線是從背面照過來的）；

結(jié)果：

對比，左：PBR Standard材質(zhì)，右：Blinn-Phong 手寫Shader