書接上文
前文介紹了我們游戲草海的基本渲染方案，本文將介紹一些更加有趣的動態(tài)效果。
碰撞彎曲
碰撞彎曲 在手游中比較常見，下圖是我們游戲里的效果：
uNature 的實現(xiàn)方式 類似用一個球體壓迫草面，使得草的頂點遠離球體中心。
uNature 一共支持 20個碰撞源，不過手游的話只計算 主角的碰撞 就夠了。
我們可以在 頂點著色器 中添加如下代碼：
inline float4 CalculateTouchBending(float4 vertex)
{
float4 current = _InteractionTouchBendedInstances;
if (distance(vertex.xyz, current.xyz) < current.w)
{
float WMDistance = 1 - clamp(distance(vertex.xyz, current.xyz) / current.w, 0, 1);
float3 posDifferences = normalize(vertex.xyz - current.xyz);
float3 strengthedDifferences = posDifferences * (_TouchBendingStrength + _TouchBendingStrength);
float3 resultXZ = WMDistance * strengthedDifferences;
vertex.xz += resultXZ.xz;
vertex.y -= WMDistance * _TouchBendingStrength;
return vertex;
}
return vertex;
}
上面代碼中的 _InteractionTouchBendedInstances 存貯的是 碰撞源 的信息，其 xyz 分量是 球心的世界坐標， w 分量是球的 半徑，_InteractionTouchBendedInstances 的值由腳本傳入。
這里的代碼很簡單，不廢話。
割草
割草 是另外一個好玩的東西，自從玩過 塞爾達，看到什么都想砍兩刀，：）
下圖是我們游戲的割草效果：
割草 的原理也很簡單：在運行時修改 草的密度。
前文提過，Unity內置的 Terrain 提供了一個 GetDetailLayer 接口，這個接口返回一個二維數(shù)組，這個二維數(shù)組和 柵格化 后的地表網格是相對應的，數(shù)組每個元素的值即當前格 草的密度。
uNature 的實現(xiàn)方式和 Terrain 類似，場景依然會被 柵格化，不同的是，uNature 用一張紋理 GrassMap 來存貯密度。
割草 主要的邏輯就是計算出 攻擊范圍 覆蓋的單元格，并且修改這些單元格的密度。
常見的技能攻擊形狀包括：圓形攻擊，扇形攻擊，矩形攻擊等。
下圖是一個 扇形攻擊 覆蓋的單元格示意：
趁著年前有空，我把 割草 的代碼整理了一翻，丟到 Asset Store 賺點小錢，Terrain版本 和 uNature版本 的割草都有：
歡迎參考。
燒草
塞爾達 的草不但可以割，還可以燒。
下圖是我們模仿 塞爾達 的燒草效果，包括火勢蔓延，：）
原理上，燒草 和 割草 類似，不同的是，割草需要 密度，而燒草需要 燃燒度。
這里的 燃燒度 是我們自己定義的，就是 草發(fā)黑的程度。
我們當然可以模仿 密度圖 生成一張 燃燒度圖，不過從優(yōu)化資源占用的角度考慮，我們最終的做法是：復用密度圖。
我們可以對 密度 做一個編碼，讓他 即能表示密度，也能表示燃燒度。
比如 密度 的最大值我們定為 10，燃燒度 的最大值我們定為 23，10 * 23 + 22 = 252 還是在 255以內，這樣 GrassMap 的一個通道就能保存這個信息，表現(xiàn)上也足夠。
舉個例子，比如當前格的密度是 3，燃燒度是 12，那么編碼后的值就是 3 * 23 + 12 = 81。
這樣，無論是 割草 還是 燒草，我們要做的都是 更新密度，即更新 GrassMap 的 像素信息：
public Color32[] mapPixels
{
get
{
if (_mapPixels == null)
{
_mapPixels = map.GetPixels32();
}
return _mapPixels;
}
internal set
{
_mapPixels = value;
}
}
小貼士：用 Texture2D.GetPixels32 接口和 Color32 來計算，速度更快，：）
For most textures, even faster is to use GetPixels32 which returns low precision color data without costly integer-to-float conversions.
隨風擺動
uNature 草的擺動算法如下：
void FastSinCos(float4 val, out float4 s, out float4 c)
{
val = val * 6.408849 - 3.1415927;
float4 r5 = val * val;
float4 r6 = r5 * r5;
float4 r7 = r6 * r5;
float4 r8 = r6 * r5;
float4 r1 = r5 * val;
float4 r2 = r1 * r5;
float4 r3 = r2 * r5;
float4 sin7 = { 1, -0.16161616, 0.0083333, -0.00019841 };
float4 cos8 = { -0.5, 0.041666666, -0.0013888889, 0.000024801587 };
s = val + r1 * sin7.y + r2 * sin7.z + r3 * sin7.w;
c = 1 + r5 * cos8.x + r6 * cos8.y + r7 * cos8.z + r8 * cos8.w;
}
float4 ApplyFastWind(float4 vertex, float texCoordY)
{
if (_WindSpeed == 0) return vertex;
float speed = _WindSpeed;
float4 _waveXmove = float4 (0.024, 0.04, -0.12, 0.096);
float4 _waveZmove = float4 (0.006, .02, -0.02, 0.1);
const float4 waveSpeed = float4 (1.2, 2, 1.6, 4.8);
float4 waves;
waves = vertex.x * _WindBending;
waves += vertex.z * _WindBending;
waves += _Time.x * (1 - 0.4) * waveSpeed * speed;
float4 s, c;
waves = frac(waves);
FastSinCos(waves, s, c);
float waveAmount = texCoordY * (1 + 0.4);
s *= waveAmount;
s *= normalize(waveSpeed);
s = s * s;
float fade = dot(s, 1.3);
s = s * s;
float3 waveMove = float3 (0, 0, 0);
waveMove.x = dot(s, _waveXmove);
waveMove.z = dot(s, _waveZmove);
vertex.xz -= waveMove.xz;
//vertex -= mul(_World2Object, float3(_WindSpeed, 0, _WindSpeed)).x * _WindBending * _SinTime;
return vertex;
}
上面的代碼和Unity內置的 WavingGrass 版本差不多，也是自己擺自己的，不受 WindZone 影響。
我們項目并未采用上述算法，而是選擇了 Lux LWRP Essentials 的方案，細節(jié)請參考前文 Lux的風和WindTexture，這里略過。
一個浮點數(shù)比較的Bug
最后說一個 uNature 的bug。
第一次在手機上跑 uNature 的時候，我發(fā)現(xiàn)部分 Mali GPU 的手機 草不見了，追了半天，最后發(fā)現(xiàn)是下面這個函數(shù)導致的：
float GetDensity(float4 pixel)
{
pixel *= 255;
if (pixel.r == _PrototypeID) return pixel.g;
if (pixel.b == _PrototypeID) return pixel.a;
return 0;
}
這個函數(shù)根據(jù) GrassMap 獲取 指定類型草的密度，這里的 _PrototypeID 即 草的類型ID。
這里關于ID的 浮點數(shù)比較 直接用了 ==，違背了老師對我們的教導，十分的可疑。
換成下面的寫法后，這個bug就修正了：
float GetDensity(float4 pixel)
{
pixel *= 255;
if(abs(pixel.r - _PrototypeID) < 0.01f) return pixel.g;
if(abs(pixel.b - _PrototypeID) < 0.01f) return pixel.a;
return 0;
}
本文就到這里，下篇文章會介紹提升草的 光照表現(xiàn) 的一些做法。
個人主頁
本文的個人主頁鏈接：https://baddogzz.github.io/2020/01/20/Unity-Grass-04/。
好了，拜拜。
