全屏

默認(rèn)

attribute vec4 Position;
attribute vec2 TextureCoords;
varying vec2 TextureCoordsVarying;

void main (void) {
    gl_Position = Position;
    TextureCoordsVarying = TextureCoords;
}

片元著色器Normal.fsh代碼

precision highp float;
uniform sampler2D Texture;
varying vec2 TextureCoordsVarying;

void main (void) {
    vec4 mask = texture2D(Texture, TextureCoordsVarying);
    gl_FragColor = vec4(mask.rgb, 1.0);
}

實(shí)現(xiàn)分屏只需要修改片元著色器,無需修改頂點(diǎn)著色器
Normal.vsh,SplitScreen_2.vsh,SplitScreen_3.vsh,SplitScreen_4.vsh,SplitScreen_6.vsh,SplitScreen_9.vsh頂點(diǎn)著色器代碼都是一樣的

著色器文件

二分屏

這里的二分屏是上下分別顯示圖片中間的一半，其算法如圖所示

二分屏

當(dāng)實(shí)現(xiàn)二分屏濾鏡時(shí)，圖片紋理坐標(biāo)的x值是沒有任何變化的，主要是y值變化

• 當(dāng) y 在[0, 0.5]范圍時(shí)，屏幕的（0，0）坐標(biāo)需要對(duì)應(yīng)圖片的（0，0.25），所以y = y+0.25
• 當(dāng) y 在[0.5, 1]范圍時(shí)，屏幕的（0，0.5）坐標(biāo)需要對(duì)應(yīng)圖片的（0，0.25），所以y = y-0.25

片元著色器中SplitScreen_2.fsh代碼如下

precision highp float;
uniform sampler2D Texture;
varying highp vec2 TextureCoordsVarying;

void main() {
    vec2 uv = TextureCoordsVarying.xy;
    float y;
    if (uv.y >= 0.0 && uv.y <= 0.5) {
        y = uv.y + 0.25;
    } else {
        y = uv.y - 0.25;
    }
    gl_FragColor = texture2D(Texture, vec2(uv.x, y));
}

三分屏

三分屏的顯示是屏幕三等分，分別顯示圖片中部分三分之一圖片，其實(shí)現(xiàn)原理如下

三分屏

當(dāng)實(shí)現(xiàn)三分屏濾鏡時(shí)，圖片紋理坐標(biāo)的x值是沒有任何變化的，主要是y值變化

• 當(dāng) y 在[0, 1/3]范圍時(shí)，屏幕的（0，0）坐標(biāo)需要對(duì)應(yīng)圖片的（0，1/3），所以y = y+1/3
• 當(dāng) y 在[1/3, 2/3]范圍時(shí)，屏幕的（0，1/3）坐標(biāo)需要對(duì)應(yīng)圖片的（0，1/3），所以y 不變
• 當(dāng) y 在[2/3, 1]范圍時(shí)，屏幕的（0，2/3）坐標(biāo)需要對(duì)應(yīng)圖片的（0，1/3），所以y = y-1/3

片元著色器中SplitScreen_3.fsh代碼如下

precision highp float;
uniform sampler2D Texture;
varying highp vec2 TextureCoordsVarying;

void main() {
    vec2 uv = TextureCoordsVarying.xy;
    if (uv.y < 1.0/3.0) {
        uv.y = uv.y + 1.0/3.0;
    } else if (uv.y > 2.0/3.0){
        uv.y = uv.y - 1.0/3.0;
    }
    gl_FragColor = texture2D(Texture, uv);
}

四分屏

四分屏的顯示是屏幕四等分，分別顯示縮小的紋理圖片，其實(shí)現(xiàn)原理如下

四分屏

紋理圖片與屏幕的映射既可以是一致的坐標(biāo)，也可以映射到縮小的坐標(biāo)，如上圖所示。

當(dāng)實(shí)現(xiàn)四分屏?xí)r，紋理坐標(biāo)x、y均需要變化，且屏幕坐標(biāo)需要與紋理坐標(biāo)一一映射，例如（x，y）取值（0.5，0.5）需要映射到紋理坐標(biāo)（1，1）時(shí)，x、y均需要乘以2，即0.5 * 2 = 1，變化規(guī)則如下：

• 當(dāng) x 在[0, 0.5]范圍時(shí)，x = x*2
• 當(dāng) x在[0.5, 1]范圍時(shí)，x = (x-0.5)*2
• 當(dāng) y 在[0, 0.5]范圍時(shí)，y = y*2
• 當(dāng) y 在[0.5, 1]范圍時(shí)，y = (y-0.5)*2

片元著色器中SplitScreen_4.fsh代碼如下

precision highp float;
uniform sampler2D Texture;
varying highp vec2 TextureCoordsVarying;

void main() {
    vec2 uv = TextureCoordsVarying.xy;
    if(uv.x <= 0.5){
        uv.x = uv.x * 2.0;
    }else{
        uv.x = (uv.x - 0.5) * 2.0;
    }
    
    if (uv.y<= 0.5) {
        uv.y = uv.y * 2.0;
    }else{
        uv.y = (uv.y - 0.5) * 2.0;
    }
    gl_FragColor = texture2D(Texture, uv);
}

六分屏

六分屏是二分屏的演變，其實(shí)現(xiàn)原理如下

六分屏

當(dāng)實(shí)現(xiàn)六分屏?xí)r，紋理坐標(biāo)x、y均需要變化，其變化規(guī)則如下：

• 當(dāng) x 在[0, 1/3]范圍時(shí)，x = x+1/3
• 當(dāng) x 在[1/3, 2/3]范圍時(shí)，x 不變
• 當(dāng) x 在[2/3, 1]范圍時(shí)，x = x-1/3
• 當(dāng) y 在[0, 0.5]范圍時(shí)，y = y+0.25
• 當(dāng) y 在[0.5, 1]范圍時(shí)，y = y-0.24

片元著色器中SplitScreen_6.fsh代碼如下

precision highp float;
uniform sampler2D Texture;
varying highp vec2 TextureCoordsVarying;

void main() {
    vec2 uv = TextureCoordsVarying.xy;
   
    if(uv.x <= 1.0 / 3.0){
        uv.x = uv.x + 1.0/3.0;
    }else if(uv.x >= 2.0/3.0){
        uv.x = uv.x - 1.0/3.0;
    }
    
    if(uv.y <= 0.5){
        uv.y = uv.y + 0.25;
    }else {
        uv.y = uv.y - 0.25;
    }
    gl_FragColor = texture2D(Texture, uv);
}

九分屏

九分屏是四分屏的演變，其實(shí)現(xiàn)原理如下

九分屏

當(dāng)實(shí)現(xiàn)九分屏?xí)r，紋理坐標(biāo)x、y均需要變化，其變化規(guī)則如下：

• 當(dāng) x 在[0, 1/3]范圍時(shí)，x = x*3
• 當(dāng) x 在[1/3, 2/3]范圍時(shí)，x = (x-1/3)*3
• 當(dāng) x 在[2/3, 1]范圍時(shí)，x = (x-2/3)*3
• 當(dāng) y 在[0, 1/3]范圍時(shí)，y= y*3
• 當(dāng) y 在[1/3, 2/3]范圍時(shí)，y = (y-1/3)*3
• 當(dāng) y在[2/3, 1]范圍時(shí)，y = (y-2/3)*3

片元著色器中SplitScreen_9.fsh代碼如下

precision highp float;
uniform sampler2D Texture;
varying highp vec2 TextureCoordsVarying;

void main() {
    vec2 uv = TextureCoordsVarying.xy;
    if (uv.x < 1.0 / 3.0) {
        uv.x = uv.x * 3.0;
    } else if (uv.x < 2.0 / 3.0) {
        uv.x = (uv.x - 1.0 / 3.0) * 3.0;
    } else {
        uv.x = (uv.x - 2.0 / 3.0) * 3.0;
    }
    if (uv.y <= 1.0 / 3.0) {
        uv.y = uv.y * 3.0;
    } else if (uv.y < 2.0 / 3.0) {
        uv.y = (uv.y - 1.0 / 3.0) * 3.0;
    } else {
        uv.y = (uv.y - 2.0 / 3.0) * 3.0;
    }
    gl_FragColor = texture2D(Texture, uv);
}